cshop item + skin

[deadlylord]

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cstrike>
#include <customshop>
#include <hamsandwich>

additem ITEM_MORE_DAMAGE
new g_bMoreDamage[33]
new g_szDamage[16]

public plugin_init()
{
    register_plugin("CSHOP: More Damage", "1.0", "OciXCrom @ amxx-bg.info/forum")
    RegisterHam(Ham_TakeDamage, "player", "PreTakeDamage")
    cshop_get_string(ITEM_MORE_DAMAGE, "Amount", g_szDamage, charsmax(g_szDamage))
}

public plugin_precache()
{
    ITEM_MORE_DAMAGE = cshop_register_item("zombiedamage2", "+25% Damage", 6000)
    cshop_set_string(ITEM_MORE_DAMAGE, "Amount", "+25%")
}

public cshop_item_selected(id, iItem)
{
    if(iItem == ITEM_MORE_DAMAGE)
        g_bMoreDamage[id] = true
}

public cshop_item_removed(id, iItem)
{
	if(iItem == ITEM_MORE_DAMAGE)
		g_bMoreDamage[id] = false
}

public client_putinserver(id)
    g_bMoreDamage[id] = false
    
public PreTakeDamage(iVictim, iInflictor, iAttacker, Float:flDamage, iDamageBits)
{
    if(is_user_alive(iAttacker) && iAttacker != iVictim && g_bMoreDamage[iAttacker])
        SetHamParamFloat(4, math_add_f(flDamage, g_szDamage))
}

Float:math_add_f(Float:fNum, const szMath[])
{
    static szNewMath[16], Float:fMath, bool:bPercent, cOperator
    
    copy(szNewMath, charsmax(szNewMath), szMath)
    bPercent = szNewMath[strlen(szNewMath) - 1] == '%'
    cOperator = szNewMath[0]
    
    if(!isdigit(szNewMath[0]))
        szNewMath[0] = ' '
    
    if(bPercent)
        replace(szNewMath, charsmax(szNewMath), "%", "")
        
    trim(szNewMath)
    fMath = str_to_float(szNewMath)
    
    if(bPercent)
        fMath *= fNum / 100
        
    switch(cOperator)
    {
        case '+': fNum += fMath
        case '-': fNum -= fMath
        case '/': fNum /= fMath
        case '*': fNum *= fMath
        default: fNum = fMath
    }
    
    return fNum
} 

http://gamebanana.com/skins/141107

Може ли този скин да се добави в кода, тоест, като човека си купи предмета да се променя скина на ножа?

[OciXCrom]

models/custom_shop/v_katana.mdl

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cstrike>
#include <customshop>
#include <fakemeta>
#include <hamsandwich>

additem ITEM_MORE_DAMAGE
new g_bMoreDamage[33]
new g_szDamage[16]
new const g_szKnife[] = "models/custom_shop/v_katana.mdl"

public plugin_init()
{
    register_plugin("CSHOP: More Damage", "1.0", "OciXCrom @ amxx-bg.info/forum")
    register_event("CurWeapon", "OnSelectKnife", "be", "1=1", "2=29")
    RegisterHam(Ham_TakeDamage, "player", "PreTakeDamage")
    cshop_get_string(ITEM_MORE_DAMAGE, "Amount", g_szDamage, charsmax(g_szDamage))
}

public plugin_precache()
{
    ITEM_MORE_DAMAGE = cshop_register_item("zombiedamage2", "+25% Damage", 6000)
    cshop_set_string(ITEM_MORE_DAMAGE, "Amount", "+25%")
    precache_model(g_szKnife)
}

public cshop_item_selected(id, iItem)
{
    if(iItem == ITEM_MORE_DAMAGE)
        g_bMoreDamage[id] = true
}

public cshop_item_removed(id, iItem)
{
   if(iItem == ITEM_MORE_DAMAGE)
      g_bMoreDamage[id] = false
}

public client_putinserver(id)
    g_bMoreDamage[id] = false
    
public OnSelectKnife(id)
{
    if(g_bMoreDamage[id])
        set_pev(id, pev_viewmodel2, g_szKnife)
}
   
public PreTakeDamage(iVictim, iInflictor, iAttacker, Float:flDamage, iDamageBits)
{
    if(is_user_alive(iAttacker) && iAttacker != iVictim && g_bMoreDamage[iAttacker])
        SetHamParamFloat(4, math_add_f(flDamage, g_szDamage))
}

