Заявка за изработване на Happy Hour VIP плъгин

В този раздел можете да подавате всякакви заявки за намиране, изработка или преработка на плъгини/модове.
Аватар
neppyS~
Извън линия
Потребител
Потребител
Мнения: 114
Регистриран на: 30 Окт 2017, 18:25

Заявка за изработване на Happy Hour VIP плъгин

Мнение от neppyS~ » 26 Фев 2018, 16:48

В тази тема,ще поискам един Happy Hour плъгин за мод : Zombie Crysis.
Искам да пише в дясно-отгоре кога започва и кога свършва.
Тоест:
Happy Hour VIP
Start : 20:00 End: 24:00
Когато е Happy Hour всички да имат двоен скок и да започва в 20:00 и да свършва в 24:00.
Дано съм обяснил възможно най-добре.

Аватар
OciXCrom
Извън линия
Администратор
Администратор
Мнения: 7206
Регистриран на: 06 Окт 2016, 19:20
Местоположение: /resetscore
Се отблагодари: 117 пъти
Получена благодарност: 1295 пъти
Обратна връзка:

Заявка за изработване на Happy Hour VIP плъгин

Мнение от OciXCrom » 26 Фев 2018, 16:55

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <engine>

#define MAX_JUMPS 2
#define TASK_MESSAGE 344874

new bool:g_bHappyHour, g_pStart, g_pEnd, g_iStart, g_iEnd, g_iObject
new bool:g_bDoJump[33], g_iJumps[33]

public plugin_init()
{
	register_plugin("Happy Hour", "1.0", "OciXCrom")
	register_logevent("OnRoundStart", 2, "1=Round_Start")
	g_pStart = register_cvar("happyhour_start", "20")
	g_pEnd = register_cvar("happyhour_end", "0")
	g_iObject = CreateHudSyncObj()
}

public client_putinserver(id)
{
	g_bDoJump[id] = false
	g_iJumps[id] = 0
}
	
public OnRoundStart()
{
	g_iStart = get_pcvar_num(g_pStart)
	g_iEnd = get_pcvar_num(g_pEnd)
	g_bHappyHour = is_happy_hour(g_iStart, g_iEnd)
	
	if(g_bHappyHour)
		set_task(1.0, "display_message", TASK_MESSAGE, .flags = "b")
	else
		remove_task(TASK_MESSAGE)
}

public display_message()
{	
	set_hudmessage(0, 255, 0, 0.08, 0.2, 0, 0.1, 1.0, 0.1, 0.1, -1)
	ShowSyncHudMsg(0, g_iObject, "Happy Hour VIP^nStart : %i:00 End: %i:00", g_iStart, g_iEnd)
}

public client_PreThink(id)
{
	if(!g_bHappyHour || !is_user_alive(id))
		return PLUGIN_CONTINUE
	
	new iNewButton = get_user_button(id)
	new iOldButton = get_user_oldbutton(id)
	
	if((iNewButton & IN_JUMP) && !(get_entity_flags(id) & FL_ONGROUND) && !(iOldButton & IN_JUMP))
	{
		if(g_iJumps[id] < MAX_JUMPS)
		{
			g_bDoJump[id] = true
			g_iJumps[id]++
			return PLUGIN_CONTINUE
		}
	}
	
	if((iNewButton & IN_JUMP) && (get_entity_flags(id) & FL_ONGROUND))
	{
		g_iJumps[id] = 0
		return PLUGIN_CONTINUE
	}
	
	return PLUGIN_CONTINUE
}

public client_PostThink(id)
{
	if(!g_bHappyHour || !is_user_alive(id))
		return PLUGIN_CONTINUE
		
	if(g_bDoJump[id])
	{
		new Float:flVelocity[3]	
		entity_get_vector(id, EV_VEC_velocity, flVelocity)
		flVelocity[2] = random_float(265.0, 285.0)
		entity_set_vector(id, EV_VEC_velocity, flVelocity)
		g_bDoJump[id] = false
	}
	
	return PLUGIN_CONTINUE
}

bool:is_happy_hour(const iStart, const iEnd)
{
    static iHour; time(iHour)
    return bool:(iStart < iEnd ? (iStart <= iHour < iEnd) : (iStart <= iHour || iHour < iEnd))
}

Аватар
neppyS~
Извън линия
Потребител
Потребител
Мнения: 114
Регистриран на: 30 Окт 2017, 18:25

Заявка за изработване на Happy Hour VIP плъгин

Мнение от neppyS~ » 26 Фев 2018, 17:53

Благодаря за труда!
ЛОК!

Заключено
  • Подобни теми
    Отговори
    Преглеждания
     Последно мнение

Обратно към “Заявки за плъгини”

Кой е на линия

Потребители разглеждащи този форум: Bing [Bot] и 16 госта