Заявка за редакция на плъгин

В този раздел можете да подавате всякакви заявки за намиране, изработка или преработка на плъгини/модове.
Аватар
Carebear
Извън линия
Потребител
Потребител
Мнения: 1
Регистриран на: 19 Яну 2022, 23:36
Се отблагодари: 1 път

Заявка за редакция на плъгин

Мнение от Carebear » 20 Яну 2022, 09:11

Здравейте, ако може бих искал да се добави в следния плъгин да се ползва само от играчи с флаг (t), както и като си вземат оръжията от следното меню, ако са терористи да не им премахва Ц4, а ако са ЦТ да им дава и кит. Ще го прилагам в класик сървър и ако има такава опция първия рунд менюто да не работи за въпросните играчи, ако не, не е проблем. Благодаря!

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <hamsandwich>
#include <cstrike>
#include <fun>

#define PLUGIN_NAME "BonusWeapons"
#define PLUGIN_VERSION "1.0"
#define PLUGIN_AUTHOR "miDnight"

#define ARMOR 100

#define MENU_TITLE "\yBonusWep Menu"
#define MENU_ITEM1 "M4A1 + Deagle"
#define MENU_ITEM2 "AK47 + Deagle"
#define MENU_EXITNAME "Exit"

#define AK47_BPAMMO 90
#define M4A1_BPAMMO 90
#define DEAGLE_BPAMMO 35


public plugin_init()
{
	register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR)
	RegisterHam(Ham_Spawn, "player", "eventPlayerSpawn", 1)
	
}

public eventPlayerSpawn(id)
{
	if(is_user_alive(id))
	{
		
		{
			cs_set_user_armor(id, ARMOR, CS_ARMOR_VESTHELM)
			
			give_item(id, "weapon_hegrenade")
			give_item(id, "weapon_flashbang")
			give_item(id, "weapon_flashbang")
			
			freeWeaponsMenu(id)
		}
	}
}

public freeWeaponsMenu(id)
{
	new menu = menu_create(MENU_TITLE, "giveWeapons")
	
	menu_additem(menu, MENU_ITEM1, "1", 0)
	menu_additem(menu, MENU_ITEM2, "2", 0)
	menu_addblank(menu, 0)
	menu_additem(menu, MENU_EXITNAME, "3", 0)
	
	menu_setprop(menu, MPROP_EXIT, MEXIT_NEVER)
	menu_display(id, menu, 0)
}

public giveWeapons(id, menu, item)
{
	new data[6], name[64], access, callback
	
	menu_item_getinfo(menu, item, access, data, charsmax(data), name, charsmax(name), callback)
	
	new key = str_to_num(data)
	
	switch(key)
	{
		case 1:
		{
			strip_and_give_knife(id)
			give_item(id, "weapon_ak47")
			give_item(id, "weapon_deagle")
			cs_set_user_bpammo(id, CSW_AK47, AK47_BPAMMO)
			cs_set_user_bpammo(id, CSW_DEAGLE, DEAGLE_BPAMMO)
		}
		case 2:
		{
			strip_and_give_knife(id)
			give_item(id, "weapon_m4a1")
			give_item(id, "weapon_deagle")
			cs_set_user_bpammo(id, CSW_M4A1, M4A1_BPAMMO)
			cs_set_user_bpammo(id, CSW_DEAGLE, DEAGLE_BPAMMO)
		}
	}
	
	menu_destroy(menu)
	return PLUGIN_HANDLED;
}

strip_and_give_knife(const id)
{
	strip_user_weapons(id)
	give_item(id, "weapon_knife")
}

Аватар
OciXCrom
Извън линия
Администратор
Администратор
Мнения: 7206
Регистриран на: 06 Окт 2016, 19:20
Местоположение: /resetscore
Се отблагодари: 117 пъти
Получена благодарност: 1295 пъти
Обратна връзка:

Заявка за редакция на плъгин

Мнение от OciXCrom » 23 Яну 2022, 22:12

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <hamsandwich>
#include <cstrike>
#include <fun>

