Заявка за плъгин - Simple connect + VIP Connect + VIP List

[Stilex]

Играчите който ще влизат в сървъра да им показва така
[Prefix] Player KaHuBalL (STEAM_ID) connected to server
[Prefix] Player KaHuBalL (STEAM_ID) left to server
Вип играчите да им показва така и със флаг b
[Prefix] VIP KaHuBalL (STEAM_ID) connected to server
[Prefix] VIP KaHuBalL (STEAM_ID) left to server
А за вип листа да показва така и пак на флаг b
[Prefix] VIP Online: KaHuBalL, Proto, AdmBAD - и т.н
[Prefix] Iskash da si VIP? Molq svurji se sus OWNER

Това всичко да е във един код. Да сте ме разбрали.

[illusion]

Код за потвърждение: Избери целия код

#include <amxmodx>

#define PLUGIN_NAME "ILLUSION PLUGINS: Show Admins/Connections"
#define PLUGIN_VERSION "1.0"
#define PLUGIN_AUTHOR "illusion"

#define VIP_FLAG ADMIN_RESERVATION

new g_iChatPrefix[32]

public plugin_init()
{
	register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR)
	register_clcmd("say /vips", "CmdVipsOnline")
	register_clcmd("say_team /vips", "CmdVipsOnline")

	bind_pcvar_string(create_cvar("chat_prefix_sac", "^1[^3Your^4Prefix^1]", FCVAR_NONE, "Prefix appears in chat"), g_iChatPrefix, charsmax(g_iChatPrefix))

	AutoExecConfig(true, "ILLUSION_ShowAdminsConn")
}

public CmdVipsOnline(id) 
{
	new Vips[16], aCounter = 0
	new MaxP[32], pCounter, player 
	get_players(MaxP, pCounter, "ch") 
	
	for (new i=0 ; i<pCounter ; i++) 
	{ 
		player = MaxP[i] 
		
		if(get_user_flags(player) & VIP_FLAG)
		{
			Vips[aCounter] = player 
			aCounter++ 
			continue; 
		} 
	}          
	
	if (aCounter == 0)    
	{  
		client_print_color(id, print_team_default, "%s ^4Online VIP's ^1: ^4No Online VIP's", g_iChatPrefix)  
	}  
	else
	{  
		new viponline[200]  
		new vipname[32], iVipID  
		
		for (new z=0 ; z<aCounter ; z++)  
		{  
			iVipID = Vips[z]  
			get_user_name(iVipID, vipname, 31)  
			add(viponline, charsmax(viponline), vipname)  
			
			if (z != aCounter-1)  
			{  
				add(viponline, charsmax(viponline), "^1, ")  
			}  
		} 

		client_print_color(id, print_team_default, "%s ^4Online VIP's ^1: ^3%s^1.", g_iChatPrefix, viponline)
		client_print_color(id, print_team_default, "%s ^1Iskash da si ^4VIP^1? Molq ^4svurji se sus ^3OWNER", g_iChatPrefix)

	} 
}

public client_connect(id)
{
	new UserName[MAX_NAME_LENGTH], szAuthID[MAX_AUTHID_LENGTH]

	get_user_name(id, UserName, charsmax(UserName))
	get_user_authid(id, szAuthID, charsmax(szAuthID))

	if(get_user_flags(id) & VIP_FLAG)
	{
		client_print_color(id, print_team_default, "%s ^4VIP ^3%s ^1(^3%s^1) ^4connected ^1to server", g_iChatPrefix, UserName, szAuthID)
	}
	else {
		client_print_color(id, print_team_default, "%s ^4Player ^3%s ^1(^3%s^1) ^4connected ^1to server", g_iChatPrefix, UserName, szAuthID)
	}
}

public client_disconnected(id)
{
	new UserName[MAX_NAME_LENGTH], szAuthID[MAX_AUTHID_LENGTH]

	get_user_name(id, UserName, charsmax(UserName))
	get_user_authid(id, szAuthID, charsmax(szAuthID))

	if(get_user_flags(id) & VIP_FLAG)
	{
		client_print_color(id, print_team_default, "%s ^4VIP ^3%s ^1(^3%s^1) ^4disconnected ^1from server", g_iChatPrefix, UserName, szAuthID)
	}
	else {
		client_print_color(id, print_team_default, "%s ^4Player ^3%s ^1(^3%s^1) ^4disconnected ^1from server", g_iChatPrefix, UserName, szAuthID)
	}
}

До колкото разбрах искаш това, тествай. Като сложиш плъгина ще се създаде папка в configs на име "plugins" (ако вече я нямаш) и в нея ще имаш файл "ILLUSION_ShowAdminsConn.cfg", от там си редактираш чат префикса. Вип листа го отваряш с команда /vips.

Плъгина не съм го тествал.

[Stilex]

Работи както трябва тествах го.
Ключ.