Уведомяване на играчите при активен Happy Hour

[Lethality]

Здравейте,

може ли да се добави към Happy Hour плъгина за OciXCrom Ranksystem уведомяване на играчите чрез чата. Ако например Happy Hour е активен в 23:00 часа до 01:00 часа, да изписва в чата, че събитието е активно през 5 минути в чата. Съответно започва от 23:00 и приключват съобщенията в 01:00. Например: !g***!tDouble !gXP !tfor kills from !g23:00 !nto !g01:00!n: !gACTIVE
Предполагам, че оцветяването на съобщенията ще е най-добре с cromchat

Благодаря предварително!

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <crxranks>

#define PLUGIN_VERSION "1.0"

new bool:g_bHappyHour, g_pStart, g_pEnd, g_pMultiplier, g_iMultiplier

public plugin_init()
{
	register_plugin("CRXRanks: Happy Hour", PLUGIN_VERSION, "OciXCrom")
	register_cvar("CRXRanksHH", PLUGIN_VERSION, FCVAR_SERVER|FCVAR_SPONLY|FCVAR_UNLOGGED)
	register_logevent("OnRoundStart", 2, "0=World triggered", "1=Round_Start")
	g_pStart = register_cvar("crxranks_hh_start", "20")
	g_pEnd = register_cvar("crxranks_hh_end", "23")
	g_pMultiplier = register_cvar("crxranks_hh_multiplier", "2")
}

public plugin_cfg()
	OnRoundStart()

public OnRoundStart()
{
	g_iMultiplier = get_pcvar_num(g_pMultiplier)
	g_bHappyHour = is_happy_hour(get_pcvar_num(g_pStart), get_pcvar_num(g_pEnd))
}

public crxranks_user_receive_xp(id, iXP, CRXRanks_XPSources:iSource)
{
	if(g_bHappyHour && iSource == CRXRANKS_XPS_REWARD)
		return iXP * g_iMultiplier
		
	return CRXRANKS_CONTINUE
}

bool:is_happy_hour(const iStart, const iEnd)
{
    static iHour; time(iHour)
    return bool:(iStart < iEnd ? (iStart <= iHour < iEnd) : (iStart <= iHour || iHour < iEnd))
}

[OciXCrom]

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <crxranks>

#define CC_COLORS_TYPE CC_COLORS_SHORT
#include <cromchat>

#define PLUGIN_VERSION "1.0+chat"

new bool:g_bHappyHour, g_pStart, g_pEnd, g_pChatFreq, g_pMultiplier, g_iMultiplier

public plugin_init()
{
	register_plugin("CRXRanks: Happy Hour", PLUGIN_VERSION, "OciXCrom")
	register_cvar("CRXRanksHH", PLUGIN_VERSION, FCVAR_SERVER|FCVAR_SPONLY|FCVAR_UNLOGGED)
	register_logevent("OnRoundStart", 2, "0=World triggered", "1=Round_Start")
	g_pStart = register_cvar("crxranks_hh_start", "20")
	g_pEnd = register_cvar("crxranks_hh_end", "23")
	g_pMultiplier = register_cvar("crxranks_hh_multiplier", "2")
	g_pChatFreq = register_cvar("crxranks_hh_chat_freq", "300")
}

public plugin_cfg()
{
	OnRoundStart()
	set_task(get_pcvar_float(g_pChatFreq), "DisplayChatMessage", .flags = "b")
}

public DisplayChatMessage()
{
	if(g_bHappyHour)
	{
		CC_SendMessage(0, "!g***!tDouble !gXP !tfor kills from !g%i:00 !nto !g%i:00!n: !gACTIVE", get_pcvar_num(g_pStart), get_pcvar_num(g_pEnd))
	}
}

public OnRoundStart()
{
	g_iMultiplier = get_pcvar_num(g_pMultiplier)
	g_bHappyHour = is_happy_hour(get_pcvar_num(g_pStart), get_pcvar_num(g_pEnd))
}

public crxranks_user_receive_xp(id, iXP, CRXRanks_XPSources:iSource)
{
	if(g_bHappyHour && iSource == CRXRANKS_XPS_REWARD)
		return iXP * g_iMultiplier
		
	return CRXRANKS_CONTINUE
}

bool:is_happy_hour(const iStart, const iEnd)
{
    static iHour; time(iHour)
    return bool:(iStart < iEnd ? (iStart <= iHour < iEnd) : (iStart <= iHour || iHour < iEnd))
}

[Lethality]

Благодаря много за бързото съдействие!