Заявка за прост плъгин - Resetscore for admins !

[SILENT HILL`]

Здравейте от заглавието се разбира флаг ADMIN_LEVEL_H

[Fatall]

Не съм го тествал.

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <fun>
#include <cstrike>
#include <cromchat>

#define PLUGIN "ResetScore"
#define VERSION "1.0"
#define AUTHOR "sed1"

#define flag ADMIN_LEVEL_H 	// Тук определяте флага който да се изиска, за да може потребителя да нулира резултата си. Сегашен флаг - 't'

public plugin_init()
{
	register_plugin (PLUGIN, VERSION, AUTHOR);

	register_clcmd("say /rs","ResetScorePlayer")
	register_clcmd("say_team /rs","ResetScorePlayer")
	register_clcmd("say /resetscore","ResetScorePlayer")
	register_clcmd("say_team /resetscore","ResetScorePlayer")
	
	CC_SetPrefix("&x04[&x03HDservers&x04]")
}

public ResetScorePlayer(id)
{
	if( is_user_alive(id) )
	{
		if( get_user_flags(id) & flag )
		{
			set_user_frags(id,0)
			cs_set_user_deaths(id,0)
			CC_SendMessage(id,"You have just &x04reset &x01your score&x03.")
			return PLUGIN_HANDLED
		}
		else
		{
			CC_SendMessage(id,"You have to be a &x03ViP&x01 to reset your score&x04.")
			return PLUGIN_HANDLED
		}
		return PLUGIN_CONTINUE
	}
	else
	{
		CC_SendMessage(id,"You have to be &x04alive &x01to reset your score&x04.")
		return PLUGIN_HANDLED
	}
	return PLUGIN_CONTINUE
}

[mi0]

viewtopic.php?f=32&t=59

[OciXCrom]

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cromchat>
#include <cstrike>
#include <fun>

#define PLUGIN_VERSION "2.1f"
#define ARG_NAME "<name>"

new g_pMessage
new const g_szCommands[][] = { "/rs", "/resetscore" }

public plugin_init()
{
	register_plugin("Simple Resetscore", PLUGIN_VERSION, "OciXCrom")
	register_cvar("CRXSimpleRS", PLUGIN_VERSION, FCVAR_SERVER|FCVAR_SPONLY|FCVAR_UNLOGGED)
	g_pMessage = register_cvar("simplers_message", "&x04[&x03Simple Resetscore&x04] &x03<name> &x01has just reset his score!")

	for(new i; i < sizeof(g_szCommands); i++)
		register_chat_command(g_szCommands[i], "Cmd_ResetScore")
}

public Cmd_ResetScore(id)
{
	if(!(get_user_flags(id) & ADMIN_LEVEL_H))
	{
		CC_SendMessage(id, "&x04[&x03Simple Resetscore&x04] &x01You have no access to this command.")
		return PLUGIN_HANDLED
	}

	new szMessage[256], iType
	get_pcvar_string(g_pMessage, szMessage, charsmax(szMessage))

	if(contain(szMessage, ARG_NAME) != -1)
	{
		new szName[32]
		get_user_name(id, szName, charsmax(szName))
		replace(szMessage, charsmax(szMessage), ARG_NAME, szName)
		iType = 1
	}

	set_user_frags(id, 0)
	cs_set_user_deaths(id, 0)
	CC_SendMatched(iType ? id : 0, id, szMessage)
	return PLUGIN_HANDLED
}

register_chat_command(const szCommand[], const szFunction[])
{
	static szTemp[32]
	formatex(szTemp, charsmax(szTemp), "say %s", szCommand)
	register_clcmd(szTemp, szFunction)
	formatex(szTemp, charsmax(szTemp), "say_team %s", szCommand)
	register_clcmd(szTemp, szFunction)
}