Заявка за плъгин LAST-MAN

[Siska]

Здравейте ! Така както е кода работи при гърмене на ц4. Може ли да се направи да не работи при взривяване на ц4 , защото бомбата може да взриви много хора едновременно и се объркват нещата в такава ситуация ?

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <amxmisc>
#define CC_COLORS_TYPE CC_COLORS_SHORT
#include <cromchat>

enum _:LastSounds {
	Sound_T = 0,
	Sound_CT,
	Sound_Duel
}

new const last_sound[LastSounds][] = {
 	"radio/last_man_standing6.wav",
 	"radio/last_man_standing3.wav",
	"radio/peptalk6.wav"
}


new chat_messages[][] = {
	"!t%n !nis the last one standing!",
	"!t%n!n's teammates were killed. Good Luck!",
	"!t%n !nnow you are alone."
}

new chat_duel_messages[][] = {
	"!t%n !nvs !t%n"
}

new g_Announced[MAX_PLAYERS + 1] = {false, ...}
new g_pCvarMinPlayers

public plugin_init()
{
	register_plugin("Last Man Standing", "1.0", "YankoNL")

	register_event("DeathMsg", "death_msg", "a")
	register_logevent("OnRoundStart", 2, "1=Round_Start")

	g_pCvarMinPlayers = register_cvar("lms_min_players", "8")
}

public plugin_precache()
{
	for (new i = 0; i < sizeof last_sound; i++)
	{
		precache_sound(last_sound[i])
	}
}

public OnRoundStart()
{
	arrayset(g_Announced, false, sizeof (g_Announced))
}

public death_msg(id)
{
	if (get_playersnum() < get_pcvar_num(g_pCvarMinPlayers))
		return

	new CTCount = get_playersnum_ex(GetPlayers_ExcludeDead | GetPlayers_MatchTeam, "CT")
	new TCount = get_playersnum_ex(GetPlayers_ExcludeDead | GetPlayers_MatchTeam, "TERRORIST")

	new playersTeam

	if (CTCount == 1 && TCount == 1)
	{
		new players[MAX_PLAYERS], playersnum_unused;
		get_players_ex(players, playersnum_unused, GetPlayers_ExcludeDead)
		CC_SendMessage(0, chat_duel_messages[random(sizeof(chat_duel_messages))], players[0], players[1])
		client_cmd(0, "spk %s", last_sound[Sound_Duel])
		return
	}
	else if (CTCount == 1) {
		playersTeam = 1;
	}
	else if (TCount == 1) {
		playersTeam = 0;
	}
	else {
		return
	}

	new const playersTeams[][] = {
		"TERRORIST",
		"CT"
	}

	new players[MAX_PLAYERS], playersnum_unused;
	get_players_ex(players, playersnum_unused, GetPlayers_ExcludeDead | GetPlayers_MatchTeam, playersTeams[playersTeam])

	if (!g_Announced[players[0]])
	{
		CC_SendMessage(0, chat_messages[random(sizeof(chat_messages))], players[0])
		client_cmd(players[0], "spk %s", last_sound[_:LastSounds:playersTeam])
		g_Announced[players[0]] = true
	}
}