Добър вечер, използвам на OciXCrom плъгина от тази тема: http://amxx-bg.info/forum/viewtopic.php?f=53&t=967&start=10
Ако може да се добави команда чрез която да се скрива HUD-a или да се изработи отделен плъгин за тази цел.
Благодаря.
Преработка на HappyHour плъгин.
-
OciXCrom
Извън линия - Администратор
- Мнения: 7206
- Регистриран на: 06 Окт 2016, 19:20
- Местоположение: /resetscore
- Се отблагодари: 117 пъти
- Получена благодарност: 1295 пъти
- Обратна връзка:
Re: Преработка на HappyHour плъгин.
/hidehud
Код за потвърждение: Избери целия код
#include <amxmodx>
#include <fun>
#if AMXX_VERSION_NUM < 183
#include <fmt>
#endif
#define PLUGIN_VERSION "1.0"
#define TASK_MESSAGE 383822
enum _:HappyHour
{
Name[16],
Start,
End,
Frags
}
new const g_eHappyHour[][HappyHour] =
{
{ "Dust", 7, 17, 2 },
{ "Classic", 18, 19, 3 }
}
new g_iBonus
new g_iObject
new g_msgSayText
new g_szMessage[128]
new bool:g_bDisabled[33]
new const g_szPrefix[] = "^4[HappyHour]^1"
public plugin_init()
{
register_plugin("Happy Hour", PLUGIN_VERSION, "OciXCrom @ amxx-bg.info/forum")
register_event("DeathMsg", "OnPlayerKilled", "a", "1>0", "2>0", "1!2")
register_logevent("OnRoundStart", 2, "1=Round_Start")
register_clcmd("say /hidehud", "ToggleHUD")
register_clcmd("say_team /hidehud", "ToggleHUD")
g_msgSayText = get_user_msgid("SayText")
g_iObject = CreateHudSyncObj()
OnRoundStart()
}
public client_disconnect(id)
remove_task(id + TASK_MESSAGE)
public client_putinserver(id)
{
g_bDisabled[id] = false
set_task(1.0, "DisplayMessage", id + TASK_MESSAGE, .flags = "b")
}
public ToggleHUD(id)
{
g_bDisabled[id] = g_bDisabled[id] ? false : true
ColorChat(id, "HUD has been ^4%s", g_bDisabled[id] ? "disabled" : "enabled")
return PLUGIN_HANDLED
}
public OnRoundStart()
{
g_iBonus = 0
copy(g_szMessage, charsmax(g_szMessage), "Igraite bez hackove!^n")
new iHour; time(iHour)
for(new i; i < sizeof(g_eHappyHour); i++)
{
if(g_eHappyHour[i][Start] <= iHour <= g_eHappyHour[i][End])
{
g_iBonus = g_eHappyHour[i][Frags]
ColorChat(0, "+%i points/frags!", g_iBonus)
break
}
}
for(new i; i < sizeof(g_eHappyHour); i++)
add(g_szMessage, charsmax(g_szMessage), fmt("Happy Hour%s: %s^n", g_eHappyHour[i][Name], g_iBonus == g_eHappyHour[i][Frags] ? fmt("(ON)") : fmt("%i:00 do %i:00", g_eHappyHour[i][Start], g_eHappyHour[i][End])))
}
public OnPlayerKilled()
{
if(g_iBonus)
{
new iKiller = read_data(1)
set_user_frags(iKiller, get_user_frags(iKiller) + (g_iBonus - 1))
}
}
public DisplayMessage(id)
{
id -= TASK_MESSAGE
if(g_bDisabled[id])
return
set_hudmessage(random(256), random(256), random(256), 0.02, 0.18, 1, 2.0, 1.0, 0.5, 1.0, -1)
ShowSyncHudMsg(id, g_iObject, g_szMessage)
}
ColorChat(const id, const szInput[], any:...)
{
new iPlayers[32], iCount = 1
static szMessage[191]
vformat(szMessage, charsmax(szMessage), szInput, 3)
format(szMessage[0], charsmax(szMessage), "%s %s", g_szPrefix, szMessage)
replace_all(szMessage, charsmax(szMessage), "!g", "^4")
replace_all(szMessage, charsmax(szMessage), "!n", "^1")
replace_all(szMessage, charsmax(szMessage), "!t", "^3")
if(id)
iPlayers[0] = id
else
get_players(iPlayers, iCount, "ch")
for(new i; i < iCount; i++)
{
if(is_user_connected(iPlayers[i]))
{
message_begin(MSG_ONE_UNRELIABLE, g_msgSayText, _, iPlayers[i])
write_byte(iPlayers[i])
write_string(szMessage)
message_end()
}
}
}
-
- Подобни теми
- Отговори
- Преглеждания
- Последно мнение
-
- 2 Отговори
- 851 Преглеждания
-
Последно мнение от The Pain
-
- 5 Отговори
- 2395 Преглеждания
-
Последно мнение от Niiicu
-
- 1 Отговори
- 1017 Преглеждания
-
Последно мнение от menkisa
-
- 6 Отговори
- 4551 Преглеждания
-
Последно мнение от HeatoN
-
- 1 Отговори
- 1401 Преглеждания
-
Последно мнение от Siska
-
- 4 Отговори
- 2521 Преглеждания
-
Последно мнение от someoneh
-
- 1 Отговори
- 203 Преглеждания
-
Последно мнение от cgozzie
Кой е на линия
Потребители разглеждащи този форум: 0 регистрирани и 18 госта