Добавяне на звук (I am blind) в ReAPI Team Flash Snitch

[LoShIaA]

Здравейте. Някой може ли да ми добави звукът, който съм прикачил и квар команда с, която мога да пускам и спирам дали да се чува звъкът. Общо взето да стане както е в стария плъгин.
Ето го плъгина: viewtopic.php?f=18&t=2070
Ето го кода:

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <reapi>
#include <WPMGPrintChatColor>

new const g_MsgPrefix[] = "[Team Flash Snitch]"

const BLINDED_PARTLY = 200
const BLINDED_FULLY = 255

new g_szName[33][32]

public plugin_init() 
{
	register_plugin("[ReAPI] Team Flash Snitch", "1.0", "WaLkZ")
	
	RegisterHookChain(RG_PlayerBlind, "PlayerBlind", .post = true)
	RegisterHookChain(RG_CBasePlayer_SetClientUserInfoName, "CBasePlayer_SetUserInfoName", .post = true)
}

public client_putinserver(id)
{
	get_user_name(id, g_szName[id], charsmax(g_szName[]))
}

public CBasePlayer_SetUserInfoName(const id, infobuffer[], szNewName[])
{
	if (!equal(g_szName[id], szNewName))
	{
		copy(g_szName[id], charsmax(g_szName[]), szNewName)
	}
}

public PlayerBlind(const iFlashed, const iInflictor, const iFlasher, const Float:fFadeTime, const Float:fFadeHold, const iAlpha, Float:fColor[3])
{
	if (iFlashed == iFlasher)
	{
		return HC_CONTINUE
	}
	
	if (get_member(iFlashed, m_iTeam) == get_member(iFlasher, m_iTeam))
	{		
		PrintChatColor(iFlashed, PRINT_COLOR_PLAYERTEAM, "!g%s You have been teamflashed by !t%s", g_MsgPrefix, g_szName[iFlasher])
		PrintChatColor(iFlasher, PRINT_COLOR_PLAYERTEAM, "!g%s You have %s flashed a teammate !t%s", g_MsgPrefix, iAlpha == BLINDED_FULLY ? "totally" : "partly", g_szName[iFlashed])	
	}
	
	return HC_CONTINUE
}

Въпросния квар:
tfs_sound
0 - Звука изключен
1 - Звука включен

Самият звук:

im_blind.wav

(17.06 KiB) Свалено 113 пъти

im_blind.wav

(17.06 KiB) Свалено 113 пъти

[OciXCrom]

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <reapi>
#include <WPMGPrintChatColor>

new const g_MsgPrefix[] = "[Team Flash Snitch]"
new const g_szSound[] = "radio/bot/im_blind.wav"

const BLINDED_PARTLY = 200
const BLINDED_FULLY = 255

new g_szName[33][32]
new g_pSound

public plugin_init() 
{
	register_plugin("[ReAPI] Team Flash Snitch", "1.0", "WaLkZ")
	
	RegisterHookChain(RG_PlayerBlind, "PlayerBlind", .post = true)
	RegisterHookChain(RG_CBasePlayer_SetClientUserInfoName, "CBasePlayer_SetUserInfoName", .post = true)
	
	g_pSound = register_cvar("tfs_sound", "1")
}

public plugin_precache()
{
	precache_sound(g_szSound)
}

public client_putinserver(id)
{
	get_user_name(id, g_szName[id], charsmax(g_szName[]))
}

public CBasePlayer_SetUserInfoName(const id, infobuffer[], szNewName[])
{
	if (!equal(g_szName[id], szNewName))
	{
		copy(g_szName[id], charsmax(g_szName[]), szNewName)
	}
}

public PlayerBlind(const iFlashed, const iInflictor, const iFlasher, const Float:fFadeTime, const Float:fFadeHold, const iAlpha, Float:fColor[3])
{
	if (iFlashed == iFlasher)
	{
		return HC_CONTINUE
	}
	
	if (get_member(iFlashed, m_iTeam) == get_member(iFlasher, m_iTeam))
	{		
		PrintChatColor(iFlashed, PRINT_COLOR_PLAYERTEAM, "!g%s You have been teamflashed by !t%s", g_MsgPrefix, g_szName[iFlasher])
		PrintChatColor(iFlasher, PRINT_COLOR_PLAYERTEAM, "!g%s You have %s flashed a teammate !t%s", g_MsgPrefix, iAlpha == BLINDED_FULLY ? "totally" : "partly", g_szName[iFlashed])
		
		if(get_pcvar_num(g_pSound))
		{
			client_cmd(iFlashed, "spk ^"%s^"", g_szSound)
		}
	}
	
	return HC_CONTINUE
}

[LoShIaA]

Всичко работи както трябва. Мерси.