admin_screen plugin

Мнение от **runthenwalk** » 06 Сеп 2022, 12:30

Здр
Трябава ми admin_screen plugin на .sma файл . Трябва ми като избера ника на играч , да му прави автоматично 4 скрийншота на неговия екран през няколко секунди с timestamp на неговитe съобщения в чата примерно "admin takes screenshot to you 06.09.2022 11:36:36 . Командата да е amx_screen nick/steamID .
Кварове за броя на снимки и през колко секунди да е самоснимачката и с какъв флаг да имат право да правят снимки.
Плъгина да Dark Style не работи при мен , дава грешка
Това е общо взето.

Мнение от **thoughtz** » 06 Сеп 2022, 16:29

viewtopic.php?f=33&t=1951&start=10 в тази тема пише, че въпросния плъгин на DaRk_StyLe работи. Каква е грешката, която ти "дава"?

2.

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <amxmisc>
#include <cromchat>
#include <hamsandwich>

/* The admin flag */
#define ADMIN_FLAG "e"

/* The console command. Put // in front to disable it */
new const CONSOLE_COMMAND[] = "amx_screen"

/* The chat command. Put // in front to disable it */
//new const CHAT_COMMAND[] = "/screen"

/* Whether the command can be used on yourself (true = yes; false = no) */
new const bool:USE_ON_SELF = true

/* The chat prefix. Put // in front to disable it */
new const COMMAND_PREFIX[] = "&x04[AMXX]"

/* Number of screenshots */
new const SCREENSHOT_NUM = 4

/* Seconds between each screenshot */
new const Float:SCREENSHOT_DELAY = 2.0

/* --- End of settings --- */

#define PLUGIN_VERSION "1.0"
#define TASK_SCREEN 334222
new ADMIN_FLAG_BIT

public plugin_init()
{
    register_plugin("Screenshot command", PLUGIN_VERSION, "OciXCrom @ amxx-bg.info/forum")
    register_cvar("CRXCMD_Screenshot", PLUGIN_VERSION, FCVAR_SERVER|FCVAR_SPONLY|FCVAR_UNLOGGED)
    ADMIN_FLAG_BIT = read_flags(ADMIN_FLAG)
    
    #if defined CONSOLE_COMMAND
    register_concmd(CONSOLE_COMMAND, "Cmd_Main", ADMIN_FLAG_BIT, "<nick|#userid>")
    #endif
    
    #if defined CHAT_COMMAND
    register_clcmd("say", "Cmd_Say")
    register_clcmd("say_team", "Cmd_Say")
    #endif
    
    #if defined COMMAND_PREFIX
    CC_SetPrefix(COMMAND_PREFIX)
    #endif
}

#if defined CONSOLE_COMMAND
public Cmd_Main(id, iLevel, iCid)
{
    if(!cmd_access(id, iLevel, iCid, 2))
        return PLUGIN_HANDLED
        
    new szPlayer[32]
    read_argv(1, szPlayer, charsmax(szPlayer))
    DoAction(id, szPlayer)
    return PLUGIN_HANDLED
}
#endif

#if defined CHAT_COMMAND
public Cmd_Say(id)
{
    if(~get_user_flags(id) & ADMIN_FLAG_BIT)
        goto @END
        
    static szArgs[64]
    read_args(szArgs, charsmax(szArgs))
    remove_quotes(szArgs)
    
    if(equali(szArgs[0], CHAT_COMMAND, charsmax(CHAT_COMMAND)))
    {
        new szPlayer[32]
        parse(szArgs, szArgs, charsmax(szArgs), szPlayer, charsmax(szPlayer))
        DoAction(id, szPlayer)
        return PLUGIN_HANDLED
    }
    
    @END:
    return PLUGIN_CONTINUE
}
#endif

DoAction(id, szPlayer[])
{
    new iPlayer = cmd_target(id, szPlayer, CMDTARGET_OBEY_IMMUNITY)
    
    if(!iPlayer)
        return PLUGIN_HANDLED
        
    if(id == iPlayer && !USE_ON_SELF)
    {
        CC_SendMessage(id, "You can't use this command on yourself!")
        return PLUGIN_HANDLED
    }
    
    new iData[2]
    iData[0] = id
    iData[1] = iPlayer
    
    set_task(SCREENSHOT_DELAY, "TakeScreenshot", TASK_SCREEN + iPlayer, iData, .flags = "a", .repeat = SCREENSHOT_NUM)
    
    new szName[32]
    get_user_name(iPlayer, szName, charsmax(szName))
    CC_SendMessage(id, "Taking &x04%i screenshots &x01on &x03%s &x01with a &x04%.1f seconds delay&x01.", SCREENSHOT_NUM, szName, SCREENSHOT_DELAY)
    return PLUGIN_CONTINUE
}

public TakeScreenshot(iData[2])
{
    new id = iData[0], iPlayer = iData[1]
    
    if(!is_user_connected(iPlayer))
    {
        CC_SendMessage(id, "Player left while taking screenshots.")
        remove_task(TASK_SCREEN + iPlayer)
        return
    }
    
    client_cmd(iPlayer, "snapshot")
    CC_SendMessage(id, "Screenshot took...")
}

Има и още 1 плъгин в същата тема, предоставен от InviusART.

Мнение от **runthenwalk** » 08 Сеп 2022, 22:32

На мен ми изписва ,че прави screenshots но на играча - не . И няма снимки никъде

Мнение от **m0ney** » 08 Сеп 2022, 23:03

runthenwalk написа: ↑08 Сеп 2022, 22:32 На мен ми изписва ,че прави screenshots но на играча - не . И няма снимки никъде

Ако е сложил цс-а в C примерно може и да не записва файлове, тества ли го на себе си?

https://forums.alliedmods.net/showthread.php?t=49350

Мнение от **runthenwalk** » 09 Сеп 2022, 20:04

m0ney написа: ↑08 Сеп 2022, 23:03
runthenwalk написа: ↑08 Сеп 2022, 22:32 На мен ми изписва ,че прави screenshots но на играча - не . И няма снимки никъде
Ако е сложил цс-а в C примерно може и да не записва файлове, тества ли го на себе си?

https://forums.alliedmods.net/showthread.php?t=49350

Този бачка перфеткно , имат разлика двата плъгина
Мерси