Counter-Strike 1.6
FIREZONE # ZOMBIE BIOHAZARD © [MULTIMOD] INFECTION ®
45.144.155.91:27015
zm_nuke_zg
Играчи: 14/32
zm_nuke_zg
Counter-Strike 1.6
HH-GaminG.EU #One Bullet 45.144.155.102:27020 fy_simpsons Играчи: 8/21
Counter-Strike 1.6
CS1.BG | DUST2 NOSHTA GARMI [RANKED PLAY] 45.144.155.113:27015 de_dust2 Играчи: 0/31
Counter-Strike 1.6
Cs-PlovdiV.com - Aim Attack 93.123.16.4:27022 aim_sOt Играчи: 0/16
Counter-Strike 1.6
VIP
45.144.155.171:27015 ★ [ZM]ImperialCS Zombie Plague Mega|Fast SaveAP Jetpack+GoldenAK zm_infantry_bns 16/32

Заявка за VIP Knife Plugin

В този раздел можете да подавате всякакви заявки за намиране, изработка или преработка на плъгини/модове.
Аватар
Shokub2k
Извън линия
Потребител
Потребител
Мнения: 13
Регистриран на: 28 Юли 2023, 18:49
Се отблагодари: 1 път
Получена благодарност: 1 път
Обратна връзка:

Заявка за VIP Knife Plugin

Мнение от Shokub2k » 16 Сеп 2023, 11:34

VIP Knife Plugin трябва да работи по-следния начин: Играч със нужния флаг при влизане във сървъра веднага да му се даде ножа. Да има в него P и V модели и също ако може да се сложи избор за звуци за самият нож. Смисъл аз да си слагам собствени звуци. И ако може да се добави 2xdamage, Knockback, 280speed и Gravity но когато е със ножа а когато е с други оръжия да ги няма тези магий. Само на когато е на нож да ги има.

Аватар
Hurricane
Извън линия
AMXX Скриптър
AMXX Скриптър
Мнения: 224
Регистриран на: 04 Юни 2022, 21:18
Се отблагодари: 21 пъти
Получена благодарност: 83 пъти

Re: Заявка за VIP Knife Plugin

Мнение от Hurricane » 17 Сеп 2023, 00:13

Тествано работи, пробвай и ако има нещо пиши в темата

Трябва да отправиш благодарностите си към Huehue

Промяна на админ флаг

Код за потвърждение: Избери целия код

bind_pcvar_string(create_cvar("ka_vip_access_flag", "m"), g_pCvar_VipFlag, charsmax(g_pCvar_VipFlag))
Където m заместваш c твоя флаг.

Звуците си ги избираш от тук

Код за потвърждение: Избери целия код

new const g_szKnife_Sounds_Custom[][] =
{
	"weapons/knife_deploy1.wav",
	"weapons/knife_hit1.wav",
	"weapons/knife_hit2.wav",
	"weapons/knife_hit3.wav",
	"weapons/knife_hit4.wav",
	"weapons/knife_hitwall1.wav",
	"weapons/knife_slash1.wav",
	"weapons/knife_slash2.wav",
	"weapons/knife_stab.wav"
}
А моделите от тук ?

Код за потвърждение: Избери целия код

new const g_szKnife_Models[eKnifeType][] =
{
	"models/v_knife.mdl",
	"models/p_knife.mdl"
}

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

#define VERSION "1.0.0"

new Float:g_pCvar_Gravity, Float:g_pCvar_Speed, Float:g_pCvar_Damage, g_pCvar_Knockback_Power, Float:g_pCvar_Knockback_Speed, g_pCvar_VipFlag[2]

enum _:eKnifeType
{
	V, P
}

new const g_szKnife_Models[eKnifeType][] =
{
	"models/v_knife.mdl",
	"models/p_knife.mdl"
}

new const g_szKnife_Sounds_Original[][] =
{
	"weapons/knife_deploy1.wav",
	"weapons/knife_hit1.wav",
	"weapons/knife_hit2.wav",
	"weapons/knife_hit3.wav",
	"weapons/knife_hit4.wav",
	"weapons/knife_hitwall1.wav",
	"weapons/knife_slash1.wav",
	"weapons/knife_slash2.wav",
	"weapons/knife_stab.wav"
}
new const g_szKnife_Sounds_Custom[][] =
{
	"weapons/knife_deploy1.wav",
	"weapons/knife_hit1.wav",
	"weapons/knife_hit2.wav",
	"weapons/knife_hit3.wav",
	"weapons/knife_hit4.wav",
	"weapons/knife_hitwall1.wav",
	"weapons/knife_slash1.wav",
	"weapons/knife_slash2.wav",
	"weapons/knife_stab.wav"
}

