Преработка на Golden M4A1 в Golden AWP

В този раздел можете да подавате всякакви заявки за намиране, изработка или преработка на плъгини/модове.
Аватар
cgozzie
Извън линия
Потребител
Потребител
Мнения: 1318
Регистриран на: 13 Окт 2016, 22:10
Местоположение: Варна
Се отблагодари: 244 пъти
Получена благодарност: 42 пъти

Преработка на Golden M4A1 в Golden AWP

Мнение от cgozzie » 15 Яну 2017, 23:04

Ще ми преработите ли този плъгин да е за AWP + w_models да се добави в момента има само p_ v_ models.Защото модела на авп-то което ще ползвам садържа и w_models.

Код за потвърждение: Избери целия код


/* AMX Mod script
* 
* (c) 2013, Alicx[{DARK}((-__-))]
* 
*
*/

#define PLUGIN "Golden M4a1"

#include <amxmodx>
#include <fakemeta>
#include <fun>
#include <hamsandwich>
#include <cstrike>
#include <amxmisc>


#define is_valid_player(%1) (1 <= %1 <= 32)

new M4_V_MODEL[64] = "models/v_golden_m4a1.mdl"
new M4_P_MODEL[64] = "models/p_golden_m4a1.mdl"

/* Pcvars */
new cvar_dmgmultiplier, cvar_goldbullets,  cvar_custommodel, cvar_uclip, cvar_cost

new bool:g_HasM4[33]

new g_hasZoom[ 33 ]
new bullets[ 33 ]

// Sprite
new m_spriteTexture

const Wep_m4a1 = ((1<<CSW_M4A1))

public plugin_init()
{
	
	/* CVARS */
	cvar_dmgmultiplier = register_cvar("goldenm4_dmg_multiplier", "5")
	cvar_custommodel = register_cvar("goldenm4_custom_model", "1")
	cvar_goldbullets = register_cvar("goldenm4_gold_bullets", "1")
	cvar_uclip = register_cvar("goldenm4_unlimited_clip", "1")
	cvar_cost = register_cvar("goldenm4_cost", "6000")
	
	// Register The Buy Cmd
	register_clcmd("say /goldenm4", "CmdBuyM4")
	register_clcmd("say_team /goldenm4", "CmdBuyM4")
	register_concmd("amx_goldenm4", "CmdGiveM4", ADMIN_BAN, "<name>")
	
	// Register The Plugin
	register_plugin("Golden M4A1", "1.0", "Alicx DarK")
	// Death Msg
	register_event("DeathMsg", "Death", "a")
	// Weapon Pick Up
	register_event("WeapPickup","checkModel","b","1=19")
	// Current Weapon Event
	register_event("CurWeapon","checkWeapon","be","1=1")
	register_event("CurWeapon", "make_tracer", "be", "1=1", "3>0")
	// Ham TakeDamage
	RegisterHam(Ham_TakeDamage, "player", "fw_TakeDamage")
	register_forward( FM_CmdStart, "fw_CmdStart" )
	RegisterHam(Ham_Spawn, "player", "fwHamPlayerSpawnPost", 1)
	
}

public client_connect(id)
{
	g_HasM4[id] = false
}

public client_disconnect(id)
{
	g_HasM4[id] = false
}

public Death()
{
	g_HasM4[read_data(2)] = false
}

public fwHamPlayerSpawnPost(id)
{
	g_HasM4[id] = false
}

public plugin_precache()
{
	precache_model(M4_V_MODEL)
	precache_model(M4_P_MODEL)
	m_spriteTexture = precache_model("sprites/dot.spr")
	precache_sound("weapons/zoom.wav")
}

public checkModel(id)
{
	if ( !g_HasM4[id] )
		return PLUGIN_HANDLED
	
	new szWeapID = read_data(2)
	
	if ( szWeapID == CSW_M4A1 && g_HasM4[id] == true && get_pcvar_num(cvar_custommodel) )
	{
		set_pev(id, pev_viewmodel2, M4_V_MODEL)
		set_pev(id, pev_weaponmodel2, M4_P_MODEL)
	}
	return PLUGIN_HANDLED
}

public checkWeapon(id)
{
	new plrClip, plrAmmo, plrWeap[32]
	new plrWeapId
	
	plrWeapId = get_user_weapon(id, plrClip , plrAmmo)
	
	if (plrWeapId == CSW_M4A1 && g_HasM4[id])
	{
		checkModel(id)
	}
	else 
	{
		return PLUGIN_CONTINUE
	}
	
	if (plrClip == 0 && get_pcvar_num(cvar_uclip))
	{
		// If the user is out of ammo..
		get_weaponname(plrWeapId, plrWeap, 31)
		// Get the name of their weapon
		give_item(id, plrWeap)
		engclient_cmd(id, plrWeap) 
		engclient_cmd(id, plrWeap)
		engclient_cmd(id, plrWeap)
	}
	return PLUGIN_HANDLED
}



