Търся няколко плъгина

В този раздел можете да подавате всякакви заявки за намиране, изработка или преработка на плъгини/модове.
Аватар
southdivision
Извън линия
Потребител
Потребител
Мнения: 279
Регистриран на: 14 Окт 2016, 23:17
Местоположение: София
Се отблагодари: 8 пъти
Получена благодарност: 5 пъти
Обратна връзка:

Търся няколко плъгина

Мнение от southdivision » 15 Яну 2017, 15:21

1. Плъгин който позволява на админите със RCON флаг да банват админи със имунитeт ( Използвам amxbans )
2. Когато те убият в чата да ти показва последен Killstrike: Убийства,HS,HE,Knife
3. Админите с резервиран слот да получават бонус пари при убийство и убийство в главата,смоук и две флаш гранати и една HE граната

Благодаря

Аватар
TheRedShoko
Извън линия
Модератор
Модератор
Мнения: 1016
Регистриран на: 06 Окт 2016, 07:42
Местоположение: Бургас
Се отблагодари: 5 пъти
Получена благодарност: 84 пъти

Re: Търся няколко плъгина

Мнение от TheRedShoko » 15 Яну 2017, 16:12

1. Можеш да използваш това и да им махаш имунитета.
2. Ако не се лъжа го имаше вградено в cstats.
3. Не успях да разбера кога искаш бонус гранатите, затова ги направих при HeadShot.

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cstrike>
#include <fun>

#define ADMIN_ACCESS ADMIN_RESERVATION

new p_iKillReward[2];

public plugin_init()
{
    register_plugin("Admin kill bonus", "1.0", "TheRedShoko @ AMXX-BG.info");
    
    register_event("DeathMsg", "EventDeathMsg", "a");
    
    p_iKillReward[0] = register_cvar("admin_kill_money", "500");
    p_iKillReward[1] = register_cvar("admin_hs_money", "1000");
}

public EventDeathMsg()
{
    new iKiller = read_data(1);
    new iVictim = read_data(2);
    new iHs = read_data(3);
    
    if (iKiller == iVictim 
        || !is_user_connected(iKiller) 
        || ~get_user_flags(iKiller) & ADMIN_ACCESS)
    {
        return;
    }
    
    if (iHs == 1)
    {
        give_item(iKiller, "weapon_flashbang");
        cs_set_user_bpammo(iKiller, CSW_FLASHBANG, 2);
        
        give_item(iKiller, "weapon_smokegrenade");
        
        give_item(iKiller, "weapon_hegrenade");
    }
    
    cs_set_user_money(iKiller, cs_get_user_money(iKiller) + get_pcvar_num(p_iKillReward[iHs]));
}

Аватар
southdivision
Извън линия
Потребител
Потребител
Мнения: 279
Регистриран на: 14 Окт 2016, 23:17
Местоположение: София
Се отблагодари: 8 пъти
Получена благодарност: 5 пъти
Обратна връзка:

Re: Търся няколко плъгина

Мнение от southdivision » 15 Яну 2017, 17:16

Това за махането на имунитета след използването на командата върху някой админ веднага ли му се маха имунитета или след смяната на картата?

Бонус гранатите ги искам при всеки нов рунд

Аватар
TheRedShoko
Извън линия
Модератор
Модератор
Мнения: 1016
Регистриран на: 06 Окт 2016, 07:42
Местоположение: Бургас
Се отблагодари: 5 пъти
Получена благодарност: 84 пъти

Re: Търся няколко плъгина

Мнение от TheRedShoko » 15 Яну 2017, 17:17

Веднага се маха и трае до retry. При убийство да няма бонус гранати, така ли?

Аватар
southdivision
Извън линия
Потребител
Потребител
Мнения: 279
Регистриран на: 14 Окт 2016, 23:17
Местоположение: София
Се отблагодари: 8 пъти
Получена благодарност: 5 пъти
Обратна връзка:

Re: Търся няколко плъгина

Мнение от southdivision » 15 Яну 2017, 17:22

Да,при убийство да няма бонус гранатите,а само при всяко начало на рунда

Аватар
TheRedShoko
Извън линия
Модератор
Модератор
Мнения: 1016
Регистриран на: 06 Окт 2016, 07:42
Местоположение: Бургас
Се отблагодари: 5 пъти
Получена благодарност: 84 пъти

Re: Търся няколко плъгина

Мнение от TheRedShoko » 15 Яну 2017, 18:13

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cstrike>
#include <fun>
#include <hamsandwich>

#define ADMIN_ACCESS ADMIN_RESERVATION

new p_iKillReward[2];