public plugin_init()
{
	register_plugin("VIP Knife Ability", VERSION, "Huehue @ AMXX-BG.INFO")
	
	register_event("CurWeapon", "Event_CurWeapon", "be", "1=1")

	RegisterHam(Ham_TakeDamage, "player", "CBase_Ham_TakeDamage", false)

	register_forward(FM_EmitSound, "Hook_FM_EmitSound", false)

	bind_pcvar_float(create_cvar("ka_gravity", "600.0"), g_pCvar_Gravity)
	bind_pcvar_float(create_cvar("ka_speed", "280.0"), g_pCvar_Speed)
	bind_pcvar_float(create_cvar("ka_damage", "2"), g_pCvar_Damage)
	bind_pcvar_num(create_cvar("ka_knockback_power", "1000"), g_pCvar_Knockback_Power)
	bind_pcvar_float(create_cvar("ka_knockback_speed", "500.0"), g_pCvar_Knockback_Speed)
	bind_pcvar_string(create_cvar("ka_vip_access_flag", "m"), g_pCvar_VipFlag, charsmax(g_pCvar_VipFlag))
}

public plugin_precache()
{
	new i

	for (i = 0; i < sizeof g_szKnife_Models; i++) 
		precache_model(g_szKnife_Models[i])

	for (i = 0; i < sizeof g_szKnife_Sounds_Custom; i++)
		precache_sound(g_szKnife_Sounds_Custom[i])
}

public Event_CurWeapon(id)
{
	if (!is_user_connected(id) || !is_user_vip(id))
		return PLUGIN_HANDLED

	new iWeapon = read_data(2)

	if (iWeapon == CSW_KNIFE)
	{
		set_pev(id, pev_viewmodel2, g_szKnife_Models[V])
		set_pev(id, pev_weaponmodel2, g_szKnife_Models[P])

		new Float:flGravity = g_pCvar_Gravity / 800.0
			
		set_pev(id, pev_maxspeed, g_pCvar_Speed)
		set_pev(id, pev_gravity, flGravity)
	}
	else
	{
		ExecuteHamB(Ham_CS_Player_ResetMaxSpeed, id)
		set_pev(id, pev_gravity, 1.0)
	}
	return PLUGIN_HANDLED
}

public CBase_Ham_TakeDamage(iVictim, Inflictor, iAttacker, Float:flDamage, iDamageBits)
{
	if (!is_user_connected(iAttacker) || get_user_weapon(iAttacker) != CSW_KNIFE || iVictim == iAttacker)
		return HAM_IGNORED

	SetHamParamFloat(4, flDamage * g_pCvar_Damage)

	new Float:fVelocity[3]
	velocity_by_aim(iAttacker, g_pCvar_Knockback_Power, fVelocity)
	fVelocity[2] = g_pCvar_Knockback_Speed
	set_pev(iVictim, pev_velocity, fVelocity)

	return HAM_IGNORED
}

public Hook_FM_EmitSound(id, iChannel, szSample[], Float:flVolume, Float:flAttn, iFlag, iPitch)
{
	if (!is_user_connected(id))
		return FMRES_IGNORED

	for (new i = 0; i < sizeof g_szKnife_Sounds_Custom; i++)
	{
		if (equal(szSample, g_szKnife_Sounds_Original[i]))
		{
			emit_sound(id, iChannel, g_szKnife_Sounds_Custom[i], flVolume, flAttn, iFlag, iPitch)
			return FMRES_SUPERCEDE
		}
	}
	return FMRES_IGNORED
}

stock bool:is_user_vip(id)
{
	if (get_user_flags (id) & read_flags(g_pCvar_VipFlag))
		return true

	return false
}
function calculateStatistics() {
    const numWars = 15;
    const totalYearsOfWar = 135;
    const yearsUnderOppression = 500;

    return [numWars, totalYearsOfWar, yearsUnderOppression];
}

function main() {
    const [numWars, totalYearsOfWar, yearsUnderOppression] = calculateStatistics();

    console.log("България над всичко!");
}

main();


Аватар
Shokub2k
Извън линия
Потребител
Потребител
Мнения: 13
Регистриран на: 28 Юли 2023, 18:49
Се отблагодари: 1 път
Получена благодарност: 1 път
Обратна връзка:

Re: Заявка за VIP Knife Plugin

Мнение от Shokub2k » 18 Сеп 2023, 02:26

Още тая вечер ще го пробвам и ще пиша за проблеми.
Иначе благодаря много!

Публикувай отговор
  • Подобни теми
    Отговори
    Преглеждания
     Последно мнение

Обратно към “Заявки за плъгини”

Кой е на линия

Потребители разглеждащи този форум: 0 регистрирани и 8 госта