Загряващ рунд

[impossible]

Искам код ,който като се смени мапа или да има загряващ рунд от 40 секунди или когато си сам в сървара и някой влезе Game Commencing да се активира загряващия рунд и да започне да отброява секунди centur hud като при всяка секунда да се мени цвета на текста и секундите

Текст gameservers primerno V momenta zagrqvame ostavashto vreme : 40 sek и да отброява с различните цветове на текста и секундите и след това да пак рестарт да изписва The game will restart in 1 SECONDи текст gameservers
Neka igrata zapochne SEGA!

[mBFF-TheFucKBG]

Ппц не е трудно да ползваш търсачката горе...................

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cromchat>
#include <cstrike>
#include <fun>
#include <hamsandwich>

#define WARMUP_DURATION 45
#define RESET_DELAY 3

#define HUD_MESSAGE "Warmup: %i sekundi"
#define CHAT_MESSAGE "^3[Warmup] ^1Ostavat oshte ^4%i ^1sekundi."

#define HUD_MESSAGE_END "Warmup zavurshi!^nIgrata zapochva sled %i sekundi!"
#define CHAT_MESSAGE_END "^3[Warmup] ^1Igrata zapochva sled ^4%i ^1sekundi!"
#define CHAT_MESSAGE_REPEAT 3

#define HUD_COLOR 0, 255, 0
#define HUD_POSITION -1.0, 0.2

#define HUD_FREQ 1.0
#define TASK_WARMUP 332912

new bool:g_bWarmupEnded, g_iObject, g_iCountdown;

public plugin_init()
{
	register_plugin("Warmup with Countdown", "1.0", "OciXCrom");
	register_logevent("OnFirstRound", 2, "0=World triggered", "1&Restart_Round_");
	register_logevent("OnFirstRound", 2, "0=World triggered", "1=Game_Commencing");
	RegisterHam(Ham_Spawn, "player", "OnPlayerSpawn", 1);
	g_iObject = CreateHudSyncObj();
	OnFirstRound();
}

public OnPlayerSpawn(id)
{
	if(!is_user_alive(id) || g_bWarmupEnded)
		return;

	strip_user_weapons(id)
	give_item(id, "weapon_knife")
	give_item(id, "weapon_deagle")
	cs_set_user_bpammo(id, CSW_DEAGLE, 35)
	cs_set_user_money(id, 0)
}

public OnFirstRound()
{
	if(g_bWarmupEnded)
		return;

	remove_task(TASK_WARMUP);
	g_iCountdown = WARMUP_DURATION;
	set_task(HUD_FREQ, "DisplayMessage", TASK_WARMUP, .flags = "b");
}

public DisplayMessage()
{
	set_hudmessage(HUD_COLOR, HUD_POSITION, 0, 0.1, 5.0, 0.1, 0.1);

	if(--g_iCountdown == 0)
	{
		server_cmd("sv_restartround %i", RESET_DELAY);
		ShowSyncHudMsg(0, g_iObject, HUD_MESSAGE_END, RESET_DELAY);

		for(new i; i < CHAT_MESSAGE_REPEAT; i++)
			CC_SendMessage(0, CHAT_MESSAGE_END, RESET_DELAY);

		remove_task(TASK_WARMUP);
		g_bWarmupEnded = true;
		return;
	}

	ShowSyncHudMsg(0, g_iObject, HUD_MESSAGE, g_iCountdown);
	CC_SendMessage(0, CHAT_MESSAGE, g_iCountdown);
}

[impossible]

Код за потвърждение: Избери целия код

Не е това което търся


Нещо подобно 


/* Plugin generated by AMXX-Studio */


#include <amxmodx>

#define PLUGIN "Auto Restart vl"
#define VERSION "1.4"
#define AUTHOR "vato loco [GE-S]"

#define TIMER_TASK        123456
#define RESTART_TASK      789123

new g_counter  

new g_autorestart
new g_autoenabled
new g_autocds
new g_autocount_color
new g_autostart_color
new g_auto_xypos

new g_SyncGameStart
new g_SyncRestartTimer