public plugin_init()
{
    register_plugin("Admin kill bonus", "1.0", "TheRedShoko @ AMXX-BG.info");
    
    register_event("DeathMsg", "EventDeathMsg", "a");
    
    RegisterHam(Ham_Spawn, "player", "FwPlayerSpawnPost", 1);
    
    p_iKillReward[0] = register_cvar("admin_kill_money", "500");
    p_iKillReward[1] = register_cvar("admin_hs_money", "1000");
}

public FwPlayerSpawnPost(id)
{
    if (!is_user_alive(id) || ~get_user_flags(id) & ADMIN_ACCESS)
    {
        return;
    }
    
    give_item(id, "weapon_flashbang");
    cs_set_user_bpammo(id, CSW_FLASHBANG, 2);
    
    give_item(id, "weapon_smokegrenade");
    
    give_item(id, "weapon_hegrenade");
}

public EventDeathMsg()
{
    new iKiller = read_data(1);
    new iVictim = read_data(2);
    
    if (iKiller == iVictim 
        || !is_user_connected(iKiller) 
        || ~get_user_flags(iKiller) & ADMIN_ACCESS)
    {
        return;
    }
        
    cs_set_user_money(iKiller, cs_get_user_money(iKiller) + get_pcvar_num(p_iKillReward[read_data(3)]));
} 

Аватар
southdivision
Извън линия
Потребител
Потребител
Мнения: 279
Регистриран на: 14 Окт 2016, 23:17
Местоположение: София
Се отблагодари: 8 пъти
Получена благодарност: 5 пъти
Обратна връзка:

Re: Търся няколко плъгина

Мнение от southdivision » 15 Яну 2017, 18:39

Благодаря ти! Нека да остане отключена темата поне,ако някой се навие случайно да направи второто което искам :)

Аватар
TheRedShoko
Извън линия
Модератор
Модератор
Мнения: 1016
Регистриран на: 06 Окт 2016, 07:42
Местоположение: Бургас
Се отблагодари: 5 пъти
Получена благодарност: 84 пъти

Re: Търся няколко плъгина

Мнение от TheRedShoko » 15 Яну 2017, 19:28

Ако изпозлваш cstats погледни, мисля че го имаше вградено. Ако го няма вградено ще го направя.

Аватар
southdivision
Извън линия
Потребител
Потребител
Мнения: 279
Регистриран на: 14 Окт 2016, 23:17
Местоположение: София
Се отблагодари: 8 пъти
Получена благодарност: 5 пъти
Обратна връзка:

Re: Търся няколко плъгина

Мнение от southdivision » 15 Яну 2017, 19:32

Мисля,че го няма,но на мен ми трябва в отделен плъгин

Аватар
TheRedShoko
Извън линия
Модератор
Модератор
Мнения: 1016
Регистриран на: 06 Окт 2016, 07:42
Местоположение: Бургас
Се отблагодари: 5 пъти
Получена благодарност: 84 пъти

Re: Търся няколко плъгина

Мнение от TheRedShoko » 15 Яну 2017, 19:55

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <WPMGPrintChatColor>

enum _:Streak
{
    KILLS,
    HS,
    HE,
    KNIFE
}

new g_iKillStreak[33][Streak];

public plugin_init()
{
    register_plugin("Kill Streak", "1.0", "TheRedShoko @ AMXX-BG.info");
    
    register_event("DeathMsg", "EventDeathMsg", "a");
}

public EventDeathMsg()
{
    new iKiller = read_data(1);
    new iVictim = read_data(2);
    new iHS = read_data(3);
    new szWeapon[32];
    read_data(4, szWeapon, charsmax(szWeapon));
    
    PrintChatColor(iVictim, PRINT_COLOR_PLAYERTEAM, "!g[KillStreak]!y Your last kill streak: !t%i!y kills !t%i!y headshots!t %i!y HE kills!t %i!y Knife kills.",
    g_iKillStreak[iVictim][KILLS], g_iKillStreak[iVictim][HS], g_iKillStreak[iVictim][HE], g_iKillStreak[iVictim][KNIFE]);
    arrayset(g_iKillStreak[iVictim], 0, Streak);
    
    if (iKiller == iVictim || !is_user_connected(iKiller))
    {
        return;
    }
    
    g_iKillStreak[iKiller][KILLS]++;
    
    if (iHS == 1)
    {
        g_iKillStreak[iKiller][HS]++;
    }
    
    new iWeapon = get_weaponid(szWeapon);
    
    switch (iWeapon)
    {
        case CSW_KNIFE: g_iKillStreak[iKiller][KNIFE]++;
        case CSW_HEGRENADE: g_iKillStreak[iKiller][HE]++;
    }
} 

Заключено
  • Подобни теми
    Отговори
    Преглеждания
     Последно мнение

Обратно към “Заявки за плъгини”

Кой е на линия

Потребители разглеждащи този форум: 0 регистрирани и 13 госта