#define PLUGIN_NAME "BonusWeapons"
#define PLUGIN_VERSION "1.0"
#define PLUGIN_AUTHOR "miDnight"

/* Edit by OciXCrom:
 * Add C4 for Terrorists
 * Add Defuse kit for Counter-Terrorists
 * Make for admin flag T only
 * Work only after 1st round
 * Fix grenades */

#define ARMOR 100

#define MENU_TITLE "\yBonusWep Menu"
#define MENU_ITEM1 "M4A1 + Deagle"
#define MENU_ITEM2 "AK47 + Deagle"
#define MENU_EXITNAME "Exit"
#define MENU_FLAG ADMIN_LEVEL_H
#define MENU_ROUND 1

#define AK47_BPAMMO 90
#define M4A1_BPAMMO 90
#define DEAGLE_BPAMMO 35

new current_round

public plugin_init()
{
	register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR)
	RegisterHam(Ham_Spawn, "player", "eventPlayerSpawn", 1)
	register_logevent("OnRoundStart", 2, "0=World triggered", "1=Round_Start")
	register_logevent("OnFirstRound", 2, "0=World triggered", "1&Restart_Round_")
	register_logevent("OnFirstRound", 2, "0=World triggered", "1=Game_Commencing")
}

public OnFirstRound()
{
	current_round = 0
}

public OnRoundStart()
{
	current_round++
}

public eventPlayerSpawn(id)
{
	if(current_round > MENU_ROUND && is_user_alive(id) && get_user_flags(id) & MENU_FLAG)
	{
		{
			freeWeaponsMenu(id)
			cs_set_user_armor(id, ARMOR, CS_ARMOR_VESTHELM)
		}
	}
}

public freeWeaponsMenu(id)
{
	new menu = menu_create(MENU_TITLE, "giveWeapons")
	
	menu_additem(menu, MENU_ITEM1, "1", 0)
	menu_additem(menu, MENU_ITEM2, "2", 0)
	menu_addblank(menu, 0)
	menu_additem(menu, MENU_EXITNAME, "3", 0)
	
	menu_setprop(menu, MPROP_EXIT, MEXIT_NEVER)
	menu_display(id, menu, 0)
}

public giveWeapons(id, menu, item)
{
	if(is_user_alive(id))
	{
		new data[6], name[64], access, callback
		
		menu_item_getinfo(menu, item, access, data, charsmax(data), name, charsmax(name), callback)
		
		new key = str_to_num(data)
		
		switch(key)
		{
			case 1:
			{
				strip_and_give_knife(id)
				give_item(id, "weapon_ak47")
				give_item(id, "weapon_deagle")
				cs_set_user_bpammo(id, CSW_AK47, AK47_BPAMMO)
				cs_set_user_bpammo(id, CSW_DEAGLE, DEAGLE_BPAMMO)
			}
			case 2:
			{
				strip_and_give_knife(id)
				give_item(id, "weapon_m4a1")
				give_item(id, "weapon_deagle")
				cs_set_user_bpammo(id, CSW_M4A1, M4A1_BPAMMO)
				cs_set_user_bpammo(id, CSW_DEAGLE, DEAGLE_BPAMMO)
			}
		}
	}
		
	menu_destroy(menu)
	return PLUGIN_HANDLED;
}

strip_and_give_knife(const id)
{
	new c4 = user_has_weapon(id, CSW_C4)

	strip_user_weapons(id)
	give_item(id, "weapon_knife")

	if(c4)
	{
		give_item(id, "weapon_c4")
		cs_set_user_plant(id)
	}

	if(cs_get_user_team(id) == CS_TEAM_CT)
	{
		give_item(id, "item_thighpack")
	}

	give_item(id, "weapon_hegrenade")
	give_item(id, "weapon_flashbang")
	give_item(id, "weapon_flashbang")
}

Публикувай отговор
  • Подобни теми
    Отговори
    Преглеждания
     Последно мнение

Обратно към “Заявки за плъгини”

Кой е на линия

Потребители разглеждащи този форум: Bing [Bot] и 17 госта