Заявка за рандом glow

[Dem0na]

здравейте може ли някой да направи плъгин който всички играчи които държат пистолет usp да светят в различен цвят през 2 секунди , благодаря ви

[OciXCrom]

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <fun>

#define TASK_RANDOMGLOW 444333
#define GLOW_FREQUENCY 2.0

new bool:g_bGlow[33]

public plugin_init()
{
	register_plugin("Random Glow for USP Players", "1.0", "OciXCrom")
	register_event("CurWeapon", "OnWeaponChange", "be", "1=1")
}

public client_putinserver(id)
	g_bGlow[id] = false

public OnWeaponChange(id)
{
	if(!is_user_alive(id))
		return
		
	if(read_data(2) == CSW_USP)
	{
		apply_random_glow(id)
		
		new iTask = id + TASK_RANDOMGLOW
		remove_task(iTask)
		set_task(GLOW_FREQUENCY, "check_and_set", iTask, .flags = "b")
	}
	else
	{
		remove_task(id + TASK_RANDOMGLOW)
		
		if(g_bGlow[id])
			remove_glow(id)
	}
}

public check_and_set(id)
{
	id -= TASK_RANDOMGLOW
	
	if(get_user_weapon(id) == CSW_USP)
		apply_random_glow(id)
}

apply_random_glow(const id)
{
	if(is_user_alive(id))
	{
		g_bGlow[id] = true
		set_user_rendering(id, kRenderFxGlowShell, random(256), random(256), random(256), kRenderNormal, 75)
	}
}
	
remove_glow(const id)
{
	g_bGlow[id] = false
	set_user_rendering(id, kRenderFxNone, 0, 0, 0, kRenderNormal, 0)
}

[Dem0na]

мерси много , локвайте <3