Заявка за auto restart round

[bg-bb]

Здравейте, може ли да се изработи плъгин auto restart round защото когато има един човек във сървъра и VZBB Fun Mode не се активира в първия рунд.Когато аз го рестартирам рунда VZBB Fun Mode се активира.

[impossible]

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <reapi>

#define WARMUP_DURATION 45
#define RESET_DELAY 3

#define HUD_MESSAGE "Warmup: %i sekundi"
#define CHAT_MESSAGE "^3[Warmup] ^1Ostavat oshte ^4%i ^1sekundi."

#define HUD_MESSAGE_END "Warmup zavurshi!^nIgrata zapochva sled %i sekundi!"
#define CHAT_MESSAGE_END "^3[Warmup] ^1Igrata zapochva sled ^4%i ^1sekundi!"
#define CHAT_MESSAGE_REPEAT 3

#define HUD_COLOR 0, 255, 0
#define HUD_POSITION -1.0, 0.2

#define HUD_FREQ 1.0
#define TASK_WARMUP 332912

new bool:g_bWarmupEnded, g_iObject, g_iCountdown;

public plugin_init()
{
	register_plugin("Warmup with Countdown", "1.0", "OciXCrom");
	register_logevent("OnFirstRound", 2, "0=World triggered", "1&Restart_Round_");
	register_logevent("OnFirstRound", 2, "0=World triggered", "1=Game_Commencing");
	RegisterHookChain(RG_CBasePlayer_OnSpawnEquip, "OnSpawnEquip");
	g_iObject = CreateHudSyncObj();
	OnFirstRound();
}

public OnSpawnEquip(id)
{
	if(g_bWarmupEnded)
		return HC_CONTINUE;

	rg_give_item(id, "weapon_knife");
	rg_give_item(id, "weapon_deagle");
	rg_set_user_bpammo(id, WEAPON_DEAGLE, 35);
	rg_add_account(id, 0, AS_SET);

	return HC_SUPERCEDE;
}

public OnFirstRound()
{
	if(g_bWarmupEnded)
		return;

	remove_task(TASK_WARMUP);
	g_iCountdown = WARMUP_DURATION;
	set_task(HUD_FREQ, "DisplayMessage", TASK_WARMUP, .flags = "b");
}

public DisplayMessage()
{
	set_hudmessage(HUD_COLOR, HUD_POSITION, 0, 0.1, 5.0, 0.1, 0.1);

	if(--g_iCountdown == 0)
	{
		server_cmd("sv_restartround %i", RESET_DELAY);
		ShowSyncHudMsg(0, g_iObject, HUD_MESSAGE_END, RESET_DELAY);

		for(new i; i < CHAT_MESSAGE_REPEAT; i++)
			client_print_color(0, 0, CHAT_MESSAGE_END, RESET_DELAY);

		remove_task(TASK_WARMUP);
		g_bWarmupEnded = true;
		return;
	}

	ShowSyncHudMsg(0, g_iObject, HUD_MESSAGE, g_iCountdown);
	client_print_color(0, 0, CHAT_MESSAGE, g_iCountdown);
}

[bg-bb]

От къде се сменят секундите?Искам да го напрая на 3 секунди.

[impossible]

3 секунди загряващ рунд ?

Код за потвърждение: Избери целия код

#define WARMUP_DURATION 3

[bg-bb]

Мерси лок!