Admin Connect Name v2.0a

Одобрените от нас плъгини. Моля, докладвайте ако забележите бъг с някой от плъгините в този раздел.
Аватар
Unbr3akable
Извън линия
Потребител
Потребител
Мнения: 178
Регистриран на: 21 Дек 2016, 20:50
Получена благодарност: 6 пъти

Admin Connect Name v2.0a

Мнение от Unbr3akable » 04 Фев 2017, 23:17

Автор: Unbr3akable

Описание:
Прост плъгин, който показва името на админа в HUD/DHUD съобщение при конектинг. В новата версия има и конфигурационен файл, чрез който много просто може да настройте всичко, както желаете.

Настройки:
В конфигурационния файл ще намерите настройки от две групи - главни и HUD, и една допълнителна информация.

[ГЛАВНИ НАСТРОЙКИ]
ACN_ADMIN_FLAG (DEFAULT: d) -- Флага на админа.
ACN_TASK_TIME (DEFAULT: 5.0) -- След колко секунди да се покаже HUD/DHUD съобщението.
ACN_CONNECT_SOUND (0 = Изключено | 1 = Включено) (DEFAULT: 1) -- Дали да има звук при конектинг.
ACN_SOUND_DIR (DEFAULT: buttons/bell1.wav) -- Ако горната опция е включена, тук задавате пътя към звука.

[HUD НАСТРОЙКИ]
ACN_HUD_TYPE (0 = HUD | 1 = DHUD) (DEFAULT: 1) -- Вида на HUD съобщението.
ACN_HUD_R_COLOR (DEFAULT: 255) -- Цвят червено (от 0 до 255).
ACN_HUD_G_COLOR (DEFAULT: 0) -- Цвят зелено (от 0 до 255).
ACN_HUD_BCOLOR (DEFAULT: 255) -- Цвят синьо (от 0 до 255).
ACN_HUD_X_POS (DEFAULT: 0.10) -- Позиция X при HUD/DHUD съобщението.
ACN_HUD_Y_POS (DEFAULT: 0.55) -- Позиция Y при HUD/DHUD съобщението.
ACN_HUD_EFFECTS (0 = Без ефекти | 1 = Премигване | 2 = Пишеща машина) (DEFAULT: 0) -- Ефекти при HUD/DHUD съобщението.
ACN_HUD_EFFECTS_TIME (DEFAULT: 1.0) -- Времетраене на HUD/DHUD ефектите.
ACN_HUD_TIME (DEFAULT: 6.0) -- Времетраене на HUD/DHUD съобщението.
ACN_HUD_TEXT (DEFAULT: Admin <name> connected.) -- HUD/DHUD съобщението, което да се показва.

[ДОПЪЛНИТЕЛНО]
Използвайте <name> за името на админа.

Начин на инсталация:
1. Файлът AdminConnectName.ini отива в папката configs.
2. Файлът acn.sma отива в папката scripting.
3. Компилирате acn.sma локално и получения файл отива в папката plugins.
4. В configs/plugins.ini пишете на нов ред името на файла - acn.sma.

Допълнителна информация и изтегляне:
* Сървъри, използващи този плъгин. - ЦЪК!
acn.rar
Версия 2.0a
(2.15 KiB) Свалено 461 пъти
acn.rar
Версия 2.0a
(2.15 KiB) Свалено 461 пъти
Последно промяна от Unbr3akable на 13 Фев 2017, 21:09, променено общо 2 пъти.

Аватар
OciXCrom
Извън линия
Администратор
Администратор
Мнения: 7206
Регистриран на: 06 Окт 2016, 19:20
Местоположение: /resetscore
Се отблагодари: 117 пъти
Получена благодарност: 1295 пъти
Обратна връзка:

Re: Admin Connect Name v2.0

Мнение от OciXCrom » 05 Фев 2017, 16:28

1.

Код за потвърждение: Избери целия код

public plugin_cfg()
    readfile()
Това трябва да е в plugin_precache(), тъй като във файла има и звук, който трябва да се precache-не.

2.

Код за потвърждение: Избери целия код

