Заявка за drop weapon

[Shoko]

Здравейте,ако е възможно да се направи плъгин който да махне оръжието на играч или админ.
Когато напиша в чата /drop "imeto na igracha" и да му се махне оръжието му.
Флаг за админите - a
Съобщение което да излиза.
Жълто [ Зелено BaseBuilder жълто ] зелено Admin remove your weapon

[JackEyedJones]

amx_regain_pistols

Ако искаш да получават обратно пистолет, стойност 1.

Код за потвърждение: Избери целия код

#define CHAT_FLAG ADMIN_IMMUNITY

Флага.

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <amxmisc>
#include <cstrike>
#include <colorchat>
#include <fun>

new const szChatEventHandlers[][] = { "say", "say_team" };

#define CHAT_FLAG ADMIN_IMMUNITY

#define cm(%1) (charsmax(%1))

new g_pistol_pcvar

public plugin_init()
{
	register_plugin("Admin Drop Weapons", "v1.0", "JackEyedJones");

	for(new registercommands = 0; registercommands < sizeof(szChatEventHandlers); registercommands++)
		register_clcmd(szChatEventHandlers[registercommands], "MainEvent");

	g_pistol_pcvar = register_cvar("amx_regain_pistols", "1");
}

public MainEvent(id)
{
	new szArg[192], szArg_Command[63], szArg_Name[63];
	read_args(szArg, cm(szArg)); remove_quotes(szArg);

	parse(szArg, szArg_Command, cm(szArg_Command), szArg_Name, cm(szArg_Name));

	if(equali(szArg_Command, "/drop"))
	{
		if(!access(id, CHAT_FLAG))
		{

			ColorChat(id, NORMAL, "!n[!gBaseBuilder!n] !gOnly available to admins.");

			return PLUGIN_HANDLED;
		}

		if(!strlen(szArg_Name))
		{
			ColorChat(id, NORMAL, "!n[!gBaseBuilder!n] Usage: !g/drop <nick>");

			return PLUGIN_HANDLED;
		}

		new target_player = cmd_target(id, szArg_Name, CMDTARGET_ONLY_ALIVE);

		if(!target_player)
		{
			ColorChat(id, NORMAL, "!n[!gBaseBuilder!n] There is no such player.");

			return PLUGIN_HANDLED;
		}

		strip_user_weapons(target_player);
		give_item(target_player, "weapon_knife");

		if(get_pcvar_num(g_pistol_pcvar))
		{
			give_item(target_player, cs_get_user_team(target_player) == CS_TEAM_T ? "weapon_glock18" : "weapon_usp");
			ColorChat(id, NORMAL, "!n[!gBaseBuilder!n] !gYour pistol is saved.");
		}

		ColorChat(id, NORMAL, "!n[!gBaseBuilder!n] !gAdmin removed your weapons.");

		return PLUGIN_HANDLED;
	}
	
	return PLUGIN_CONTINUE;
}

[Shoko]

Локвайте!
Благодаря ти @JackEyedJones