Nemesis extra for zombie plague 5.0

[Dachoni]

Здравейте, бихте ли редактирали така че екстрата:

Да може да се ползва само от Human вида.
Да може да се ползва само, преди инфекцията.
Да има ограничение за брой купувания за един мап-(пример:3 пъти).
Да може да се купува максимум от до двама играчи на рунд.

Благодаря!

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <fakemeta>
#include <cstrike>
#include <zombieplague>

#define PLUGIN "[ZP] Nemesis"
#define VERSION "1.0"
#define AUTHOR "Maakera"

new g_enabled
new g_nemesis
new const g_cost = 18 // Cost of pack

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR)
	g_enabled = register_cvar("zp_extra_nemesis", "1")
	g_nemesis = zp_register_extra_item("Nemesis", g_cost, ZP_TEAM_ZOMBIE)
}

public zp_extra_item_selected(player, itemid)
{
	if (itemid == g_nemesis)
	{
		if (get_pcvar_num(g_enabled)) {
		zp_make_user_nemesis(player)
		set_hudmessage(255, 0, 0, -1.0, 0.01)
		show_hudmessage(0, "Alert There's a nemesis!")
		
		}
		else
		{
			static ammopacks
			ammopacks = zp_get_user_ammo_packs(player)
			zp_set_user_ammo_packs(player, ammopacks + g_cost)
		}
	}
}

/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1033\\ f0\\ fs16 \n\\ par }
*/

[OciXCrom]

Пренаписах го:

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <zombieplague>

#define ITEM_COST 18
#define USES_PER_MAP 3
#define USES_PER_ROUND 2

new bool:g_bStarted = false
new g_pEnabled, g_iNemesis, g_iMapUses, g_iRoundUses

public plugin_init()
{
	register_plugin("[ZP] Nemesis", "1.0", "Rewrite by OciXCrom" /*Original author: Maakera*/)
	register_logevent("OnRoundStart", 2, "0=World triggered", "1=Round_Start")
	g_pEnabled = register_cvar("zp_extra_nemesis", "1")
	g_iNemesis = zp_register_extra_item("Nemesis", ITEM_COST, ZP_TEAM_HUMAN)
}

public OnRoundStart()
{
	g_iRoundUses = 0
	g_bStarted = false
}

public zp_round_started()
	g_bStarted = true	

public zp_extra_item_selected(id, iItem)
{
	if(iItem == g_iNemesis)
	{
		if(!get_pcvar_num(g_pEnabled))
		{
			client_print(id, print_center, "This item is currently disabled.")
			return ZP_PLUGIN_HANDLED
		}
		
		if(g_bStarted)
		{
			client_print(id, print_center, "This item can only be purchased before the infection.")
			return ZP_PLUGIN_HANDLED
		}
			
		if(g_iMapUses >= USES_PER_MAP)
		{
			client_print(id, print_center, "This item can be purchased only %i times per map.", USES_PER_MAP)
			return ZP_PLUGIN_HANDLED
		}
		
		if(g_iRoundUses >= USES_PER_ROUND)
		{
			client_print(id, print_center, "This item can be purchased only %i times per round.", USES_PER_ROUND)
			return ZP_PLUGIN_HANDLED
		}
		
		g_iMapUses++
		g_iRoundUses++
		
		new szName[32]
		get_user_name(id, szName, charsmax(szName))
		zp_make_user_nemesis(id)
		set_hudmessage(255, 0, 0, -1.0, 0.01)
		show_hudmessage(0, "Alert! %s became a NEMESIS!", szName)
	}
	
	return PLUGIN_CONTINUE
}

[Dachoni]

Някаква квар до начало на инфекцията за плъгина има ли за промяна?

[OciXCrom]

Смисъл? Нали искаш да може да се купува само преди инфекцията?

[Dachoni]

Не ми пасва с това от мода, освен това дава само веднъж да се направиш немесис на следващия рунд пише преди да тръгне инфекцията това:

Код за потвърждение: Избери целия код

This item can only be purchased before the infection

------редакция на поста-----
Оправих се благодаря за редакцията на кода!