Пререботка на плъгина "/snipers"

В този раздел можете да подавате всякакви заявки за намиране, изработка или преработка на плъгини/модове.
Аватар
MickeyMouse
Извън линия
Потребител
Потребител
Мнения: 36
Регистриран на: 06 Фев 2018, 15:57

Пререботка на плъгина "/snipers"

Мнение от MickeyMouse » 11 Фев 2018, 14:14

Здравейте. Някой може ли да ми направи така ,че човек с флаг "r" да може да взима безплатно дадените снайпери?
Прикачени файлове
snipers.sma
(4.93 KiB) Свалено 100 пъти
snipers.sma
(4.93 KiB) Свалено 100 пъти

Аватар
OciXCrom
Извън линия
Администратор
Администратор
Мнения: 7206
Регистриран на: 06 Окт 2016, 19:20
Местоположение: /resetscore
Се отблагодари: 117 пъти
Получена благодарност: 1295 пъти
Обратна връзка:

Пререботка на плъгина "/snipers"

Мнение от OciXCrom » 11 Фев 2018, 15:10

Кодът е зле. Направих ти нов:

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cromchat>
#include <cstrike>
#include <fun>

//#define USING_REAPI
#define REPLACE_OLD_WEAPONS

#if defined USING_REAPI
	#include <reapi>
#else
	#if defined REPLACE_OLD_WEAPONS
		#include <stripweapons>
	#endif
#endif

#define PLUGIN_VERSION "1.0"
#define SOUND_BUY "items/gunpickup2.wav"
#define FREE_FLAG ADMIN_LEVEL_F

enum _:ItemInfo
{
	Name[32],
	Price,
	Weapon[16],
	Ammo,
	Csw
}

new g_eItems[][ItemInfo] = 
{
	/* "Name", Price, "weapon_id", Bullets, CSW_ID */
	{ "AWP", 6000, "weapon_awp", 30, CSW_AWP },
	{ "SG-550", 6000, "weapon_sg550", 90, CSW_SG550 },
	{ "G3SG1", 6000, "weapon_g3sg1", 90, CSW_G3SG1 }
}
	
public plugin_init()
{
	register_plugin("Simple Shop", PLUGIN_VERSION, "OciXCrom")
	register_cvar("CRXSimpleShop", PLUGIN_VERSION, FCVAR_SERVER|FCVAR_SPONLY|FCVAR_UNLOGGED)
	register_clcmd("say /snipers", "cmdShop")
	register_clcmd("say_team /snipers", "cmdShop")
	CC_SetPrefix("[&x04CS-ZAPAD&x01]")
}

public plugin_precache()
	precache_sound(SOUND_BUY)

public cmdShop(id)
{
	if(!is_user_alive(id))
		CC_SendMessage(id, "You need to be alive.")
	else
	{
		new iMenu = menu_create("\rSniper Shop", "shopHandler")
		new szItem[64], iMoney = cs_get_user_money(id)
		
		for(new i, bool:bFree = bool:(get_user_flags(id) & FREE_FLAG); i < sizeof(g_eItems); i++)
		{
			if(bFree)
				formatex(szItem, charsmax(szItem), "%s \y[FREE]", g_eItems[i][Name])
			else
				formatex(szItem, charsmax(szItem), "%s %s[%i$]", g_eItems[i][Name], iMoney >= g_eItems[i][Price] ? "\r" : "\d", g_eItems[i][Price])
				
			menu_additem(iMenu, szItem)
		}
		
		menu_display(id, iMenu, 0)
	}
	
	return PLUGIN_HANDLED
}

public shopHandler(id, iMenu, iItem)
{
	if(iItem != MENU_EXIT && is_user_alive(id))
	{
		new iMoney = cs_get_user_money(id)
		new bool:bFree = bool:(get_user_flags(id) & FREE_FLAG)
		
		if(!bFree && iMoney < g_eItems[iItem][Price])
			CC_SendMessage(id, "You don't have enough money to purchase this item.")
		else
		{
			if(!bFree)
			{
				cs_set_user_money(id, iMoney - g_eItems[iItem][Price])
				CC_SendMessage(id, "You have bought ^3%s ^1for ^4%i$", g_eItems[iItem][Name], g_eItems[iItem][Price])
			}
			else CC_SendMessage(id, "You received ^3%s ^1for ^4FREE", g_eItems[iItem][Name])
				
			emit_sound(id, CHAN_ITEM, SOUND_BUY, 1.0, ATTN_NORM, 0, PITCH_NORM)
			
			#if defined USING_REAPI
				#if defined REPLACE_OLD_WEAPONS
				rg_give_item(id, g_eItems[iItem][Weapon], GT_REPLACE)
				#else
				rg_give_item(id, g_eItems[iItem][Weapon], GT_APPEND)
				#endif
			#else
				#if defined REPLACE_OLD_WEAPONS
				StripWeapons(id, Primary)
				#endif
				
				give_item(id, g_eItems[iItem][Weapon])
			#endif
			
			cs_set_user_bpammo(id, g_eItems[iItem][Ammo], g_eItems[iItem][Csw])
		}
	}

	menu_destroy(iMenu)
	return PLUGIN_HANDLED
}
Ако ползваш ReAPI & ReGameDLL, разкоментирай реда #define USING_REAPI.
Ако не искаш старите оръжия да се премахват, коментирай реда #define REPLACE_OLD_WEAPONS.

Аватар
MickeyMouse
Извън линия
Потребител
Потребител
Мнения: 36
Регистриран на: 06 Фев 2018, 15:57

Пререботка на плъгина "/snipers"

Мнение от MickeyMouse » 11 Фев 2018, 15:45

Всичко е точно. Може да lock-нете темата.

Заключено
  • Подобни теми
    Отговори
    Преглеждания
     Последно мнение

Обратно към “Заявки за плъгини”

Кой е на линия

Потребители разглеждащи този форум: Semrush [Bot] и 10 госта