Заявка за два два плъгина (1 плъгин забраняващ knife, 1 плъгин hud информация)

В този раздел можете да подавате всякакви заявки за намиране, изработка или преработка на плъгини/модове.
Аватар
southdivision
Извън линия
Потребител
Потребител
Мнения: 279
Регистриран на: 14 Окт 2016, 23:17
Местоположение: София
Се отблагодари: 8 пъти
Получена благодарност: 5 пъти
Обратна връзка:

Заявка за два два плъгина (1 плъгин забраняващ knife, 1 плъгин hud информация)

Мнение от southdivision » 06 Ное 2017, 01:06

Първия плъгин да изпълнява команда която забранява използването/смяната от оръжие към knife на всички терористи също така да забранява да си изхвърлят оръжията. Командата да е /zabraniknifeiorujiq за всички играчи

Втория да е следния

Когато си CT и гледаш (насочил мерника) към CT да изписва във hud в средата името и парите
КОгато си CT и гледаш (насочил мерника) към Т да изписва в Hud в средата името
Когато си Т и гледаш (насочил мерника) към T да изписва във hud в средата името
Когато си Т и гледаш (насочил мерника) към CT да изписва във hud в средата името и парите
Последно промяна от southdivision на 06 Ное 2017, 02:19, променено общо 1 път.

Аватар
OciXCrom
Извън линия
Администратор
Администратор
Мнения: 7206
Регистриран на: 06 Окт 2016, 19:20
Местоположение: /resetscore
Се отблагодари: 117 пъти
Получена благодарност: 1295 пъти
Обратна връзка:

Заявка за два плъгина

Мнение от OciXCrom » 06 Ное 2017, 01:59

Заглавието.

Аватар
OciXCrom
Извън линия
Администратор
Администратор
Мнения: 7206
Регистриран на: 06 Окт 2016, 19:20
Местоположение: /resetscore
Се отблагодари: 117 пъти
Получена благодарност: 1295 пъти
Обратна връзка:

Заявка за два два плъгина (1 плъгин забраняващ knife, 1 плъгин hud информация)

Мнение от OciXCrom » 07 Ное 2017, 20:56

1. Какво правим ако играчът има само нож?

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cromchat>

new bool:g_bNoKnife = false
new g_iLastWeapon[33]

public plugin_init()
{
	register_plugin("NoKnife", "1.0", "OciXCrom")
	register_clcmd("say /zabraniknifeiorujiq", "CmdNoKnife")
	register_clcmd("say_team /zabraniknifeiorujiq", "CmdNoKnife")
	register_clcmd("drop", "OnDrop")
	register_event("CurWeapon", "OnWeaponChange", "be", "1=1")
	CC_SetPrefix("&x04[NoKnife]")
}

public client_putinserver(id)
	g_iLastWeapon[id] = 0

public CmdNoKnife(id)
{
	g_bNoKnife = !g_bNoKnife
	CromChat(id, g_bNoKnife ? "&x06Enabled." : "&x07Disabled.")
	return PLUGIN_HANDLED
}

public OnDrop(id)
{
	if(g_bNoKnife)
	{
		client_print(id, print_center, "You're not allowed to drop your weapon at the moment.")
		return PLUGIN_HANDLED
	}
	
	return PLUGIN_CONTINUE
}

public OnWeaponChange(id)
{
	if(get_user_team(id) != 1)
		return
		
	new iWeapon = read_data(2)
	
	if(iWeapon == CSW_KNIFE && g_iLastWeapon[id])
	{
		new szWeapon[20]
		get_weaponname(g_iLastWeapon[id], szWeapon, charsmax(szWeapon))
		engclient_cmd(id, szWeapon)
		return
	}
	
	g_iLastWeapon[id] = iWeapon
}
2.

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cstrike>

new g_iStatusVictim[33], g_iObject

public plugin_init()
{
	register_plugin("NoKnife", "1.0", "OciXCrom")
	register_event("StatusValue", "OnStatusValue", "be", "1=2", "2!0")
	register_event("StatusValue", "OnStatusValue", "be", "1=1", "2=0")
	g_iObject = CreateHudSyncObj()
}

public client_putinserver(id)
	g_iStatusVictim[id] = 0

public OnStatusValue(id)
{
	static iType, iPlayer
	
	iType = read_data(1)
	iPlayer = read_data(2)
	
	switch(iType)
	{
		case 1:
		{
			if(task_exists(id))
				remove_task(id)
		}
		case 2:
		{
			g_iStatusVictim[id] = iPlayer
			DisplayStatus(id)
			set_task(0.5, "DisplayStatus", id, .flags = "b")
		}
	}
	
	return PLUGIN_HANDLED
}

public DisplayStatus(id)
{
	if(is_user_alive(id))
	{
		new szName[32], iPlayer = g_iStatusVictim[id]
		get_user_name(iPlayer, szName, charsmax(szName))
		
		new CsTeams:iTeamId = cs_get_user_team(id)
		new CsTeams:iTeamPlayer = cs_get_user_team(iPlayer)
		
		if(iTeamPlayer != CS_TEAM_CT && iTeamPlayer != CS_TEAM_T)
			iTeamPlayer = CS_TEAM_SPECTATOR
		
		set_hudmessage(0, 255, 0, -1.0, 0.60, 0, 0.5, 0.5)
		
		if(iTeamId == CS_TEAM_CT)
		{
			if(iTeamPlayer == CS_TEAM_CT)
				ShowSyncHudMsg(id, g_iObject, "%s [%i$]", szName, cs_get_user_money(iPlayer))
			else
				ShowSyncHudMsg(id, g_iObject, "%s", szName)
		}
		else
		{
			if(iTeamPlayer == CS_TEAM_CT)
				ShowSyncHudMsg(id, g_iObject, "%s [%i$]", szName, cs_get_user_money(iPlayer))
			else
				ShowSyncHudMsg(id, g_iObject, "%s", szName)
		}
	}
	else remove_task(id)
}

Аватар
southdivision
Извън линия
Потребител
Потребител
Мнения: 279
Регистриран на: 14 Окт 2016, 23:17
Местоположение: София
Се отблагодари: 8 пъти
Получена благодарност: 5 пъти
Обратна връзка:

Заявка за два два плъгина (1 плъгин забраняващ knife, 1 плъгин hud информация)

Мнение от southdivision » 10 Ное 2017, 16:59

Тествах ги и станаха! Това беше което искам. Благодаря,може да локваш

Заключено
  • Подобни теми
    Отговори
    Преглеждания
     Последно мнение

Обратно към “Заявки за плъгини”

Кой е на линия

Потребители разглеждащи този форум: Google [Bot] и 9 госта