Заявка/Изработка на Gun skin с флаг

[LUMIS43]

Здравейте, бих искал да се изработи плъгин,които да променя скина на оръжията:
(AK47, M4A1 и knife) на SMS VIP играчите с флаг "r"
(AK47, M4A1 и knife) на SMS Админ играчите с флаг "t"

Благодаря предварително.

[OciXCrom]

Настрой си скиновете в g_szModels. Ако някой скин няма p_ модел, остави полето празно ("").

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <fakemeta>

#define MAX_MODELS 32

enum _:Data
{
	Flags[32],
	AK47_V[32],
	AK47_P[32],
	M4A1_V[32],
	M4A1_P[32],
	Knife_V[32],
	Knife_P[32]
}

new const g_szModels[][Data] = 
{
	/* "Flags", "AK47 V Model", "AK47 P Model", "M4A1 V Model", "M4A1 P Model", "Knife V Model", "Knife P Model" */
	{ "r", "models/v_ak47.mdl", "models/p_ak47.mdl", "models/v_m4a1.mdl", "models/p_m4a1.mdl", "models/v_knife.mdl", "models/p_knife.mdl" },
	{ "t", "models/v_ak47.mdl", "models/p_ak47.mdl", "models/v_m4a1.mdl", "models/p_m4a1.mdl", "models/v_knife.mdl", "models/p_knife.mdl" }
}

new g_iFlags[MAX_MODELS]

public plugin_init()
{
	register_plugin("Admin Models", "1.0", "OciXCrom")
	register_event("CurWeapon", "OnWeaponChange", "be", "1=1")
}

public plugin_precache()
{
	for(new i; i < sizeof(g_szModels); i++)
	{
		g_iFlags[i] = read_flags(g_szModels[i][Flags])
		
		if(g_szModels[i][AK47_V][0])
			precache_model(g_szModels[i][AK47_V])
			
		if(g_szModels[i][AK47_P][0])
			precache_model(g_szModels[i][AK47_P])
			
		if(g_szModels[i][M4A1_V][0])
			precache_model(g_szModels[i][M4A1_V])
			
		if(g_szModels[i][M4A1_P][0])
			precache_model(g_szModels[i][M4A1_P])
			
		if(g_szModels[i][Knife_V][0])
			precache_model(g_szModels[i][Knife_V])
			
		if(g_szModels[i][Knife_P][0])
			precache_model(g_szModels[i][Knife_P])
	}
}

public OnWeaponChange(id)
{
	for(new i, iFlags = get_user_flags(id); i < sizeof(g_szModels); i++)
	{
		if((iFlags & g_iFlags[i]) == g_iFlags[i])
		{
			switch(read_data(2))
			{
				case CSW_AK47:
				{
					if(g_szModels[i][AK47_V][0])
						set_pev(id, pev_viewmodel2, g_szModels[i][AK47_V])
						
					if(g_szModels[i][AK47_P][0])
						set_pev(id, pev_weaponmodel2, g_szModels[i][AK47_P])
				}
				case CSW_M4A1:
				{
					if(g_szModels[i][M4A1_V][0])
						set_pev(id, pev_viewmodel2, g_szModels[i][M4A1_V])
						
					if(g_szModels[i][M4A1_P][0])
						set_pev(id, pev_weaponmodel2, g_szModels[i][M4A1_P])
				}
				case CSW_KNIFE:
				{
					if(g_szModels[i][Knife_V][0])
						set_pev(id, pev_viewmodel2, g_szModels[i][Knife_V])
						
					if(g_szModels[i][Knife_P][0])
						set_pev(id, pev_weaponmodel2, g_szModels[i][Knife_P])
				}
			}
			
			break
		}
	}
}