Redirect Fixed

[lantimilan]

Hello im using one plugin for automaticly redirect in new ip but i dont know what wrong after 10 sec i stay in old server not transfer, do you know any force command what transfer everybody

Код за потвърждение: Избери целия код

#include <amxmodx>

#define PLUGIN  "Redirect Server New"
#define VERSION "1.2"
#define AUTHOR  "Wilian M."

#define A2S_INFO_SOURCE_IDX_VERSION 2
#define A2S_INFO_SOURCE_IDX_APPID 7
#define A2S_INFO_GOLD_IDX_VERSION 9

new xCount[33], xCvarTimeRedirect, xCvarIp, xCvarPort
new xIpCvar[64]

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR)

	xCvarIp = register_cvar("rs_ip_new", "5.252.100.242")
	xCvarPort = register_cvar("rs_port_new", "27025")
	xCvarTimeRedirect = register_cvar("rs_time_redirect", "10")
}

public client_disconnect(id)
{
	xCount[id] = false
}

public client_putinserver(id)
{
	set_task(3.0, "xCountNewIp", id+887744)

	xCount[id] = get_pcvar_num(xCvarTimeRedirect)
}

public xCountNewIp(id)
{
	id -= 887744

	if(!is_user_connected(id))
		remove_task(id+887744)

	get_pcvar_string(xCvarIp, xIpCvar, charsmax(xIpCvar))
	
	if(xCount[id] < 0)
	{
		client_cmd(id, "wait;wait;wait;wait;wait;^"connect^" %s:%d", xIpCvar, get_pcvar_num(xCvarPort))
	}
	else
	{
		set_hudmessage(255, 0, 0, -1.0, -1.0, 2, 0.03, 1.0, 0.01, 0.02, 1)
		show_hudmessage(id, "> ..::[Lipjani] Dust2 Only [+18]::.n <^n^n- Ndryshimi IP.^n- IP Reja: %s:%d^n- Redirektoheni per: %d sekonda.", xIpCvar, get_pcvar_num(xCvarPort), xCount[id])

		xCount[id]--

		set_task(1.0, "xCountNewIp", id+887744)
	}
}

[Dennis]

Код за потвърждение: Избери целия код

client_cmd(id, "wait;wait;wait;wait;wait;^"connect^" %s:%d", xIpCvar, get_pcvar_num(xCvarPort))

There is no possible solution for this since client_cmd connect is blocked by Valve.
https://developer.valvesoftware.com/wik ... lowhacking

I've tested many-many ways to achieve this myself, none of which work at this current day and age.
xRedirect did made a request to Valve, this to be resoluted - but since this would result in quite a few fake servers redirecting players, I don't see that happening anytime soon.

Best way to achieve the goal of redirecting to a new server is via MOTD.

Код за потвърждение: Избери целия код

#include <amxmodx>

#pragma semicolon 1

enum _:Cvars {
	NSR_STATUS,
	NSR_IP[32],
	NSR_PORT,
	Float:NSR_DELAY
};

new g_eCvars[Cvars];

public plugin_init()
{
	register_plugin("New Server Redirect", "1.0", "Someone");

	bind_pcvar_num(create_cvar("nsr_enable", "1"), g_eCvars[NSR_STATUS]);
	bind_pcvar_string(create_cvar("nsr_new_ip", "123.45.67.89"), g_eCvars[NSR_IP], charsmax(g_eCvars[NSR_IP]));
	bind_pcvar_num(create_cvar("nsr_new_port", "27015"), g_eCvars[NSR_PORT]);
	bind_pcvar_float(create_cvar("nsr_redirect_delay", "10.0"), g_eCvars[NSR_DELAY]);

	if(!file_exists("new_server.txt"))
		set_fail_state("new_server.txt file not found");

	if(!g_eCvars[NSR_STATUS])
		set_fail_state("Plugin is turned off. Check plugin settings!");

	if(equal(g_eCvars[NSR_IP], ""))
		set_fail_state("The server IP missing. Check plugin settings!");

	register_event("InitHUD", "displayHUD", "bd");
	register_message(get_user_msgid("VGUIMenu"), "checkVGUI");
}

public displayHUD(id)
{
	if(!is_user_bot(id) && !is_user_hltv(id) || !is_user_immune(id))
	{
		set_task(0.1, "DisplayMOTD", id, "", 0, "b");

		console_print(id, "^n***********************");
		console_print(id, "*  The server IP has changed");
		console_print(id, "*                NEW IP:");
		console_print(id, "*      %s:%d^n*", g_eCvars[NSR_IP], g_eCvars[NSR_PORT]);
		console_print(id, "*  Update it in your Favorites");
		console_print(id, "***********************^n");
	}
}

public client_disconnected(id)
{
	remove_task(id);
	remove_task(id + 123);
}

public DisplayMOTD(id)
{
	if(is_user_connected(id))
		show_motd(id, "new_server.txt");
	else
	{
		remove_task(id);
		remove_task(id + 123);
	}
}

public checkVGUI(msgid, dest, id)
{
	if(is_user_immune(id))
		return PLUGIN_CONTINUE;

	return PLUGIN_HANDLED;
}

bool:is_user_immune(id)
	return bool:(get_user_flags(id) & ADMIN_IMMUNITY);

[lantimilan]

thanks bro