Помощ за gungame - warmup, infinity round

[Siska]

Ползваме версията на гънгейм 2.13(бета)
Искам да пусна warmup и в същото време да ползвам безкраен рунд, но когато пусна безкрайния рунд "warmup" спира. Пробвах по различни начини, но "warmup" винаги спира , когато има безкраен рунд. На този сървър сме със amx 1.82 , без regamedll.
Някой може ли да ми даде някаква идея как да стане и двете едновременно ? Да кача ли кода на целия гънгейм ?

[zolfeca]

Какво точно трябва да се случи по време на warmup, което не се случва по време на безкрайния рунд ?

[EMOTO2.COM]

Ползвай regame и блокирай всички флагове от mp_round_infinite освен флаг B (block needed players round end check)

[Siska]

Ползвай regame и блокирай всички флагове от mp_round_infinite освен флаг B (block needed players round end check)

Благодаря , евентуално може и да пробваме , но на този етап не смятаме да слагаме регейм на този сървър.
Има ли някакъв друг начин ?

zolfeca, warmup е загрявка с нож или други оръжия 30 сек. или 60 сек. преди да започне истинската игра. Това се ползва , за да си починат малко играчите преди новата карта, защото гънгейм е натоварващ мод. Някои го ползват, за да пушат цигара и т.н.
Безкрайният рунд е ценен за такъв вид мод и аз искам да го ползвам, но като го пусна спира загрявката.
Може ли по някакъв начин да се преправи гънгейма или евентуално warmup плъгин или май имаше и модул за такова нещо, по такъв начин , че да има warmup , а след това автоматично да се променя и да се включва безкрайния рунд. Един вид все едно инфинити да е нула по време на загрявката , а след това да се променя на 1. Нали разбирате ?

[zolfeca]

Ами прикачи плъгина, в който е безкрайния рунд.

[Siska]

Благодаря на zolfeca , че е готов да преправя плъгин.
Решихме да ползваме регейм и се получи по начина на EMOTO2.COM, но сега имам друг проблем.
Явно , когато ползвам безкраен рунд автоматичния баланс не работи. Пробвах с "mp_autoteambalance 2" , но не работи.
Това ще може ли да се оправи по някакъв начин ? Примерно , ако напиша в amxx.cfg "mp_autoteambalance 1 или 2" ???

[EMOTO2.COM]

За баланс ще трябва да добавиш този плугин:

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cstrike>

#define BALANCE_IMMUNITY		ADMIN_LEVEL_H

#define MAX_PLAYERS	32

enum {
	aTerro,
	aCt
}

new bool:g_bImmuned[MAX_PLAYERS+1]

new Float:g_fJoinedTeam[MAX_PLAYERS+1] = {-1.0, ...}

new g_pcvarCount, g_pcvarImmune, g_pCvarMessage

new g_iCounter
new mp_limitteams, mp_autoteambalance

public plugin_init()
{
	register_plugin("Auto team balance","1.6","LauNcHerR")

	g_pcvarCount = register_cvar("atb_death_freq", "3")
	g_pcvarImmune = register_cvar("atb_admins_immunity", "1")
	g_pCvarMessage = register_cvar("iatb_message", "Auto teams balanced")

	register_logevent("LogEvent_JoinTeam", 3, "1=joined team")
	register_event("DeathMsg", "Event_DeathMsg", "a")

	mp_limitteams = get_cvar_pointer("mp_limitteams")
	mp_autoteambalance = get_cvar_pointer("mp_autoteambalance")
}

public Event_DeathMsg()
{
	new iFreq = get_pcvar_num(g_pcvarCount)
	if( !iFreq || !get_pcvar_num(mp_autoteambalance) )
		return

	if( ++g_iCounter < iFreq )
		return

	g_iCounter = 0
	balance_teams()
}

public LogEvent_JoinTeam()
{
	new loguser[80], name[32], id
	read_logargv(0, loguser, 79)
	parse_loguser(loguser, name, 31)
	id = get_user_index(name)

	g_fJoinedTeam[id] = get_gametime()
}

public client_authorized(id)
{
	g_bImmuned[id] = bool:(get_user_flags(id) & BALANCE_IMMUNITY)
}

public client_disconnect(id)
{
	g_iCounter = max(0, get_pcvar_num(g_pcvarCount) - 1)
}

balance_teams()
{
	new iPlayers[MAX_PLAYERS], iNum
	new aTeams[2][MAX_PLAYERS], aNum[2], id

	get_players(iPlayers, iNum, "h")

	for(new i; i<iNum; i++)
	{
		id = iPlayers[i]

		switch( cs_get_user_team(id) )
		{
			case CS_TEAM_T:
			{
				aTeams[aTerro][aNum[aTerro]++] = id
			}
			case CS_TEAM_CT:
			{
				aTeams[aCt][aNum[aCt]++] = id
			}
		}
	}

	new iCheck
	new iTimes = aNum[aCt] - aNum[aTerro]

	if(iTimes > 0)
	{
		iCheck = aCt
	}
	else if(iTimes < 0)
	{
		iCheck = aTerro
	}
	else
	{
		return
	}

	iTimes = abs(iTimes)

	if( iTimes < 2 || iTimes <= get_pcvar_num(mp_limitteams) )
	{
		return
	}

	iTimes /= 2

	new bool:bTransfered[MAX_PLAYERS+1],
		bool:bAdminsImmune = bool:get_pcvar_num(g_pcvarImmune)

	new iLast, iCount
	while( iTimes > 0 )
	{
		iLast = 0
		for(new i=0; i <aNum[iCheck]; i++)
		{
			id = aTeams[iCheck][i]
			if( g_bImmuned[id] && bAdminsImmune )
			{
				continue
			}
			if(bTransfered[id])
			{
				continue
			}
			if(g_fJoinedTeam[id] > g_fJoinedTeam[iLast])
			{
				iLast = id
			}
		}

		if(!iLast)
		{
			return
		}

		if( iCheck )
		{
			cs_set_user_team(iLast, CS_TEAM_T)
		}
		else
		{
			cs_set_user_team(iLast, CS_TEAM_CT)
		}

		bTransfered[iLast] = true
		iCount++
		iTimes--
	}

	new szMessage[128]
	get_pcvar_string(g_pCvarMessage, szMessage, charsmax(szMessage))
	client_print(0, print_center, szMessage)
}

[illusion]

За баланса можеш да видиш и този код, от крома е
https://www.amxx-bg.info/forum/viewtopic.php?t=1096

[Siska]

И тук приключих...
Вече имаме и warmup и безкраен рунд и баланс.
Благодаря на всички , може да се заключва.