public fw_TakeDamage(victim, inflictor, attacker, Float:damage)
{
	if ( is_valid_player( attacker ) && get_user_weapon(attacker) == CSW_M4A1 && g_HasM4[attacker] )
	{
		SetHamParamFloat(4, damage * get_pcvar_float( cvar_dmgmultiplier ) )
	}
}

public fw_CmdStart( id, uc_handle, seed )
{
	if( !is_user_alive( id ) ) 
		return PLUGIN_HANDLED
	
	if( ( get_uc( uc_handle, UC_Buttons ) & IN_ATTACK2 ) && !( pev( id, pev_oldbuttons ) & IN_ATTACK2 ) )
	{
		new szClip, szAmmo
		new szWeapID = get_user_weapon( id, szClip, szAmmo )
		
		if( szWeapID == CSW_M4A1 && g_HasM4[id] == true && !g_hasZoom[id] == true)
		{
			g_hasZoom[id] = true
			cs_set_user_zoom( id, CS_SET_AUGSG552_ZOOM, 0 )
			emit_sound( id, CHAN_ITEM, "weapons/zoom.wav", 0.20, 2.40, 0, 100 )
		}
		
		else if ( szWeapID == CSW_M4A1 && g_HasM4[id] == true && g_hasZoom[id])
		{
			g_hasZoom[ id ] = false
			cs_set_user_zoom( id, CS_RESET_ZOOM, 0 )
			
		}
		
	}
	return PLUGIN_HANDLED
}


public make_tracer(id)
{
	if (get_pcvar_num(cvar_goldbullets))
	{
		new clip,ammo
		new wpnid = get_user_weapon(id,clip,ammo)
		new pteam[16]
		
		get_user_team(id, pteam, 15)
		
		if ((bullets[id] > clip) && (wpnid == CSW_M4A1) && g_HasM4[id]) 
		{
			new vec1[3], vec2[3]
			get_user_origin(id, vec1, 1) // origin; your camera point.
			get_user_origin(id, vec2, 4) // termina; where your bullet goes (4 is cs-only)
			
			
			//BEAMENTPOINTS
			message_begin( MSG_BROADCAST,SVC_TEMPENTITY)
			write_byte (0)     //TE_BEAMENTPOINTS 0
			write_coord(vec1[0])
			write_coord(vec1[1])
			write_coord(vec1[2])
			write_coord(vec2[0])
			write_coord(vec2[1])
			write_coord(vec2[2])
			write_short( m_spriteTexture )
			write_byte(1) // framestart
			write_byte(5) // framerate
			write_byte(2) // life
			write_byte(10) // width
			write_byte(0) // noise
			write_byte( 255 )     // r, g, b
			write_byte( 215 )       // r, g, b
			write_byte( 0 )       // r, g, b
			write_byte(200) // brightness
			write_byte(150) // speed
			message_end()
		}
		
		bullets[id] = clip
	}
	
}

public CmdBuyM4(id)
{
	if ( !is_user_alive(id) )
	{
		client_print(id,print_chat, "[AMXX] To buy golden M4a1 You need to be alive!")
		return PLUGIN_HANDLED
	}
	
	new money = cs_get_user_money(id)
	
	if (money >= get_pcvar_num(cvar_cost))
	{
		cs_set_user_money(id, money - get_pcvar_num(cvar_cost))
		give_item(id, "weapon_m4a1")
		g_HasM4[id] = true
	}
	
	else
	{
		client_print(id, print_chat, "[AMXX] You dont hav enough money to buy Golden M4a1. Cost $%d ", get_pcvar_num(cvar_cost))
	}
	return PLUGIN_HANDLED
}

public CmdGiveM4(id,level,cid)
{
	if (!cmd_access(id,level,cid,2))
		return PLUGIN_HANDLED;
	new arg[32];
	read_argv(1,arg,31);
	
	new player = cmd_target(id,arg,7);
	if (!player) 
		return PLUGIN_HANDLED;
	
	new name[32];
	get_user_name(player,name,31);
	
	give_item(player, "weapon_m4a1")
	g_HasM4[player] = true
	
	return PLUGIN_HANDLED
}

stock drop_prim(id) 
{
	new weapons[32], num
	get_user_weapons(id, weapons, num)
	for (new i = 0; i < num; i++) {
		if (Wep_m4a1 & (1<<weapons[i])) 
		{
			static wname[32]
			get_weaponname(weapons[i], wname, sizeof wname - 1)
			engclient_cmd(id, "drop", wname)
		}
	}
}
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1034\\ f0\\ fs16 \n\\ par }
*/
Изображение

