Заявка за изработване на show round и ct - t win

[VOVERAX]

подобно на тази снимка да изглежда http://prikachi.com/images.php?images/965/9054965A.jpg

[OciXCrom]

Код за потвърждение: Избери целия код

#include <amxmodx>

#if AMXX_VERSION_NUM < 183
    #include <dhudmessage>
#endif

#define HUD_ROUND 255, 255, 255, -1.0, 0.1, 0, 0.5, 1.0
#define HUD_SCORE_CT 114, 199, 255, 0.45, 0.05, 0, 0.5, 1.0
#define HUD_SCORE_T 220, 205, 105, 0.55, 0.05, 0, 0.5, 1.0

new g_iMaxRounds,
    g_iRound,
    g_iWinsT,
    g_iWinsCT,
    g_iObject

public plugin_init()
{
    register_plugin("Game Info on HUD", "1.0", "OciXCrom @ amxx-bg.info/forum")
    
    register_logevent("OnFirstRound", 2, "0=World triggered", "1&Restart_Round_")
    register_logevent("OnFirstRound", 2, "0=World triggered", "1=Game_Commencing")
    register_logevent("OnRoundStart", 2, "0=World triggered", "1=Round_Start")
    register_event("SendAudio", "OnTeamWin", "a", "2&%!MRAD_terwin", "2&%!MRAD_ctwin")
    
    set_task(1.0, "DisplayInfo", .flags = "b")
    g_iObject = CreateHudSyncObj()
}

public plugin_cfg()
    g_iMaxRounds = get_cvar_num("mp_maxrounds")

public OnFirstRound()
{
    g_iRound = 0
    g_iWinsT = 0
    g_iWinsCT = 0
}

public OnRoundStart()
    g_iRound++
    
public OnTeamWin()
{
    static szTeam[9]
    read_data(2, szTeam, charsmax(szTeam))
    client_print(0, print_chat, szTeam)
    
    switch(szTeam[7])
    {
        case 'c': g_iWinsCT++
        case 't': g_iWinsT++
    }
}

public DisplayInfo()
{
    set_hudmessage(HUD_ROUND)
    
    if(g_iMaxRounds)
        ShowSyncHudMsg(0, g_iObject, "Round %i/%i", g_iRound, g_iMaxRounds)
    else
        ShowSyncHudMsg(0, g_iObject, "Round %i", g_iRound)
        
    set_dhudmessage(HUD_SCORE_CT)
    show_dhudmessage(0, "%i", g_iWinsCT)
    
    set_dhudmessage(HUD_SCORE_T)
    show_dhudmessage(0, "%i", g_iWinsT)
} 

[VOVERAX]

Не мога да го компилирам http://prikachi.com/images.php?images/577/9055577l.jpg

[JustInCase]

Изтегли си библиотеката dhudmessage.inc

[VOVERAX]

Благодаря може да