else if(equal(szKey, "ACN_SOUND_DIR"))
    copy(g_eSettings[ACN_SOUND_DIR], charsmax(g_eSettings[ACN_SOUND_DIR]), szValue)
Precache? Без precache играчът няма да изтегли звука при свързване към сървъра.


Аватар
OciXCrom
Извън линия
Администратор
Администратор
Мнения: 7206
Регистриран на: 06 Окт 2016, 19:20
Местоположение: /resetscore
Се отблагодари: 117 пъти
Получена благодарност: 1295 пъти
Обратна връзка:

Re: Admin Connect Name v2.0a

Мнение от OciXCrom » 05 Фев 2017, 17:12

Одобрен

Аватар
<< SaNchez >>
Извън линия
Потребител
Потребител
Мнения: 131
Регистриран на: 02 Ное 2016, 22:00
Местоположение: по сфета и у нас
Обратна връзка:

Re: Admin Connect Name v2.0a

Мнение от << SaNchez >> » 10 Фев 2017, 12:39

Защо след като плъгина е за тази цел не постнете 1-2 скрийншота да видим за какво иде реч?
Данък обществено мнение не плащам :coolface:

Аватар
gil5587
Извън линия
Foreigner
Foreigner
Мнения: 72
Регистриран на: 01 Сеп 2018, 01:26
Се отблагодари: 77 пъти
Получена благодарност: 3 пъти

Admin Connect Name v2.0a

Мнение от gil5587 » 11 Окт 2018, 03:13

It shows wrong names for some reason.. for example, admin "Bob" connected, it shows other name of another admin instead.. etc

Аватар
illusion
Извън линия
Developer
Developer
Мнения: 1796
Регистриран на: 27 Ное 2016, 17:47
Местоположение: CraftVision
Се отблагодари: 151 пъти
Получена благодарност: 358 пъти
Обратна връзка:

Admin Connect Name v2.0a

Мнение от illusion » 11 Окт 2018, 07:33

gil5587 написа: 11 Окт 2018, 03:13 It shows wrong names for some reason.. for example, admin "Bob" connected, it shows other name of another admin instead.. etc
same here

Аватар
TheRedShoko
Извън линия
Модератор
Модератор
Мнения: 1016
Регистриран на: 06 Окт 2016, 07:42
Местоположение: Бургас
Се отблагодари: 5 пъти
Получена благодарност: 84 пъти

Admin Connect Name v2.0a

Мнение от TheRedShoko » 11 Окт 2018, 16:01

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <amxmisc>

#if AMXX_VERSION_NUM < 183
	#include <dhudmessage>
#endif

#define PLUGIN_VERSION "2.0"

enum _: Settings
{
	ACN_ADMIN_FLAG[2],
	Float:ACN_TASK_TIME,
	ACN_CONNECT_SOUND,
	ACN_SOUND_DIR[128],
	ACN_HUD_TYPE,
	ACN_HUD_R_COLOR,
	ACN_HUD_G_COLOR,
	ACN_HUD_B_COLOR,
	Float:ACN_HUD_X_POS,
	Float:ACN_HUD_Y_POS,
	ACN_HUD_EFFECTS,
	Float:ACN_HUD_EFFECTS_TIME,
	Float:ACN_HUD_TIME,
	ACN_HUD_TEXT[192]
}

new g_eSettings[Settings]

public plugin_init()
{
	register_plugin("Admin Connect Name", PLUGIN_VERSION, "Unbr3akable")
	register_cvar("AdminConnectName", PLUGIN_VERSION, FCVAR_SERVER|FCVAR_SPONLY|FCVAR_UNLOGGED)
}

public plugin_precache()
	readfile()
	
