(Заявка) Задаване на playermodel-и, според това какви флагове има играчът

[Kenway]

Много бих искал да мога да задавам различни playermodel-и на играчите (и то различни, в зависимост от това дали играчът е в T или CT отбора), според това какви флагове те притежават.

Всъщност аз в момента използвам този плъгин: https://forums.alliedmods.net/showthread.php?t=106094 и съм доста доволен от функционалността му, единствено бих искал, както казах, да може в него playermodel-ите да се настройват за играчите, според техните флагове, а не само по steamID, каквато изглежда е единствената опция тук.

Ако някой може да ми помогне да постигна желания резултат ще бъда много благодарен!

[Radeon]

Кажи за кои флагове искаш скиновете и по отбори как да са. Аз имам готов плъгин който дава скин само на хора с определен флаг и за CT и Т може да е различен скина. В твоя случай просто ще добавя още флагове

[OciXCrom]

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cstrike>
#include <hamsandwich>

enum _:ModelsInfo
{
    Flag,
    CTModel[32],
    TModel[32]
}

new const g_eModels[][ModelsInfo] =
{
    { ADMIN_LEVEL_A, "owner_ct", "owner_t" },
    { ADMIN_LEVEL_B, "admin_ct", "admin_t" }
}

new bool:g_bHasCustomSkin[33]

public plugin_init()
{
    register_plugin("Multiple Player Models", "1.0", "OciXCrom")
    RegisterHam(Ham_Spawn, "player", "OnPlayerSpawn", 1)
}

public plugin_precache()
{
    for(new i; i < sizeof(g_eModels); i++)
    {
        precache_player_model(g_eModels[i][CTModel])
        precache_player_model(g_eModels[i][TModel])
    }
}

public client_putinserver(id)
    g_bHasCustomSkin[id] = false

public OnPlayerSpawn(id)
{
    if(is_user_alive(id))
    {
        new bool:bMatch

        for(new iFlags = get_user_flags(id), i; i < sizeof(g_eModels); i++)
        {
            if(iFlags & g_eModels[i][Flag])
            {
                switch(cs_get_user_team(id))
                {
                    case CS_TEAM_CT: set_model(id, g_eModels[i][CTModel])
                    case CS_TEAM_T: set_model(id, g_eModels[i][TModel])
                }

                bMatch = true
                break
            }
        }

        if(!bMatch && g_bHasCustomSkin[id])
        {
            g_bHasCustomSkin[id] = false
            cs_reset_user_model(id)
        }
    }
}

set_model(const id, const szModel[])
{
    cs_set_user_model(id, szModel)
    g_bHasCustomSkin[id] = true
}

precache_player_model(const name[], &id = 0)
{
    new model[128]
    formatex(model, charsmax(model), "models/player/%s/%sT.mdl", name, name)

    if(file_exists(model))
    {
        id = precache_generic(model)
    }

    static const extension[] = "T.mdl"
    #pragma unused extension

    copy(model[strlen(model) - charsmax(extension)], charsmax(model), ".mdl")
    return precache_generic(model)
}

[Kenway]

Много ви благодаря за отговорите, но някак си успях да се оправя тук с един друг плъгин и засега всичко изглежда работи, точно както го исках.

Ако нещо вземе да се обърка ще се консултирам отново с този пост.