Effect on kill

[HeatoN]

Ако може да се направи ефекта само при Headshot

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <hamsandwich>
#include <fakemeta>

new gCKP

public plugin_init() 
{
	register_plugin("Killing Particles", "1.01", "metallicawOw")  
	
	// Hams
	RegisterHam(Ham_Killed, "player", "fw_PlayerKilled") 
	
	// Enable/Disable the plugin
	gCKP = register_cvar("gc_kp_enable", "1")
}

public fw_PlayerKilled(victim, attacker, shouldgib)
{
	if(!is_user_connected(attacker) || !is_user_connected(victim) || attacker == victim || !attacker)
	return HAM_IGNORED;
	
	if(get_pcvar_num(gCKP))		
	{
		static Float:FOrigin3[3] 
		pev(victim, pev_origin, FOrigin3)
		
		engfunc(EngFunc_MessageBegin, MSG_PVS, SVC_TEMPENTITY, FOrigin3, 0)
		write_byte(TE_IMPLOSION)
		engfunc(EngFunc_WriteCoord, FOrigin3[0])
		engfunc(EngFunc_WriteCoord, FOrigin3[1])
		engfunc(EngFunc_WriteCoord, FOrigin3[2])
		write_byte(200)
		write_byte(100)
		write_byte(5)  
		message_end()
		
		engfunc(EngFunc_MessageBegin, MSG_PVS, SVC_TEMPENTITY, FOrigin3, 0)
		write_byte(TE_PARTICLEBURST) // TE id
		engfunc(EngFunc_WriteCoord, FOrigin3[0]) // x
		engfunc(EngFunc_WriteCoord, FOrigin3[1]) // y
		engfunc(EngFunc_WriteCoord, FOrigin3[2]) // z
		write_short(50) // radius
		write_byte(72) // color
		write_byte(6) // duration (will be randomized a bit)
		message_end()
	}  
	return PLUGIN_HANDLED
} 

[illusion]

Пробвай така, никва идея дали ще бачка

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <fakemeta>

new gCKP

public plugin_init() 
{
	register_plugin("Killing Particles", "1.01", "metallicawOw / edit - ABSTRACT")  
	
	// HS Event
	register_event("DeathMsg", "eventDeathMsg", "a")
	
	// Enable/Disable the plugin
	gCKP = register_cvar("gc_kp_enable", "1")
}

public eventDeathMsg()
{
	new iKiller = read_data(1), iVictim = read_data(2)
	new iHeadshot = read_data(3)

	if(!is_user_connected(iKiller) || iKiller == iVictim)
		return PLUGIN_CONTINUE;
	
	if(get_pcvar_num(gCKP) && iHeadshot)		
	{
		static Float:FOrigin3[3] 
		pev(iVictim, pev_origin, FOrigin3)
		
		engfunc(EngFunc_MessageBegin, MSG_PVS, SVC_TEMPENTITY, FOrigin3, 0)
		write_byte(TE_IMPLOSION)
		engfunc(EngFunc_WriteCoord, FOrigin3[0])
		engfunc(EngFunc_WriteCoord, FOrigin3[1])
		engfunc(EngFunc_WriteCoord, FOrigin3[2])
		write_byte(200)
		write_byte(100)
		write_byte(5)  
		message_end()
		
		engfunc(EngFunc_MessageBegin, MSG_PVS, SVC_TEMPENTITY, FOrigin3, 0)
		write_byte(TE_PARTICLEBURST) // TE id
		engfunc(EngFunc_WriteCoord, FOrigin3[0]) // x
		engfunc(EngFunc_WriteCoord, FOrigin3[1]) // y
		engfunc(EngFunc_WriteCoord, FOrigin3[2]) // z
		write_short(50) // radius
		write_byte(72) // color
		write_byte(6) // duration (will be randomized a bit)
		message_end()
	}  
	return PLUGIN_HANDLED
} 

[HeatoN]

Благодаря, ти може да локнеш