Добавяне на звук (I am blind) в ReAPI Team Flash Snitch

В този раздел можете да подавате всякакви заявки за намиране, изработка или преработка на плъгини/модове.
Заключено
Аватар
LoShIaA
Извън линия
Потребител
Потребител
Мнения: 323
Регистриран на: 20 Окт 2016, 14:44
Местоположение: Стара Загора
Се отблагодари: 120 пъти
Получена благодарност: 8 пъти

Добавяне на звук (I am blind) в ReAPI Team Flash Snitch

Мнение от LoShIaA » 07 Окт 2017, 12:58

Здравейте. Някой може ли да ми добави звукът, който съм прикачил и квар команда с, която мога да пускам и спирам дали да се чува звъкът. Общо взето да стане както е в стария плъгин.
Ето го плъгина: Тема: Team Flash Snitch
Ето го кода:

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <reapi>
#include <WPMGPrintChatColor>

new const g_MsgPrefix[] = "[Team Flash Snitch]"

const BLINDED_PARTLY = 200
const BLINDED_FULLY = 255

new g_szName[33][32]

public plugin_init() 
{
	register_plugin("[ReAPI] Team Flash Snitch", "1.0", "WaLkZ")
	
	RegisterHookChain(RG_PlayerBlind, "PlayerBlind", .post = true)
	RegisterHookChain(RG_CBasePlayer_SetClientUserInfoName, "CBasePlayer_SetUserInfoName", .post = true)
}

public client_putinserver(id)
{
	get_user_name(id, g_szName[id], charsmax(g_szName[]))
}

public CBasePlayer_SetUserInfoName(const id, infobuffer[], szNewName[])
{
	if (!equal(g_szName[id], szNewName))
	{
		copy(g_szName[id], charsmax(g_szName[]), szNewName)
	}
}

public PlayerBlind(const iFlashed, const iInflictor, const iFlasher, const Float:fFadeTime, const Float:fFadeHold, const iAlpha, Float:fColor[3])
{
	if (iFlashed == iFlasher)
	{
		return HC_CONTINUE
	}
	
	if (get_member(iFlashed, m_iTeam) == get_member(iFlasher, m_iTeam))
	{		
		PrintChatColor(iFlashed, PRINT_COLOR_PLAYERTEAM, "!g%s You have been teamflashed by !t%s", g_MsgPrefix, g_szName[iFlasher])
		PrintChatColor(iFlasher, PRINT_COLOR_PLAYERTEAM, "!g%s You have %s flashed a teammate !t%s", g_MsgPrefix, iAlpha == BLINDED_FULLY ? "totally" : "partly", g_szName[iFlashed])	
	}
	
	return HC_CONTINUE
}
Въпросния квар:
tfs_sound
0 - Звука изключен
1 - Звука включен

Самият звук:
im_blind.wav
(17.06 KiB) Свалено 104 пъти
im_blind.wav
(17.06 KiB) Свалено 104 пъти

Аватар
OciXCrom
Извън линия
Администратор
Администратор
Мнения: 7205
Регистриран на: 06 Окт 2016, 19:20
Местоположение: /resetscore
Се отблагодари: 117 пъти
Получена благодарност: 1278 пъти
Обратна връзка:

Добавяне на звук (I am blind) в ReAPI Team Flash Snitch

Мнение от OciXCrom » 07 Окт 2017, 14:46

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <reapi>
#include <WPMGPrintChatColor>

new const g_MsgPrefix[] = "[Team Flash Snitch]"
new const g_szSound[] = "radio/bot/im_blind.wav"

const BLINDED_PARTLY = 200
const BLINDED_FULLY = 255

new g_szName[33][32]
new g_pSound

public plugin_init() 
{
	register_plugin("[ReAPI] Team Flash Snitch", "1.0", "WaLkZ")
	
	RegisterHookChain(RG_PlayerBlind, "PlayerBlind", .post = true)
	RegisterHookChain(RG_CBasePlayer_SetClientUserInfoName, "CBasePlayer_SetUserInfoName", .post = true)
	
	g_pSound = register_cvar("tfs_sound", "1")
}

public plugin_precache()
{
	precache_sound(g_szSound)
}

public client_putinserver(id)
{
	get_user_name(id, g_szName[id], charsmax(g_szName[]))
}

public CBasePlayer_SetUserInfoName(const id, infobuffer[], szNewName[])
{
	if (!equal(g_szName[id], szNewName))
	{
		copy(g_szName[id], charsmax(g_szName[]), szNewName)
	}
}

public PlayerBlind(const iFlashed, const iInflictor, const iFlasher, const Float:fFadeTime, const Float:fFadeHold, const iAlpha, Float:fColor[3])
{
	if (iFlashed == iFlasher)
	{
		return HC_CONTINUE
	}
	
	if (get_member(iFlashed, m_iTeam) == get_member(iFlasher, m_iTeam))
	{		
		PrintChatColor(iFlashed, PRINT_COLOR_PLAYERTEAM, "!g%s You have been teamflashed by !t%s", g_MsgPrefix, g_szName[iFlasher])
		PrintChatColor(iFlasher, PRINT_COLOR_PLAYERTEAM, "!g%s You have %s flashed a teammate !t%s", g_MsgPrefix, iAlpha == BLINDED_FULLY ? "totally" : "partly", g_szName[iFlashed])
		
		if(get_pcvar_num(g_pSound))
		{
			client_cmd(iFlashed, "spk ^"%s^"", g_szSound)
		}
	}
	
	return HC_CONTINUE
}

Аватар
LoShIaA
Извън линия
Потребител
Потребител
Мнения: 323
Регистриран на: 20 Окт 2016, 14:44
Местоположение: Стара Загора
Се отблагодари: 120 пъти
Получена благодарност: 8 пъти

Добавяне на звук (I am blind) в ReAPI Team Flash Snitch

Мнение от LoShIaA » 09 Окт 2017, 09:43

Всичко работи както трябва. Мерси.

Заключено
  • Подобни теми
    Отговори
    Преглеждания
     Последно мнение

Обратно към “Заявки за плъгини”

Кой е на линия

Потребители разглеждащи този форум: 0 регистрирани и 27 госта