readfile()
{
	new szConfigsName[256], szFileName[256]
	get_configsdir(szConfigsName, charsmax(szConfigsName))
	formatex(szFileName, charsmax(szFileName), "%s/AdminConnectName.ini", szConfigsName)
	new iFilePointer = fopen(szFileName, "rt")
	
	if(iFilePointer)
	{
		new szData[160], szKey[32], szValue[128]
		
		while(!feof(iFilePointer))
		{
			fgets(iFilePointer, szData, charsmax(szData))
			trim(szData)
			
			switch(szData[0])
			{
				case EOS, ';': continue
				default:
				{
					strtok(szData, szKey, charsmax(szKey), szValue, charsmax(szValue), '=')
					trim(szKey); trim(szValue)
					
					if(is_blank(szValue))
						continue
					
					if(equal(szKey, "ACN_ADMIN_FLAG"))
						copy(g_eSettings[ACN_ADMIN_FLAG], charsmax(g_eSettings[ACN_ADMIN_FLAG]), szValue)
					else if(equal(szKey, "ACN_TASK_TIME"))
						g_eSettings[ACN_TASK_TIME] = _:str_to_float(szValue)
					else if(equal(szKey, "ACN_CONNECT_SOUND"))
						g_eSettings[ACN_CONNECT_SOUND] = clamp(str_to_num(szValue), 0, 1)
					else if(equal(szKey, "ACN_SOUND_DIR"))
					{
						copy(g_eSettings[ACN_SOUND_DIR], charsmax(g_eSettings[ACN_SOUND_DIR]), szValue)
						precache_sound(szValue)
					}
					else if(equal(szKey, "ACN_HUD_TYPE"))
						g_eSettings[ACN_HUD_TYPE] = clamp(str_to_num(szValue), 0, 1)
					else if(equal(szKey, "ACN_HUD_R_COLOR"))
						g_eSettings[ACN_HUD_R_COLOR] = clamp(str_to_num(szValue), 0, 255)
					else if(equal(szKey, "ACN_HUD_G_COLOR"))
						g_eSettings[ACN_HUD_G_COLOR] = clamp(str_to_num(szValue), 0, 255)
					else if(equal(szKey, "ACN_HUD_B_COLOR"))
						g_eSettings[ACN_HUD_B_COLOR] = clamp(str_to_num(szValue), 0, 255)
					else if(equal(szKey, "ACN_HUD_X_POS"))
						g_eSettings[ACN_HUD_X_POS] = _:floatclamp(str_to_float(szValue), -1.0, 1.0)
					else if(equal(szKey, "ACN_HUD_Y_POS"))
						g_eSettings[ACN_HUD_Y_POS] = _:floatclamp(str_to_float(szValue), -1.0, 1.0)
					else if(equal(szKey, "ACN_HUD_EFFECTS"))
						g_eSettings[ACN_HUD_EFFECTS] = clamp(str_to_num(szValue), 0, 2)
					else if(equal(szKey, "ACN_HUD_EFFECTS_TIME"))
						g_eSettings[ACN_HUD_EFFECTS_TIME] = _:str_to_float(szValue)
					else if(equal(szKey, "ACN_HUD_TIME"))
						g_eSettings[ACN_HUD_TIME] = _:str_to_float(szValue)
					else if(equal(szKey, "ACN_HUD_TEXT"))
						copy(g_eSettings[ACN_HUD_TEXT], charsmax(g_eSettings[ACN_HUD_TEXT]), szValue)
				}
			}
		}
		
		fclose(iFilePointer)
	}
}
	
public client_authorized(id)
		set_task(g_eSettings[ACN_TASK_TIME], "AdminConnect", id)
		