new bool:g_bRoundStart 

public plugin_init() 
{
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	register_logevent("RoundStart", 2, "1=Round_Start")
	register_event("TextMsg","RestartTask","a","2&#Game_C")   
	
	register_dictionary("auto_restart_vl.txt")
	
	g_autoenabled = register_cvar("amx_autorr_enable","1")
	g_autocds = register_cvar("amx_autorr_cds","1")
	g_autorestart = register_cvar("amx_autorr_time","40")
	g_autocount_color = register_cvar("amx_autorr_count_color","0 255 0")
	g_autostart_color = register_cvar("amx_autorr_start_color","0 255 255")
	g_auto_xypos = register_cvar("amx_autorr_xypos","-1.0 0.25")
	
	g_SyncGameStart = CreateHudSyncObj()
	g_SyncRestartTimer = CreateHudSyncObj()
}

public RoundStart()
{
	if(!get_pcvar_num(g_autoenabled))
		return PLUGIN_HANDLED
	
	if(g_bRoundStart)
	{
		static r, g, b, Float:x, Float:y
		HudMsgPos(x,y)
		HudMsgColor(g_autostart_color, r, g, b)
		
		set_hudmessage( r, g, b, x, y, 1, 5.0, 8.0, 0.0, 0.0, -1)
		ShowSyncHudMsg( 0, g_SyncGameStart, "%L",LANG_PLAYER, "GAME_STARTED")
	}
	g_bRoundStart = false
	
	return PLUGIN_CONTINUE
}

public RestartTask() 
{
	if(!get_pcvar_num(g_autoenabled))
		return PLUGIN_HANDLED
	
	set_task(1.0,"TimeCounter",TIMER_TASK,_,_,"a",get_pcvar_num(g_autorestart))
	set_task(get_pcvar_float(g_autorestart),"RestartRound",RESTART_TASK)
	
	return PLUGIN_CONTINUE
}

public TimeCounter() 
{
	g_counter++
	
	new Float:iRestartTime = get_pcvar_float(g_autorestart) - g_counter
	new Float:fSec
	fSec = iRestartTime 
	
	static r, g, b, Float:x, Float:y
	HudMsgPos(x,y)
	HudMsgColor(g_autocount_color, r, g, b)
	
	set_hudmessage( r, g, b, x, y, 0, 0.0, 1.0, 0.0, 0.0, -1)
	ShowSyncHudMsg( 0, g_SyncRestartTimer, "%L",LANG_PLAYER, "AUTO_RESTART", floatround(fSec))
	
	if(get_pcvar_num(g_autocds) && get_pcvar_num(g_autorestart) - g_counter < 11 && get_pcvar_num(g_autorestart) - g_counter !=0)
	{
		static szNum[32]
		num_to_word(get_pcvar_num(g_autorestart) - g_counter, szNum, 31)
		client_cmd(0,"speak ^"vox/%s^"", szNum)
	}
	if(g_counter == get_pcvar_num(g_autorestart))
	{
		g_bRoundStart = true
		g_counter = 0
	}
}

public RestartRound() 
{
	server_cmd("sv_restartround 1")
}

public HudMsgColor(cvar, &r, &g, &b)
{
	static color[16], piece[5]
	get_pcvar_string(cvar, color, 15)
	
	strbreak( color, piece, 4, color, 15)
	r = str_to_num(piece)
	
	strbreak( color, piece, 4, color, 15)
	g = str_to_num(piece)
	b = str_to_num(color)
}

public HudMsgPos(&Float:x, &Float:y)
{
	static coords[16], piece[10]
	get_pcvar_string(g_auto_xypos , coords, 15)
	
	strbreak(coords, piece, 9, coords, 15)
	x = str_to_float(piece)
	y = str_to_float(coords)
}

[mBFF-TheFucKBG]

МНЕНИЕТО Е СКРИТО ОТ СТРАНА НА МОДЕРАТОР! ЦЪКНИ ВЪРХУ ЛЕНТАТА ЗА ДА ГО ПРЕГЛЕДАШ.

Маняк то е същото.....