Аватар
Unbr3akable
Извън линия
Потребител
Потребител
Мнения: 178
Регистриран на: 21 Дек 2016, 20:50
Получена благодарност: 6 пъти

Re: Преработка на Golden M4A1 в Golden AWP

Мнение от Unbr3akable » 15 Яну 2017, 23:36

Код за потвърждение: Избери целия код

/* AMX Mod script
* 
* (c) 2013, Alicx[{DARK}((-__-))]
* 
*
*/

#define PLUGIN "Golden AWP"

#include <amxmodx>
#include <fakemeta>
#include <engine>
#include <fun>
#include <hamsandwich>
#include <cstrike>
#include <amxmisc>


#define is_valid_player(%1) (1 <= %1 <= 32)

new AWP_V_MODEL[64] = "models/v_golden_awp.mdl"
new AWP_P_MODEL[64] = "models/p_golden_awp.mdl"
new AWP_W_MODEL[64] = "models/w_golden_awp.mdl"

new OLD_W_MODEL[64] = "models/w_awp.mdl"

/* Pcvars */
new cvar_dmgmultiplier, cvar_goldbullets,  cvar_custommodel, cvar_uclip, cvar_cost

new bool:g_HasAWP[33]

new bullets[ 33 ]

// Sprite
new m_spriteTexture

const Wep_awp = ((1<<CSW_AWP))

public plugin_init()
{
   
   /* CVARS */
   cvar_dmgmultiplier = register_cvar("goldenawp_dmg_multiplier", "5")
   cvar_custommodel = register_cvar("goldenawp_custom_model", "1")
   cvar_goldbullets = register_cvar("goldenawp_gold_bullets", "1")
   cvar_uclip = register_cvar("goldenawp_unlimited_clip", "1")
   cvar_cost = register_cvar("goldenawp_cost", "6000")
   
   // Register The Buy Cmd
   register_clcmd("say /goldenawp", "CmdBuyAWP")
   register_clcmd("say_team /goldenawp", "CmdBuyAWP")
   register_concmd("amx_goldenawp", "CmdGiveAWP", ADMIN_BAN, "<name>")
   
   // Register The Plugin
   register_plugin("Golden AWP Edit", "1.0", "Alicx DarK")
   // Death Msg
   register_event("DeathMsg", "Death", "a")
   // Weapon Pick Up
   register_event("WeapPickup","checkModel","b","1=19")
   // Current Weapon Event
   register_event("CurWeapon","checkWeapon","be","1=1")
   register_event("CurWeapon", "make_tracer", "be", "1=1", "3>0")
   // Ham TakeDamage
   RegisterHam(Ham_TakeDamage, "player", "fw_TakeDamage")
   register_forward(FM_SetModel, "fw_SetModel")
   RegisterHam(Ham_Spawn, "player", "fwHamPlayerSpawnPost", 1)
   
}

public client_connect(id)
{
   g_HasAWP[id] = false
}

public client_disconnect(id)
{
   g_HasAWP[id] = false
}

public Death()
{
   g_HasAWP[read_data(2)] = false
}

public fwHamPlayerSpawnPost(id)
{
   g_HasAWP[id] = false
}

public plugin_precache()
{
   precache_model(AWP_V_MODEL)
   precache_model(AWP_P_MODEL)
   precache_model(AWP_W_MODEL)
   m_spriteTexture = precache_model("sprites/dot.spr")
}

public checkModel(id)
{
   if ( !g_HasAWP[id] )
      return PLUGIN_HANDLED
   
   new szWeapID = read_data(2)
   
   if ( szWeapID == CSW_AWP && g_HasAWP[id] == true && get_pcvar_num(cvar_custommodel) )
   {
      set_pev(id, pev_viewmodel2, AWP_V_MODEL)
      set_pev(id, pev_weaponmodel2, AWP_P_MODEL)
   }
   return PLUGIN_HANDLED
}

public fw_SetModel(entity, model[])
{
    if(!is_valid_ent(entity)) 
        return FMRES_IGNORED

    if(!equali(model, OLD_W_MODEL)) 
        return FMRES_IGNORED

    new className[33]
    entity_get_string(entity, EV_SZ_classname, className, 32)
    
    if(equal(className, "weaponbox") || equal(className, "armoury_entity") || equal(className, "grenade"))
    {
        engfunc(EngFunc_SetModel, entity, AWP_W_MODEL)
        return FMRES_SUPERCEDE
    }
    return FMRES_IGNORED
} 

