Need sound plugin

[Cirovic]

Hello i need plugin that will play sound for a player who i choose...
amx_play play .mp3 sound for specific player

[OciXCrom]

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <amxmisc>

#if !defined MAX_NAME_LENGTH
const MAX_NAME_LENGTH = 32
#endif

new const MP3_SOUND[] = "sound/your_sound_here.mp3"

public plugin_init()
{
	register_plugin("Play Sound Command", "1.0", "OciXCrom")
	register_concmd("amx_play", "Cmd_Play", ADMIN_BAN, "<player>")
}

public plugin_precache()
{
	precache_generic(MP3_SOUND)
}

public Cmd_Play(id, iLevel, iCid)
{
	if(!cmd_access(id, iLevel, iCid, 2))
	{
		return PLUGIN_HANDLED
	}

	new szPlayer[MAX_NAME_LENGTH]
	read_argv(1, szPlayer, charsmax(szPlayer))

	new iPlayer = cmd_target(id, szPlayer, CMDTARGET_ALLOW_SELF)

	if(!iPlayer)
	{
		return PLUGIN_HANDLED
	}

	new szName[MAX_NAME_LENGTH]
	get_user_name(iPlayer, szName, charsmax(szName))

	console_print(id, "Playing %s to %s", MP3_SOUND, szName)
	client_cmd(iPlayer, "mp3 play ^"%s^"", MP3_SOUND)

	return PLUGIN_HANDLED
}

[Cirovic]

Thank oci <3