Заявка за calladmin плъгин

[Vasil Handamqn]

Здравейте на всички. Някой може ли да направи този calladmin плъгин IP-адресите на нарушителите да не се запазват в Web Част ,а в един .txt файл ,който може да се сложи или в data/lang или в configs.

Ето линк към плъгина с Web-частта - viewtopic.php?t=5200

[gadinkata]

Тествах го,тествай и ти

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <amxmisc>
#include <cromchat>

new bool:iUserCalled[33]; 
new iCacheUserName[34]
new iCacheReporter[34], iCacheUserIp[18]; 

public plugin_init() 
{
	register_plugin("CallAdmin Mysql","0.1","Nikolow-version")
	
	register_clcmd("say /call", "cmdCallMenu", ADMIN_ALL); 
	register_clcmd("say /calladmin", "cmdCallMenu", ADMIN_ALL); 
	register_concmd("amx_callreason", "cmdCallReason", ADMIN_ALL); 
	
	CC_SetPrefix("&x04[Call-Admin]&x01");
}

public cmdCallMenu(id, level, cid) 
{ 
   if(!cmd_access(id, level, cid, 1)) 
      return PLUGIN_HANDLED; 
    
   new iMenu = menu_create("\rCall Admin Menu:", "cmdCallMenuFunc"); 
   new iPlayers[32], iNum, iTarget; 
   new UserName[34], szTempID[10]; 
   get_players(iPlayers, iNum); 
   for(new i; i < iNum; i++) 
   { 
      iTarget = iPlayers[i]; 
      get_user_name(iTarget, UserName, sizeof UserName - 1); 
      num_to_str(iTarget, szTempID, charsmax(szTempID)); 
      menu_additem(iMenu, UserName, szTempID, _, menu_makecallback("CallMenuPlayers")); 
   } 

   menu_display(id, iMenu, 0); 
   return PLUGIN_HANDLED; 
} 

public CallMenuPlayers(iClient, iMenu, Item) 
{ 
   new iAccess, Info[3], iCallback; 
   menu_item_getinfo(iMenu, Item, iAccess, Info, sizeof Info - 1, _, _, iCallback); 
     
   new iGetID = str_to_num(Info); 
    
   if(access(iGetID, ADMIN_IMMUNITY)) // админи с имунитед не се показват
   { 
      return ITEM_DISABLED; 
   }  
    
   if(iUserCalled[iGetID]) // вече репортнати хора не се показват
   { 
      return ITEM_DISABLED; 
   } 
    
   return ITEM_ENABLED; 
} 

public cmdCallMenuFunc(id, iMenu, Item) 
{ 
   if(Item == MENU_EXIT) 
   { 
      menu_destroy(iMenu); 
      return PLUGIN_HANDLED; 
   } 

   new iData[6], iName[64]; 
   new access, callback; 
   menu_item_getinfo(iMenu, Item, access, iData, charsmax(iData), iName, charsmax(iName), callback); 

   new iTarget = str_to_num(iData); 
   get_user_name(iTarget, iCacheUserName, sizeof iCacheUserName - 1); 
   get_user_name(id, iCacheReporter, sizeof iCacheReporter - 1); 
   get_user_ip(iTarget, iCacheUserIp, sizeof iCacheUserIp - 1, 1); 

   CC_SendMatched(id, CC_COLOR_TEAM, "Please type^4 Reason^1 for this^3 Call^1 !"); 
   client_cmd(id, "messagemode amx_callreason"); 
   
   menu_destroy(iMenu); 
   return PLUGIN_HANDLED; 
} 

public cmdCallReason(id, level, cid) 
{ 
   if(!cmd_access(id, level, cid, 1)) 
      return PLUGIN_HANDLED; 
    
   new iReason[64]; 
   read_argv(1, iReason, sizeof iReason - 1); 

   CallFunction(id, iCacheUserName, iCacheUserIp, iReason, iCacheReporter); 
   
   return PLUGIN_HANDLED; 
} 

stock CallFunction(id, const iPlayer[], const PlayerIp[], const iReason[], const iReporter[]) 
{
	new plID = find_player("bl", iPlayer)

	// server ip address
	new ip[22], szPort[6];
	get_user_ip(0,ip,15,1) 
	get_cvar_string("port", szPort, 5);
	format(ip, 21, "%s:%s", ip, szPort);
   
	// server host name
	new srvname[32];
	get_cvar_string("hostname",srvname,31)
   
	// date ?
	new datestr[11];
	get_time("%d.%m.%Y",datestr,10) 
   
	// current time ?
	new timestr[9];
	get_time("%H:%M:%S",timestr,8)
	
	log_to_file("CallAdmin.txt","Nick: %s | Ip: %s | Reason: %s | Data: %s | Chas: %s | ServName: %s | PlayerIp: %s | Report: %s ^n",iPlayer,ip,iReason,datestr,timestr,srvname,PlayerIp, iReporter)
   
	CC_SendMatched(id, CC_COLOR_TEAM, "^3 %s^1 has been^4 Reported^1 for^3 %s^1 by^4 %s", iPlayer, iReason, iReporter)
	iUserCalled[plID] = true;
} 

public client_connect(id) 
{ 
   iUserCalled[id] = false; 
}

public client_disconnected(id) 
{ 
   iUserCalled[id] = false; 
}  

L 08/19/2020 - 20:42:00: Log file started (file "cstrike\addons\amxmodx\logs\CallAdmin.txt") (game "cstrike") (amx "1.9.0.5234") L 08/19/2020 - 20:42:00: Nick: BotsBlitz | Ip: 192.168.8.100:27016 | Reason: igrae s hack | Data: 19.08.2020 | Chas: 20:42:00 | ServName: Server Name | PlayerIp: 127.0.0.1 | Report: gadinkata

[K!lLAlL]

И при мен работи.

[Vasil Handamqn]

МНЕНИЕТО Е СКРИТО ОТ СТРАНА НА МОДЕРАТОР! ЦЪКНИ ВЪРХУ ЛЕНТАТА ЗА ДА ГО ПРЕГЛЕДАШ.

K!LA|L ще ти пиша на лично да те питам нещо

[Vasil Handamqn]

Направих го Благодаря на всеки ,който ми помогна може да заключвате темата ако искате.