Изработка на примерен плъгин с конфиг файл

[NiKo.]

Здравейте,
Та плъгина който искам е да има .ini файл в който ако е написано
"name" "името на играча тук" "message" ако името на играча е в кавичките да му изпраща някакво съобщение при join в сървъра

[OciXCrom]

Погледни това дали ти върши работа - https://amxx-bg.info/forum/viewtopic.php?t=48&p=48

Иначе ето:

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <amxmisc>

new Trie:g_tData

public plugin_init()
{
	register_plugin("Player Join Messages", "1.0", "OciXCrom")
	g_tData = TrieCreate()
	ReadFile()
}

public plugin_end()
	TrieDestroy(g_tData)
	
public client_putinserver(id)
{
	new szName[32]
	get_user_name(id, szName, charsmax(szName))
	strtolower(szName)
	
	if(TrieKeyExists(g_tData, szName))
	{
		new szMessage[128]
		TrieGetString(g_tData, szName, szMessage, charsmax(szMessage))
		client_print(id, print_chat, szMessage)
	}
}
	
ReadFile()
{
	new szConfigsName[256], szFilename[256]
	get_configsdir(szConfigsName, charsmax(szConfigsName))
	formatex(szFilename, charsmax(szFilename), "%s/JoinMessages.ini", szConfigsName)
	new iFilePointer = fopen(szFilename, "rt")
	
	if(iFilePointer)
	{
		new szData[192], szType[32], szName[32], szMessage[128]
		
		while(!feof(iFilePointer))
		{
			fgets(iFilePointer, szData, charsmax(szData))
			trim(szData)
			
			switch(szData[0])
			{
				case EOS, ';': continue
				default:
				{
					parse(szData, szType, charsmax(szType), szName, charsmax(szName), szMessage, charsmax(szMessage))
					
					if(equali(szType, "name"))
					{
						strtolower(szName)
						TrieSetString(g_tData, szName, szMessage)
					}
				}
			}
		}
			
		fclose(iFilePointer)
	}
}

[NiKo.]

Плъгина Automatic Command Executor го бях погледнал, но ми трябваше код тъй като се опитах да направя едно нещо и ми трябваше от някъде да започна, че не знаех как благодаря все пак, заключвай.