AFK system

[MF1]

Здравейте !
Търся afk system който при командата /afk , прави екрана черен и ти ''замръзваш'' и трябва да ти излиза само съобщение само когато си под този ефект на плъгина '' Type /back to continue game '' или както е там
Търсих плъгина но не успях да го намеря, а и се замислих да не би да е private ? Благодаря на този който ми помогне с намирането или изработката

Amxx-bg.info ! - най-добрите !

[JustInCase]

То хубаво замръзваш ама как така ? Обясни повечко играчът остава на мястото си и е безсмъртен или ?

[Petrowch0]

Виж това.

[MF1]

То хубаво замръзваш ама как така ? Обясни повечко играчът остава на мястото си и е безсмъртен или ?

офф че съм зле, точно тук изтървах..
да има protection със активирането на командата.

[JustInCase]

Виж това което петровчо е дал.

[MF1]

Виж това.

Сървъра крашна
и изгони играчите

[RideeR ;]]

Според мен няма смисъл от това, просто направи /spec, /back.

[MF1]

Имам този, но този ми харесва повече и по предпочитан, доста хора ми го предложиха...

[TheRedShoko]

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <fakemeta>
#include <engine>
#include <WPMGPrintChatColor>

new bool:g_blIsUserAfk[33];
new g_iMsgFade, g_iMaxPlayers;

new const g_szThinkingEntity[] = "afk_freezer_ent";

public plugin_init()
{
    register_plugin("AFK freezer", "1.0", "TheRedShoko @ AMXX-BG.info");
    
    register_clcmd("say /afk", "CommandGoAfk");
    register_clcmd("say /back", "CommandGetBack");
    
    g_iMsgFade = get_user_msgid("ScreenFade");
    g_iMaxPlayers = get_maxplayers();
    
    new iEnt = create_entity("info_target");
    
    if (iEnt)
    {
        register_think(g_szThinkingEntity, "FwAfkThinking");
        
        entity_set_string(iEnt, EV_SZ_classname, g_szThinkingEntity);
        entity_set_float(iEnt, EV_FL_nextthink, get_gametime() + 0.1);
    }
}

public FwAfkThinking(iEnt)
{
    if (!is_valid_ent(iEnt))
    {
        return;
    }
    
    static i;
    
    for (i = 1; i <= g_iMaxPlayers; i++)
    {
        if (!is_user_connected(i) || !is_user_alive(i) || !g_blIsUserAfk[i]) continue;
        
        client_print(i, print_center, "You are afk, type /back to get in game!");
    }
    
    entity_set_float(iEnt, EV_FL_nextthink, get_gametime() + 10.0);
}

public CommandGoAfk(id)
{
    if (g_blIsUserAfk[id])
    {
        return PLUGIN_HANDLED;
    }
    
    g_blIsUserAfk[id] = true;
    
    entity_set_int(id, EV_INT_flags, entity_get_int(id, EV_INT_flags) | FL_FROZEN);
    entity_set_float(id, EV_FL_takedamage, DAMAGE_NO);
    ShowFade(id, 255);
    client_print(id, print_center, "You are afk, type /back to get in game!");
    set_rendering(id, kRenderFxGlowShell, 255, 255, 255);
    
    return PLUGIN_HANDLED;
}

public CommandGetBack(id)
{
    if (!g_blIsUserAfk[id])
    {
        return PLUGIN_HANDLED;
    }
    
    g_blIsUserAfk[id] = false;
    
    PrintChatColor(id, PRINT_COLOR_PLAYERTEAM, "!g[AfkFreezer]!y You are no longer afk!");
    
    client_print(id, print_center, "");
    ShowFade(id, 0);
    entity_set_float(id, EV_FL_takedamage, DAMAGE_AIM);
    entity_set_int(id, EV_INT_flags, entity_get_int(id, EV_INT_flags) & ~FL_FROZEN);
    set_rendering(id);
    
    return PLUGIN_HANDLED;
}

ShowFade(index, alpha)
{
    message_begin(MSG_ONE, g_iMsgFade, _, index)
    write_short(1<<1);
    write_short(1<<1);
    write_short(alpha == 0 ? 0x0000 : 0x0004);
    write_byte(0);
    write_byte(0);
    write_byte(0);
    write_byte(alpha); 
    message_end();
} 

[MF1]

И както винаги, невероятен ! Благодаря !