public AdminConnect(id)
{
	new szAdminName[32], szMessage[sizeof g_eSettings[ACN_HUD_TEXT]];
	copy(szMessage, charsmax(szMessage), g_eSettings[ACN_HUD_TEXT]);
	get_user_name(id, szAdminName, charsmax(szAdminName))	
	replace_all(szMessage, charsmax(szMessage), "<name>", szAdminName)
	
	if(has_flag(id, g_eSettings[ACN_ADMIN_FLAG]))
	{
		if(g_eSettings[ACN_CONNECT_SOUND])
			client_cmd(0, "spk %s", g_eSettings[ACN_SOUND_DIR])
			
		if(!g_eSettings[ACN_HUD_TYPE])
		{
			set_hudmessage(g_eSettings[ACN_HUD_R_COLOR], g_eSettings[ACN_HUD_G_COLOR], g_eSettings[ACN_HUD_B_COLOR],
			g_eSettings[ACN_HUD_X_POS], g_eSettings[ACN_HUD_Y_POS], g_eSettings[ACN_HUD_EFFECTS],
			g_eSettings[ACN_HUD_EFFECTS_TIME], g_eSettings[ACN_HUD_TIME])
			show_hudmessage(0, szMessage)
		}
		else
		{
			set_dhudmessage(g_eSettings[ACN_HUD_R_COLOR], g_eSettings[ACN_HUD_G_COLOR], g_eSettings[ACN_HUD_B_COLOR],
			g_eSettings[ACN_HUD_X_POS], g_eSettings[ACN_HUD_Y_POS], g_eSettings[ACN_HUD_EFFECTS],
			g_eSettings[ACN_HUD_EFFECTS_TIME], g_eSettings[ACN_HUD_TIME])
			show_dhudmessage(0, szMessage)
		}
	}
}
	
bool:is_blank(szString[])
	return szString[0] == EOS ? true : false
Try like this.

Аватар
gil5587
Извън линия
Foreigner
Foreigner
Мнения: 72
Регистриран на: 01 Сеп 2018, 01:26
Се отблагодари: 77 пъти
Получена благодарност: 3 пъти

Admin Connect Name v2.0a

Мнение от gil5587 » 13 Окт 2018, 23:17

TheRedShoko написа: 11 Окт 2018, 16:01

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <amxmisc>

#if AMXX_VERSION_NUM < 183
	#include <dhudmessage>
#endif

#define PLUGIN_VERSION "2.0"

enum _: Settings
{
	ACN_ADMIN_FLAG[2],
	Float:ACN_TASK_TIME,
	ACN_CONNECT_SOUND,
	ACN_SOUND_DIR[128],
	ACN_HUD_TYPE,
	ACN_HUD_R_COLOR,
	ACN_HUD_G_COLOR,
	ACN_HUD_B_COLOR,
	Float:ACN_HUD_X_POS,
	Float:ACN_HUD_Y_POS,
	ACN_HUD_EFFECTS,
	Float:ACN_HUD_EFFECTS_TIME,
	Float:ACN_HUD_TIME,
	ACN_HUD_TEXT[192]
}

new g_eSettings[Settings]

public plugin_init()
{
	register_plugin("Admin Connect Name", PLUGIN_VERSION, "Unbr3akable")
	register_cvar("AdminConnectName", PLUGIN_VERSION, FCVAR_SERVER|FCVAR_SPONLY|FCVAR_UNLOGGED)
}

public plugin_precache()
	readfile()
	
