Плъгин 5 х убийства да дава awp gold

[cgozzie]

Ако можете да ми изработите плъгин с меню когато даден играч направи 5 поредни кила да му излиза меню с авп голд и да му изписва примерно вие направихте 5 поредни убийства желаете ли да вземете голд авп и да прави 2 пъти повече щети от обикновенното авп дано съм се изразил правилно и да сте ме разбрали какво искам.Скина на авп-то аз ще си го добавя.Да е и за двата отбора.

[OciXCrom]

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cromchat>
#include <cstrike>
#include <fakemeta>
#include <fun>
#include <hamsandwich>

#define GOLDEN_SKIN_V "models/v_awp.mdl"
#define GOLDEN_SKIN_P "models/p_awp.mdl"
#define GOLDEN_WEAPON CSW_AWP
#define KILLS_NEEDED 5

new g_iMenu
new g_iKills[33]
new g_szWeapon[20]
new bool:g_bHasGolden[33]

public plugin_init()
{
	register_plugin("X Kills Golden Skin", "1.0", "OciXCrom")
	register_event("DeathMsg", "OnPlayerKilled", "a")
	RegisterHam(Ham_Spawn, "player", "OnPlayerSpawn", 1)
	RegisterHam(Ham_TakeDamage, "player", "PreTakeDamage", 0)
	get_weaponname(GOLDEN_WEAPON, g_szWeapon, charsmax(g_szWeapon))
	CC_SetPrefix("&x04[GoldenAWP]")
	g_iMenu = menu_create("Jelaete li da vzemete Golden AWP?", "Menu_Handler")
	menu_additem(g_iMenu, "\yDa")
	menu_additem(g_iMenu, "\rNe")
}

public plugin_precache()
{
	precache_model(GOLDEN_SKIN_V)
	precache_model(GOLDEN_SKIN_P)
}

public OnPlayerSpawn(id)
{
	g_iKills[id] = 0
	g_bHasGolden[id] = false
}

public OnPlayerKilled()
{
	new iAttacker = read_data(1), iVictim = read_data(2)
	
	if(is_user_alive(iAttacker) && iAttacker != iVictim && ++g_iKills[iAttacker] == KILLS_NEEDED)
		menu_display(iAttacker, g_iMenu)	
}

public Menu_Handler(id, iMenu, iItem)
{
	if(iItem == 0)
	{
		g_bHasGolden[id] = true
		CC_SendMessage(id, "Poluchi &x04Golden AWP&x01!")
		give_item(id, g_szWeapon)
		cs_set_user_bpammo(id, GOLDEN_WEAPON, 30)
		OnChangeWeapon(id)
	}
}

public OnChangeWeapon(id)
{
	if(g_bHasGolden[id] && read_data(2) == GOLDEN_WEAPON)
	{
		set_pev(id, pev_viewmodel2, GOLDEN_SKIN_V)
		set_pev(id, pev_weaponmodel2, GOLDEN_SKIN_P)
	}
}

public PreTakeDamage(iVictim, iInflictor, iAttacker, Float:fDamage, iDamageBits)
{
	if(!g_bHasGolden[iAttacker] || !is_user_alive(iAttacker) || !is_user_alive(iVictim))
		return
		
	if(iAttacker == iInflictor && get_user_weapon(iAttacker) == CSW_AWP)
		SetHamParamFloat(4, fDamage * 2)
}

[cgozzie]

В тези редове ли да променя пътя към скина на голд авп или греша.
#define GOLDEN_SKIN_V "models/v_awp.mdl"
#define GOLDEN_SKIN_P "models/p_awp.mdl"

[OciXCrom]

Еми не виждам други.

[cgozzie]

Е и аз но се пак да питам ок ще го тествам и ще пиша в темата.

Добавено преди 20 минути 9 секунди:
Модела който ще сложа е с + 1 файл w_awp.mdl виждам че има и на други места да се добави но ще оставя на теб да не оплескам аз нещата.
#define GOLDEN_SKIN_V "models/v_awp.mdl"
#define GOLDEN_SKIN_P "models/p_awp.mdl"
#define GOLDEN_SKIN_W "models/w_awp.mdl"

[OciXCrom]

w_ модела е за когато хвърлиш оръжието на земята. Добавянето на такъв модел в този случай не е изобщо лесно, тъй че не очаквай някой да го направи.

[cgozzie]

Значи да търся само с V,P или само V. ако е само с V трябва ли пак да преработваш плъгина.

[[N]eXuS]

V модела е този който ти виждаш
P модела е този който другите виждат в рацете ти
W модела е този кайто виждаш като оражието е дропнато демек е на земята

Ти може да си сложиш само в модела тогава само играча ще го вижда другите ще виждат нормалния скин

[OciXCrom]

Значи да търся само с V,P или само V. ако е само с V трябва ли пак да преработваш плъгина.

Боже, боже... Ако ги има всички 3 вида, какъв е проблемът да НЕ добавиш w_ модела?! Все едно моделите са зависими един от друг...