Заявка за admin skin plugin

[OciXCrom]

Ползвай този тук - https://amxx-bg.info/forum/viewtopic.php?f=53&t=1671#p8104
Моделите се добавят в g_szModelsCT и g_szModelsT.

[smtng]

А как трябва да стане с тези, защото извинявай но нещо неможах да те разбера : cs-vraca_admin_ct, cs-vraca_admin_t, cs-vraca_girl_ct, cs-vraca_girl_t

[OciXCrom]

В кода са добавени тези:

Код за потвърждение: Избери целия код

new const g_szTSkins[][] = { "arctic_red", "guerilla_red", "leet_red", "terror_red" }
new const g_szCTSkins[][] = { "gign_red", "gsg9_red", "sas_red", "urban_red" } 

... съответно замени ги с твоите. Първите са за Т, вторите за СТ.

[smtng]

Благодаря ти получи се искам само още нещо да те попитам а как да го направя с 2 различни флага тоест един за мъжките и един за женските флагове защото до колкото виждам сега всички са със този флаг ADMIN_MENU и в случея пуска само мъжките модели.

[OciXCrom]

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cstrike>
#include <hamsandwich>

#define ADMIN_MALE ADMIN_MENU
#define ADMIN_FEMALE ADMIN_BAN

new const g_szTSkinsM[][] = { "cs-vraca_admin_t" }
new const g_szTSkinsF[][] = { "cs-vraca_girl_t" }
new const g_szCTSkinsM[][] = { "cs-vraca_admin_ct" }
new const g_szCTSkinsF[][] = { "cs-vraca_girl_ct" }

public plugin_init()
{
    register_plugin("Admin Models", "1.0", "OciXCrom @ amxx-bg.info/forum")
    RegisterHam(Ham_Spawn, "player", "OnPlayerSpawn", 1)
}

public plugin_precache()
{
    for(new i; i < sizeof(g_szTSkinsM); i++)
        precache_player_model(g_szTSkinsM[i])
        
    for(new i; i < sizeof(g_szTSkinsF); i++)
        precache_player_model(g_szTSkinsF[i])
        
    for(new i; i < sizeof(g_szCTSkinsM); i++)
        precache_player_model(g_szCTSkinsM[i])
        
    for(new i; i < sizeof(g_szCTSkinsF); i++)
        precache_player_model(g_szCTSkinsF[i])
}

public OnPlayerSpawn(id)
{
    if(is_user_alive(id))
    {
        new iFlags = get_user_flags(id)
        
        if(iFlags & ADMIN_MALE)
        {
            switch(cs_get_user_team(id))
            {
                case CS_TEAM_T: cs_set_user_model(id, g_szTSkinsM[random(sizeof(g_szTSkinsM))])
                case CS_TEAM_CT: cs_set_user_model(id, g_szCTSkinsM[random(sizeof(g_szCTSkinsM))])
            }
        }
        else if(iFlags & ADMIN_FEMALE)
        {
            switch(cs_get_user_team(id))
            {
                case CS_TEAM_T: cs_set_user_model(id, g_szTSkinsF[random(sizeof(g_szTSkinsF))])
                case CS_TEAM_CT: cs_set_user_model(id, g_szCTSkinsF[random(sizeof(g_szCTSkinsF))])
            }
        }
        else cs_reset_user_model(id)
    }
}

precache_player_model(szModel[])
{
    static szFile[128]
    formatex(szFile, charsmax(szFile), "models/player/%s/%s.mdl", szModel, szModel)
    precache_model(szFile)
    replace(szFile, charsmax(szFile), ".mdl", "T.mdl")
    
    if(file_exists(szFile))
        precache_model(szFile)
} 

[smtng]

Не ми позволява да го компилирам ще прикача снимка на грешката
П.П. оправи се от втория път като го компилирах