Best player on map

[aLbaShaRe]

Търся плъгин който да показва като в гънгейма на края на мапа в мотд екран най - добрия играч.

[OciXCrom]

Как да се определя въпросният играч? Най-много убийства, най-много headshots, убийства минус умирания...?

[aLbaShaRe]

Най-много убийства

[OciXCrom]

Код за потвърждение: Избери целия код

#include <amxmodx>

// Минимум нужни убийства за да се покаже MOTD.
#define MIN_KILLS 3

// Пътят към MOTD файла.
#define MOTD_FILE "addons/amxmodx/configs/BestPlayer.txt"

#define ARG_NAME "$name$"
#define ARG_FRAGS "$frags$"

public plugin_init()
{  
	register_plugin("Best Player End MOTD", "1.0", "OciXCrom")
	register_message(SVC_INTERMISSION, "OnIntermission")
}

public OnIntermission()
{		 
	new iPlayers[32], iPnum
	get_players(iPlayers, iPnum)
	
	if(!iPnum)
		return PLUGIN_CONTINUE
		
	new iBestPlayer, iBestFrags
	
	for(new iPlayer, iFrags, i; i < iPnum; i++)
	{
		iPlayer = iPlayers[i]
		iFrags = get_user_frags(iPlayer)
		
		if(iFrags > iBestFrags)
		{
			iBestFrags = iFrags
			iBestPlayer = iPlayer
		}
	}
	
	if(iBestFrags < MIN_KILLS)
		return PLUGIN_CONTINUE

	new szMotd[1536], szName[32], szFrags[10]
	get_user_name(iBestPlayer, szName, charsmax(szName))
	LoadFileForMe(MOTD_FILE, szMotd, charsmax(szMotd))
	replace_all(szMotd, charsmax(szMotd), ARG_NAME, szName)
	num_to_str(iBestFrags, szFrags, charsmax(szFrags))
	replace_all(szMotd, charsmax(szMotd), ARG_FRAGS, szFrags)
	show_motd(0, szMotd)
	message_begin(MSG_ALL, SVC_FINALE)
	write_string("")
	message_end()
	return PLUGIN_HANDLED
}

configs/BestPlayer.txt:

Код за потвърждение: Избери целия код

<b>The best player is <font color="red">$name$</font> with <font color="green">$frags$</font> frags.</b>

В този файл можеш да ползваш HTML за да оформиш MOTD прозореца както желаеш (максимум 1536 символа).
$name$ е името на играча, а $frags$ броят на убийства.
Кажи дали всичко е наред. Когато намеря свободно време, ще направя цялостен плъгин с настройки.

[aLbaShaRe]

Плъгина функционира правилно, благодарности.

[OciXCrom]

Ето и цялостен плъгин: viewtopic.php?f=21&t=2444
Ползвай него, тъй като в кода по-горе ще стане объркване ако има повече играчи с еднакъв брой убийства.