public checkWeapon(id)
{
   new plrClip, plrAmmo, plrWeap[32]
   new plrWeapId
   
   plrWeapId = get_user_weapon(id, plrClip , plrAmmo)
   
   if (plrWeapId == CSW_AWP && g_HasAWP[id])
   {
      checkModel(id)
   }
   else 
   {
      return PLUGIN_CONTINUE
   }
   
   if (plrClip == 0 && get_pcvar_num(cvar_uclip))
   {
      // If the user is out of ammo..
      get_weaponname(plrWeapId, plrWeap, 31)
      // Get the name of their weapon
      give_item(id, plrWeap)
      engclient_cmd(id, plrWeap) 
      engclient_cmd(id, plrWeap)
      engclient_cmd(id, plrWeap)
   }
   return PLUGIN_HANDLED
}



public fw_TakeDamage(victim, inflictor, attacker, Float:damage)
{
   if ( is_valid_player( attacker ) && get_user_weapon(attacker) == CSW_AWP && g_HasAWP[attacker] )
   {
      SetHamParamFloat(4, damage * get_pcvar_float( cvar_dmgmultiplier ) )
   }
}

public make_tracer(id)
{
   if (get_pcvar_num(cvar_goldbullets))
   {
      new clip,ammo
      new wpnid = get_user_weapon(id,clip,ammo)
      new pteam[16]
      
      get_user_team(id, pteam, 15)
      
      if ((bullets[id] > clip) && (wpnid == CSW_AWP) && g_HasAWP[id]) 
      {
         new vec1[3], vec2[3]
         get_user_origin(id, vec1, 1) // origin; your camera point.
         get_user_origin(id, vec2, 4) // termina; where your bullet goes (4 is cs-only)
         
         
         //BEAMENTPOINTS
         message_begin( MSG_BROADCAST,SVC_TEMPENTITY)
         write_byte (0)     //TE_BEAMENTPOINTS 0
         write_coord(vec1[0])
         write_coord(vec1[1])
         write_coord(vec1[2])
         write_coord(vec2[0])
         write_coord(vec2[1])
         write_coord(vec2[2])
         write_short( m_spriteTexture )
         write_byte(1) // framestart
         write_byte(5) // framerate
         write_byte(2) // life
         write_byte(10) // width
         write_byte(0) // noise
         write_byte( 255 )     // r, g, b
         write_byte( 215 )       // r, g, b
         write_byte( 0 )       // r, g, b
         write_byte(200) // brightness
         write_byte(150) // speed
         message_end()
      }
      
      bullets[id] = clip
   }
   
}

public CmdBuyAWP(id)
{
   if ( !is_user_alive(id) )
   {
      client_print(id,print_chat, "[AMXX] To buy golden AWP You need to be alive!")
      return PLUGIN_HANDLED
   }
   
   new money = cs_get_user_money(id)
   
   if (money >= get_pcvar_num(cvar_cost))
   {
      cs_set_user_money(id, money - get_pcvar_num(cvar_cost))
      give_item(id, "weapon_awp")
      g_HasAWP[id] = true
   }
   
   else
   {
      client_print(id, print_chat, "[AMXX] You dont hav enough money to buy Golden AWP. Cost $%d ", get_pcvar_num(cvar_cost))
   }
   return PLUGIN_HANDLED
}

public CmdGiveAWP(id,level,cid)
{
   if (!cmd_access(id,level,cid,2))
      return PLUGIN_HANDLED;
   new arg[32];
   read_argv(1,arg,31);
   
   new player = cmd_target(id,arg,7);
   if (!player) 
      return PLUGIN_HANDLED;
   
   new name[32];
   get_user_name(player,name,31);
   
   give_item(player, "weapon_awp")
   g_HasAWP[player] = true
   
   return PLUGIN_HANDLED
}

stock drop_prim(id) 
{
   new weapons[32], num
   get_user_weapons(id, weapons, num)
   for (new i = 0; i < num; i++) {
      if (Wep_awp & (1<<weapons[i])) 
      {
         static wname[32]
         get_weaponname(weapons[i], wname, sizeof wname - 1)
         engclient_cmd(id, "drop", wname)
      }
   }
}
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1034\\ f0\\ fs16 \n\\ par }
*/ 
Моделите ги добавяш в cstrike/models с имена: v_golden_awp.mdl, p_golden_awp.mdl, w_golden_awp.mdl

Аватар
cgozzie
Извън линия
Потребител
Потребител
Мнения: 1318
Регистриран на: 13 Окт 2016, 22:10
Местоположение: Варна
Се отблагодари: 244 пъти
Получена благодарност: 42 пъти

Re: Преработка на Golden M4A1 в Golden AWP

Мнение от cgozzie » 15 Яну 2017, 23:47

Благодаря ти всичко работи 10/10 ..:) заключете темата..
Изображение

Заключено
  • Подобни теми
    Отговори
    Преглеждания
     Последно мнение

Обратно към “Заявки за плъгини”

Кой е на линия

Потребители разглеждащи този форум: 0 регистрирани и 14 госта