readfile()
{
	new szConfigsName[256], szFileName[256]
	get_configsdir(szConfigsName, charsmax(szConfigsName))
	formatex(szFileName, charsmax(szFileName), "%s/AdminConnectName.ini", szConfigsName)
	new iFilePointer = fopen(szFileName, "rt")
	
	if(iFilePointer)
	{
		new szData[160], szKey[32], szValue[128]
		
		while(!feof(iFilePointer))
		{
			fgets(iFilePointer, szData, charsmax(szData))
			trim(szData)
			
			switch(szData[0])
			{
				case EOS, ';': continue
				default:
				{
					strtok(szData, szKey, charsmax(szKey), szValue, charsmax(szValue), '=')
					trim(szKey); trim(szValue)
					
					if(is_blank(szValue))
						continue
					
					if(equal(szKey, "ACN_ADMIN_FLAG"))
						copy(g_eSettings[ACN_ADMIN_FLAG], charsmax(g_eSettings[ACN_ADMIN_FLAG]), szValue)
					else if(equal(szKey, "ACN_TASK_TIME"))
						g_eSettings[ACN_TASK_TIME] = _:str_to_float(szValue)
					else if(equal(szKey, "ACN_CONNECT_SOUND"))
						g_eSettings[ACN_CONNECT_SOUND] = clamp(str_to_num(szValue), 0, 1)
					else if(equal(szKey, "ACN_SOUND_DIR"))
					{
						copy(g_eSettings[ACN_SOUND_DIR], charsmax(g_eSettings[ACN_SOUND_DIR]), szValue)
						precache_sound(szValue)
					}
					else if(equal(szKey, "ACN_HUD_TYPE"))
						g_eSettings[ACN_HUD_TYPE] = clamp(str_to_num(szValue), 0, 1)
					else if(equal(szKey, "ACN_HUD_R_COLOR"))
						g_eSettings[ACN_HUD_R_COLOR] = clamp(str_to_num(szValue), 0, 255)
					else if(equal(szKey, "ACN_HUD_G_COLOR"))
						g_eSettings[ACN_HUD_G_COLOR] = clamp(str_to_num(szValue), 0, 255)
					else if(equal(szKey, "ACN_HUD_B_COLOR"))
						g_eSettings[ACN_HUD_B_COLOR] = clamp(str_to_num(szValue), 0, 255)
					else if(equal(szKey, "ACN_HUD_X_POS"))
						g_eSettings[ACN_HUD_X_POS] = _:floatclamp(str_to_float(szValue), -1.0, 1.0)
					else if(equal(szKey, "ACN_HUD_Y_POS"))
						g_eSettings[ACN_HUD_Y_POS] = _:floatclamp(str_to_float(szValue), -1.0, 1.0)
					else if(equal(szKey, "ACN_HUD_EFFECTS"))
						g_eSettings[ACN_HUD_EFFECTS] = clamp(str_to_num(szValue), 0, 2)
					else if(equal(szKey, "ACN_HUD_EFFECTS_TIME"))
						g_eSettings[ACN_HUD_EFFECTS_TIME] = _:str_to_float(szValue)
					else if(equal(szKey, "ACN_HUD_TIME"))
						g_eSettings[ACN_HUD_TIME] = _:str_to_float(szValue)
					else if(equal(szKey, "ACN_HUD_TEXT"))
						copy(g_eSettings[ACN_HUD_TEXT], charsmax(g_eSettings[ACN_HUD_TEXT]), szValue)
				}
			}
		}
		
		fclose(iFilePointer)
	}
}
	
public client_authorized(id)
		set_task(g_eSettings[ACN_TASK_TIME], "AdminConnect", id)
		
public AdminConnect(id)
{
	new szAdminName[32], szMessage[sizeof g_eSettings[ACN_HUD_TEXT]];
	copy(szMessage, charsmax(szMessage), g_eSettings[ACN_HUD_TEXT]);
	get_user_name(id, szAdminName, charsmax(szAdminName))	
	replace_all(szMessage, charsmax(szMessage), "<name>", szAdminName)
	
	if(has_flag(id, g_eSettings[ACN_ADMIN_FLAG]))
	{
		if(g_eSettings[ACN_CONNECT_SOUND])
			client_cmd(0, "spk %s", g_eSettings[ACN_SOUND_DIR])
			
		if(!g_eSettings[ACN_HUD_TYPE])
		{
			set_hudmessage(g_eSettings[ACN_HUD_R_COLOR], g_eSettings[ACN_HUD_G_COLOR], g_eSettings[ACN_HUD_B_COLOR],
			g_eSettings[ACN_HUD_X_POS], g_eSettings[ACN_HUD_Y_POS], g_eSettings[ACN_HUD_EFFECTS],
			g_eSettings[ACN_HUD_EFFECTS_TIME], g_eSettings[ACN_HUD_TIME])
			show_hudmessage(0, szMessage)
		}
		else
		{
			set_dhudmessage(g_eSettings[ACN_HUD_R_COLOR], g_eSettings[ACN_HUD_G_COLOR], g_eSettings[ACN_HUD_B_COLOR],
			g_eSettings[ACN_HUD_X_POS], g_eSettings[ACN_HUD_Y_POS], g_eSettings[ACN_HUD_EFFECTS],
			g_eSettings[ACN_HUD_EFFECTS_TIME], g_eSettings[ACN_HUD_TIME])
			show_dhudmessage(0, szMessage)
		}
	}
}
	
bool:is_blank(szString[])
	return szString[0] == EOS ? true : false
Try like this.
the whole plugin not working now