Float:math_add_f(Float:fNum, const szMath[])
{
    static szNewMath[16], Float:fMath, bool:bPercent, cOperator
   
    copy(szNewMath, charsmax(szNewMath), szMath)
    bPercent = szNewMath[strlen(szNewMath) - 1] == '%'
    cOperator = szNewMath[0]
   
    if(!isdigit(szNewMath[0]))
        szNewMath[0] = ' '
   
    if(bPercent)
        replace(szNewMath, charsmax(szNewMath), "%", "")
       
    trim(szNewMath)
    fMath = str_to_float(szNewMath)
   
    if(bPercent)
        fMath *= fNum / 100
       
    switch(cOperator)
    {
        case '+': fNum += fMath
        case '-': fNum -= fMath
        case '/': fNum /= fMath
        case '*': fNum *= fMath
        default: fNum = fMath
    }
   
    return fNum
}  

[deadlylord]

Значи кода работи, обаче тъй като сменям от нож на нож, скина се показва след 5-10 секунди, а някой път дори и не се показва

Също така като натисни Q, маха скина, обаче като се замисля, това което исках е глупаво, защото дори и човека да го вижда не се вижда в ръката му тъй като е зомби, този проблем може ли да се оправи и оръжието да излиза?

[OciXCrom]

В ръката не се вижда защото скинът няма p_ модел, съответно намери си такъв, който има. Не виждам причина да се показва след 5-10 секунди. Щом модът сменя скиновете на ръцете - ще си пречат.

[deadlylord]

Намерих скин с двата модела -> http://dox.bg/files/dw?a=deb6183b35 то на мен като цяло ми е по важен p_ модела, би било прекрасно да може да се вижда, когато предмета е купен(тоест да работи като индикатор), благодаря предварително

[OciXCrom]

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cstrike>
#include <customshop>
#include <fakemeta>
#include <hamsandwich>

additem ITEM_MORE_DAMAGE
new g_bMoreDamage[33]
new g_szDamage[16]
new const g_szKnifeV[] = "models/custom_shop/v_katana.mdl"
new const g_szKnifeP[] = "models/custom_shop/p_katana.mdl"

public plugin_init()
{
    register_plugin("CSHOP: More Damage", "1.0", "OciXCrom @ amxx-bg.info/forum")
    register_event("CurWeapon", "OnSelectKnife", "be", "1=1", "2=29")
    RegisterHam(Ham_TakeDamage, "player", "PreTakeDamage")
    cshop_get_string(ITEM_MORE_DAMAGE, "Amount", g_szDamage, charsmax(g_szDamage))
}

public plugin_precache()
{
    ITEM_MORE_DAMAGE = cshop_register_item("zombiedamage2", "+25% Damage", 6000)
    cshop_set_string(ITEM_MORE_DAMAGE, "Amount", "+25%")
    precache_model(g_szKnifeV)
    precache_model(g_szKnifeP)
}

public cshop_item_selected(id, iItem)
{
    if(iItem == ITEM_MORE_DAMAGE)
        g_bMoreDamage[id] = true
}

public cshop_item_removed(id, iItem)
{
   if(iItem == ITEM_MORE_DAMAGE)
      g_bMoreDamage[id] = false
}

public client_putinserver(id)
    g_bMoreDamage[id] = false
    
public OnSelectKnife(id)
{
    if(g_bMoreDamage[id])
    {
        set_pev(id, pev_viewmodel2, g_szKnifeV)
        set_pev(id, pev_weaponmodel2, g_szKnifeP)
    }
}
   
public PreTakeDamage(iVictim, iInflictor, iAttacker, Float:flDamage, iDamageBits)
{
    if(is_user_alive(iAttacker) && iAttacker != iVictim && g_bMoreDamage[iAttacker])
        SetHamParamFloat(4, math_add_f(flDamage, g_szDamage))
}

Float:math_add_f(Float:fNum, const szMath[])
{
    static szNewMath[16], Float:fMath, bool:bPercent, cOperator
   
    copy(szNewMath, charsmax(szNewMath), szMath)
    bPercent = szNewMath[strlen(szNewMath) - 1] == '%'
    cOperator = szNewMath[0]
   
    if(!isdigit(szNewMath[0]))
        szNewMath[0] = ' '
   
    if(bPercent)
        replace(szNewMath, charsmax(szNewMath), "%", "")
       
    trim(szNewMath)
    fMath = str_to_float(szNewMath)
   
    if(bPercent)
        fMath *= fNum / 100
       
    switch(cOperator)
    {
        case '+': fNum += fMath
        case '-': fNum -= fMath
        case '/': fNum /= fMath
        case '*': fNum *= fMath
        default: fNum = fMath
    }
   
    return fNum
} 

[deadlylord]

Работи, обаче ако се купи от нож и не работи, в златния калашник този проблем е оправен, може ли да бъде оправен и на този предмет ?

[OciXCrom]

Както казах - модът променя скина на ръцете, съответно двата плъгина си пречат. Калашника не го пипа, затова работи.

[deadlylord]

Добре тогава може ли да се направи зомбитата да имат нормален нож и да си работи този допълнителен предмет

[OciXCrom]

Качи кода на главния мод.