Проблем с regen зомби за BB 6.5 на tirant.

[sf4n]

Проблема е, че работи само първия рунд, след като започне втория зомбито не регенерира кръвта си.

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <basebuilder>
#include <fun>

#define ZCLASS_NAME "Regen Zombie"
#define ZCLASS_DESC "Regenerate health"
#define ZCLASS_MODEL "zombie_source"
#define ZCLASS_CLAWS "v_knife"
#define ZCLASS_HEALTH 4200
#define ZCLASS_SPEED 250
#define ZCLASS_GRAVITY 1.0
#define ZCLASS_REGEN_FREQ 2.0
#define ZCLASS_REGEN_AMOUNT 100

new g_iClass

public plugin_init()
	register_plugin("Regen Zombie", "1.0", "OciXCrom")
	
public plugin_precache()
	g_iClass = bb_register_zombie_class(ZCLASS_NAME, ZCLASS_DESC, ZCLASS_MODEL, ZCLASS_CLAWS, ZCLASS_HEALTH, ZCLASS_SPEED, ZCLASS_GRAVITY)
	
public client_putinserver(id)
	set_task(ZCLASS_REGEN_FREQ, "regenerate_health", id, .flags = "b")
	
public client_disconnect(id)
	remove_task(id)
	
public regenerate_health(id)
{
	if(!bb_is_user_zombie(id) || bb_get_user_zombie_class(id) != g_iClass)
		return
		
	new iHealth = get_user_health(id)
	
	if(iHealth >= ZCLASS_HEALTH)
		return
		
	set_user_health(id, clamp(iHealth + ZCLASS_REGEN_AMOUNT, .max = ZCLASS_HEALTH))
}

[OciXCrom]

Единственото за което мога да се досетя е, че някой друг плъгин премахва task-а в края на рунда. Опитай така:

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <basebuilder>
#include <fun>

#define ZCLASS_NAME "Regen Zombie"
#define ZCLASS_DESC "Regenerate health"
#define ZCLASS_MODEL "zombie_source"
#define ZCLASS_CLAWS "v_knife"
#define ZCLASS_HEALTH 4200
#define ZCLASS_SPEED 250
#define ZCLASS_GRAVITY 1.0
#define ZCLASS_REGEN_FREQ 2.0
#define ZCLASS_REGEN_AMOUNT 100

#define TASK_ID 231400

new g_iClass

public plugin_init()
	register_plugin("Regen Zombie", "1.0", "OciXCrom")
	
public plugin_precache()
	g_iClass = bb_register_zombie_class(ZCLASS_NAME, ZCLASS_DESC, ZCLASS_MODEL, ZCLASS_CLAWS, ZCLASS_HEALTH, ZCLASS_SPEED, ZCLASS_GRAVITY)
	
public client_putinserver(id)
	set_task(ZCLASS_REGEN_FREQ, "regenerate_health", id + TASK_ID, .flags = "b")
	
public client_disconnect(id)
	remove_task(id + TASK_ID)
	
public regenerate_health(id)
{
	id -= TASK_ID
	
	if(!bb_is_user_zombie(id) || bb_get_user_zombie_class(id) != g_iClass)
		return
		
	new iHealth = get_user_health(id)
	
	if(iHealth >= ZCLASS_HEALTH)
		return
		
	set_user_health(id, clamp(iHealth + ZCLASS_REGEN_AMOUNT, .max = ZCLASS_HEALTH))
}

[sf4n]

Благодаря. Може да локвате.