Аватар
JackEyedJones
Извън линия
Потребител
Потребител
Мнения: 399
Регистриран на: 10 Сеп 2018, 17:26
Местоположение: Plovdiv, Bulgaria, Europe, Entire World
Се отблагодари: 4 пъти
Получена благодарност: 69 пъти
Обратна връзка:

Admin Connect Name v2.0a

Мнение от JackEyedJones » 14 Окт 2018, 09:16

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <amxmisc>

#if AMXX_VERSION_NUM < 183
	#include <dhudmessage>
#endif

#define PLUGIN_VERSION "2.0"

enum _:Settings
{
	ACN_ADMIN_FLAG[33],
	Float:ACN_TASK_TIME,
	ACN_CONNECT_SOUND,
	ACN_SOUND_DIR[128],
	ACN_HUD_TYPE,
	ACN_HUD_R_COLOR,
	ACN_HUD_G_COLOR,
	ACN_HUD_B_COLOR,
	Float:ACN_HUD_X_POS,
	Float:ACN_HUD_Y_POS,
	ACN_HUD_EFFECTS,
	Float:ACN_HUD_EFFECTS_TIME,
	Float:ACN_HUD_TIME,
	ACN_HUD_TEXT[192]
}

new g_eSettings[Settings]

public plugin_init()
{
	register_plugin("Admin Connect Name", PLUGIN_VERSION, "Unbr3akable")
	register_cvar("AdminConnectName", PLUGIN_VERSION, FCVAR_SERVER|FCVAR_SPONLY|FCVAR_UNLOGGED)
}

public plugin_precache()
	readfile()
	
readfile()
{
	new szConfigsName[256], szFileName[256]
	get_configsdir(szConfigsName, charsmax(szConfigsName))
	formatex(szFileName, charsmax(szFileName), "%s/AdminConnectName.ini", szConfigsName)
	new iFilePointer = fopen(szFileName, "rt")
	
	if(iFilePointer)
	{
		new szData[256], szKey[64], szValue[160]
		
		while(!feof(iFilePointer))
		{
			fgets(iFilePointer, szData, charsmax(szData))
			trim(szData)
			
			switch(szData[0])
			{
				case EOS, ';': continue
				default:
				{
					strtok(szData, szKey, charsmax(szKey), szValue, charsmax(szValue), '=')
					trim(szKey); trim(szValue)
					
					if(is_blank(szValue))
						continue
					
					if(equal(szKey, "ACN_ADMIN_FLAG"))
						copy(g_eSettings[ACN_ADMIN_FLAG], charsmax(g_eSettings[ACN_ADMIN_FLAG]), szValue)
					else if(equal(szKey, "ACN_TASK_TIME"))
						g_eSettings[ACN_TASK_TIME] = _:str_to_float(szValue)
					else if(equal(szKey, "ACN_CONNECT_SOUND"))
						g_eSettings[ACN_CONNECT_SOUND] = _:clamp(str_to_num(szValue), 0, 1)
					else if(equal(szKey, "ACN_SOUND_DIR"))
					{
						copy(g_eSettings[ACN_SOUND_DIR], charsmax(g_eSettings[ACN_SOUND_DIR]), szValue)
						precache_sound(szValue)
					}
					else if(equal(szKey, "ACN_HUD_TYPE"))
						g_eSettings[ACN_HUD_TYPE] = _:clamp(str_to_num(szValue), 0, 1)
					else if(equal(szKey, "ACN_HUD_R_COLOR"))
						g_eSettings[ACN_HUD_R_COLOR] = _:clamp(str_to_num(szValue), 0, 255)
					else if(equal(szKey, "ACN_HUD_G_COLOR"))
						g_eSettings[ACN_HUD_G_COLOR] = _:clamp(str_to_num(szValue), 0, 255)
					else if(equal(szKey, "ACN_HUD_B_COLOR"))
						g_eSettings[ACN_HUD_B_COLOR] = _:clamp(str_to_num(szValue), 0, 255)
					else if(equal(szKey, "ACN_HUD_X_POS"))
						g_eSettings[ACN_HUD_X_POS] = _:floatclamp(str_to_float(szValue), -1.0, 1.0)
					else if(equal(szKey, "ACN_HUD_Y_POS"))
						g_eSettings[ACN_HUD_Y_POS] = _:floatclamp(str_to_float(szValue), -1.0, 1.0)
					else if(equal(szKey, "ACN_HUD_EFFECTS"))
						g_eSettings[ACN_HUD_EFFECTS] = _:clamp(str_to_num(szValue), 0, 2)
					else if(equal(szKey, "ACN_HUD_EFFECTS_TIME"))
						g_eSettings[ACN_HUD_EFFECTS_TIME] = _:str_to_float(szValue)
					else if(equal(szKey, "ACN_HUD_TIME"))
						g_eSettings[ACN_HUD_TIME] = _:str_to_float(szValue)
					else if(equal(szKey, "ACN_HUD_TEXT"))
						copy(g_eSettings[ACN_HUD_TEXT], charsmax(g_eSettings[ACN_HUD_TEXT]), szValue)
				}
			}
		}
		
		fclose(iFilePointer)
	}
}
	
