Заявка за Админ "skins"

[MickeyMouse]

Някой от вас може ли да ми настрой някакъв плъгин за админ скинчета на флага "r"

[wrath]

Сложи уникални имена на моделите ,но пиши без .mdl накрая.

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cstrike>
#include <hamsandwich>

#define MAX_MODELS 32

enum _:Data
{
	Flags[32],
	Model[32]
}

new const g_szModels[][Data] = 
{
	{ "m", "ime_na_modela1" },
	{ "n", "ime_na_modela2" },
	{ "o", "ime_na_modela3" },
	{ "p", "ime_na_modela4" }
}

new g_iFlags[MAX_MODELS]

public plugin_init()
{
	register_plugin("Admin Models", "1.0", "OciXCrom")
	RegisterHam(Ham_Spawn, "player", "OnPlayerSpawn", 1)
}

public plugin_precache()
{
	for(new i; i < sizeof(g_szModels); i++)
	{
		precache_player_model(g_szModels[i][Model])
		g_iFlags[i] = read_flags(g_szModels[i][Flags])
	}
}

public OnPlayerSpawn(id)
{
	if(!is_user_alive(id))
		return
	
	new bool:bMatch
		
	for(new i, iFlags = get_user_flags(id); i < sizeof(g_szModels); i++)
	{
		if((iFlags & g_iFlags[i]) == g_iFlags[i])
		{
			cs_set_user_model(id, g_szModels[i][Model])
			bMatch = true
			break
		}
	}
	
	if(!bMatch)
		cs_reset_user_model(id)
}	
	
precache_player_model(szModel[])
{
    static szFile[128]
    formatex(szFile, charsmax(szFile), "models/player/%s/%s.mdl", szModel, szModel)
    precache_model(szFile)
    replace(szFile, charsmax(szFile), ".mdl", "T.mdl")
    
    if(file_exists(szFile))
        precache_model(szFile)
}

[OciXCrom]

Ползвай това, а не горното:

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cstrike>
#include <hamsandwich>

#define ADMIN_FLAG ADMIN_LEVEL_F
#define CT_MODEL "admin_ct"
#define T_MODEL "admin_t"

public plugin_init()
{
	register_plugin("Simple Admin Models", "1.0", "OciXCrom")
	RegisterHam(Ham_Spawn, "player", "OnPlayerSpawn", 1)
}

public plugin_precache()
{
	precache_player_model(CT_MODEL)
	precache_player_model(T_MODEL)
}

public OnPlayerSpawn(id)
{
	if(!is_user_alive(id))
		return
		
	if(get_user_flags(id) & ADMIN_FLAG)
		cs_set_user_model(id, cs_get_user_team(id) == CS_TEAM_CT ? CT_MODEL : T_MODEL)
	else
		cs_reset_user_model(id)
}

precache_player_model(const szModel[])
{
    static szFile[128]
    formatex(szFile, charsmax(szFile), "models/player/%s/%s.mdl", szModel, szModel)
    precache_model(szFile)
    replace(szFile, charsmax(szFile), ".mdl", "T.mdl")
    
    if(file_exists(szFile))
        precache_model(szFile)
}

Настрой имената на моделите в #define редовете.

[wrath]

Защо да не ползва горното като може да сложи "r" флаг вместо някой от другите ,все същото.

[OciXCrom]

Поради простата причина, че горният код е направен за повече модели и начинът му на работа е в пъти по-сложен от този, който добавя само един модел и е максимално опростен. Отделно, няма опция да се сложат различни модели за СТ и Т.

[MickeyMouse]

Може да локнете