Заявка за VIP Plugin

В този раздел можете да подавате всякакви заявки за намиране, изработка или преработка на плъгини/модове.
Аватар
DoPe ;]]
Извън линия
Потребител
Потребител
Мнения: 402
Регистриран на: 27 Фев 2017, 22:10
Обратна връзка:

Заявка за VIP Plugin

Мнение от DoPe ;]] » 27 Фев 2017, 23:04

Всеки рунд:
1HE,2FB,1SG
Deagle 7/35(Да премахва основния пистолет)
100Armor
110 HP
и като някой напише /vip да му излиза MOTD в което да пише какво включва VIP-а, и /vips, като някой го напише да му показва кой е вип.
Благодаря предварително!
The Best Deathrun Server: 79.124.49.91:27019
The Best Respawn Server: 79.124.49.88:27021

Аватар
OciXCrom
Извън линия
Администратор
Администратор
Мнения: 7206
Регистриран на: 06 Окт 2016, 19:20
Местоположение: /resetscore
Се отблагодари: 117 пъти
Получена благодарност: 1295 пъти
Обратна връзка:

Re: Заявка за VIP Plugin

Мнение от OciXCrom » 28 Фев 2017, 02:58

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cstrike>
#include <fun>
#include <hamsandwich>
#include <stripweapons>

#define MOTD_FILE "vip.txt"
#define VIP_FLAG ADMIN_RESERVATION
#define VIP_HEALTH 110
#define VIP_ARMOR 100

public plugin_init()
{
    register_plugin("VIP Extras", "1.0", "OciXCrom @ amxx-bg.info/forum")
    RegisterHam(Ham_Spawn, "player", "OnPlayerSpawn", true)
    
    register_clcmd("say /vip", "ShowMotd")
    register_clcmd("say_team /vip", "ShowMotd")
    register_clcmd("say /vips", "ShowMenu")
    register_clcmd("say_team /vips", "ShowMenu")
}

public OnPlayerSpawn(id)
{
    if(!is_user_alive(id) || !is_user_vip(id))
        return
    
    StripWeapons(id, Secondary)
    give_item(id, "weapon_hegrenade")
    give_item(id, "weapon_flashbang")
    give_item(id, "weapon_flashbang")
    give_item(id, "weapon_smokegrenade")
    
    give_item(id, "weapon_deagle")
    cs_set_user_bpammo(id, CSW_DEAGLE, 35)
    set_user_health(id, VIP_HEALTH)
    set_user_armor(id, VIP_ARMOR)
}

public ShowMotd(id)
{
    show_motd(id, MOTD_FILE)
    return PLUGIN_HANDLED
}

public ShowMenu(id)
{
    static szItem[32], iPlayers[32], iPnum, iMenu, i, iPlayer
    get_players(iPlayers, iPnum)
    iMenu = menu_create("", "MenuHandler")
    
    for(i = 0; i < iPnum; i++)
    {
        iPlayer = iPlayers[i]
        
        if(is_user_vip(iPlayer))
        {
            get_user_name(iPlayer, szItem, charsmax(szItem))
            menu_additem(iMenu, szItem)
        }
    }
    
    formatex(szItem, charsmax(szItem), "\r%i \yVIPs Online\d", menu_items(iMenu))
    menu_setprop(iMenu, MPROP_TITLE, szItem)
    menu_display(id, iMenu)
    return PLUGIN_HANDLED
}

public MenuHandler(id, iMenu, iItem)
{
    menu_destroy(iMenu)
    return PLUGIN_HANDLED
}

bool:is_user_vip(id)
    return bool:(get_user_flags(id) & VIP_FLAG)
Писах го от телефона, тъй че не е тествано. Настрой флага и motd файла от настройките най-отгоре.

ПС - преди да кажеш, че при компилация ти изписва "cannot read from file stripweapons", прочети тази тема.

Аватар
DoPe ;]]
Извън линия
Потребител
Потребител
Мнения: 402
Регистриран на: 27 Фев 2017, 22:10
Обратна връзка:

Re: Заявка за VIP Plugin

Мнение от DoPe ;]] » 28 Фев 2017, 13:34

Мерси много, става :)
The Best Deathrun Server: 79.124.49.91:27019
The Best Respawn Server: 79.124.49.88:27021

Заключено
  • Подобни теми
    Отговори
    Преглеждания
     Последно мнение

Обратно към “Заявки за плъгини”

Кой е на линия

Потребители разглеждащи този форум: Bing [Bot] и 13 госта