public client_putinserver(id)
{
	if(!is_user_bot(id))
		set_task(g_eSettings[ACN_TASK_TIME], "AdminConnect", id);
}
		
public AdminConnect(id)
{
	new szAdminName[32]
	get_user_name(id, szAdminName, charsmax(szAdminName))	
	replace_all(g_eSettings[ACN_HUD_TEXT], charsmax(g_eSettings[ACN_HUD_TEXT]), "<name>", szAdminName)
	
	if(has_flag(id, g_eSettings[ACN_ADMIN_FLAG]))
	{
		if(g_eSettings[ACN_CONNECT_SOUND])
			client_cmd(0, "spk %s", g_eSettings[ACN_SOUND_DIR])
			
		if(!g_eSettings[ACN_HUD_TYPE])
		{
			set_hudmessage(g_eSettings[ACN_HUD_R_COLOR], g_eSettings[ACN_HUD_G_COLOR], g_eSettings[ACN_HUD_B_COLOR],
			g_eSettings[ACN_HUD_X_POS], g_eSettings[ACN_HUD_Y_POS], g_eSettings[ACN_HUD_EFFECTS],
			g_eSettings[ACN_HUD_EFFECTS_TIME], g_eSettings[ACN_HUD_TIME])
			show_hudmessage(0, g_eSettings[ACN_HUD_TEXT])
		}
		else
		{
			set_dhudmessage(g_eSettings[ACN_HUD_R_COLOR], g_eSettings[ACN_HUD_G_COLOR], g_eSettings[ACN_HUD_B_COLOR],
			g_eSettings[ACN_HUD_X_POS], g_eSettings[ACN_HUD_Y_POS], g_eSettings[ACN_HUD_EFFECTS],
			g_eSettings[ACN_HUD_EFFECTS_TIME], g_eSettings[ACN_HUD_TIME])
			show_dhudmessage(0, g_eSettings[ACN_HUD_TEXT])
		}
	}
}
	
bool:is_blank(szString[])
	return szString[0] == EOS;

/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1026\\ f0\\ fs16 \n\\ par }
*/
Changes made:
1. Changed size of ACN_ADMIN_FLAG[2] = > ACN_ADMIN_FLAG[33]. It now correctly reads the flag from the file.
2. All clamp(str_to_num(szValue), 0, 255) values are now _:clamp(str_to_num(szValue), 0, 255). All clamp values are also _:
3. return szString[0] == EOS ? true : false is now changed to return szString[0] == EOS;
4. Changed client_authorized(id) to client_putinserver(id) and added checking for is_user_bot(id)

Код за потвърждение: Избери целия код

public client_putinserver(id)
{
	if(!is_user_bot(id))
		set_task(g_eSettings[ACN_TASK_TIME], "AdminConnect", id);
}
It now should be working as expected.

Публикувай отговор
  • Подобни теми
    Отговори
    Преглеждания
     Последно мнение

Обратно към “Одобрени плъгини”

Кой е на линия

Потребители разглеждащи този форум: 0 регистрирани и 13 госта