CSHOP Extra Item: Faster Primary Attack [Всички оръжия]

[Marinovv]

Хей всички. Може ли нов итем за шопа, който да добавя спеед на стрелбата на оръжията?

[User12]

Може и без итем да стане това , има speed хакове който помагат или ти искаш да се презарежда по бавно ?

[OciXCrom]

Оправи заглавието на темата - добави за какъв предмет става дума.

[Marinovv]

Прощавайте хора, че не е точно заглавието и описанието. Искам просто да се добави Item в Shop-а, който да прави Speed на оръжията. Ето какво имам предвид под спийд..

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>
#include <xs>
#include <gunxpmod>
#include <engine>
#include <cstrike>

new PLUGIN_NAME[]    = "UNLOCK : AWP"
new PLUGIN_AUTHOR[]    = "жг"
new PLUGIN_VERSION[]    = "2.5"

new const WEAPON_V_MDL[] = "models/gunxpmod/v_awp.mdl";
#define WEAPON_CSW CSW_AWP
new const weapon_n[] = "weapon_awp";

const m_pPlayer   = 41;
const m_flPrimaryAttack = 46;

#define IsPlayer(%1)  ( 1 <= %1 <= g_maxplayers )


new damage_weapon, pCvarRof, weapon_recoil;
new g_maxplayers;   
new bool:g_Weapon[33];
new Float:cl_pushangle[33][3];

public plugin_init()
{
   register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR)
   register_gxm_item("AWP", "| + ULTRA Aim | + ULTRA Fast Speed | + ULTRA Power | + Scope |", 400)

   damage_weapon = register_cvar("gxm_damage_awp","4.0"); // damage multiplier
   pCvarRof = register_cvar( "awp_rof", "0.6" ); // weapon rof , 0.090 - fast
   weapon_recoil = register_cvar( "awp_recoil", "0.9" ); // weapon recoil

   register_event("CurWeapon", "Event_CurWeapon", "be", "1=1");
   
   RegisterHam( Ham_Weapon_PrimaryAttack, weapon_n, "Fwd_AttackSpeedPost" , 1 );
   RegisterHam( Ham_Weapon_PrimaryAttack, weapon_n, "Fwd_AttackSpeedPre");

        RegisterHam( Ham_Item_Deploy , weapon_n, "Fwd_AttackSpeedPost", 1 );

   RegisterHam(Ham_TakeDamage, "player", "Ham_DamageWeapon");

   register_forward( FM_CmdStart, "Fwd_CmdStart" );

   g_maxplayers = get_maxplayers();
}
public gxm_item_enabled(id)
{
   g_Weapon[id] = true;
}
public client_connect(id)
{
   g_Weapon[id] = false;
}
public plugin_precache() 
{
   engfunc(EngFunc_PrecacheModel, WEAPON_V_MDL);
}

public Fwd_AttackSpeedPre(Ent)
{
   new id = pev(Ent,pev_owner);
   entity_get_vector( id, EV_VEC_punchangle, cl_pushangle[id]);
}
public Fwd_AttackSpeedPost( const Entity )
{
   static id ; id = get_pdata_cbase(Entity, m_pPlayer, 4)
   if (g_Weapon[id] && IsPlayer(id) )
   {
      set_pdata_float( Entity, m_flPrimaryAttack, get_pcvar_float( pCvarRof ), 4 );

      new Float:push[3];
      entity_get_vector( id, EV_VEC_punchangle, cl_pushangle[id]);
      xs_vec_sub( push, cl_pushangle[id], push);
      xs_vec_mul_scalar( push, get_pcvar_float( weapon_recoil ), push);
      xs_vec_add( push, cl_pushangle[id], push);
      entity_set_vector( id, EV_VEC_punchangle, push);
   }
}

public Ham_DamageWeapon(id, inflictor, attacker, Float:damage, damagebits)
{
   if ( !IsPlayer(attacker) || !g_Weapon[attacker] )
           return HAM_IGNORED;

   new weapon2 = get_user_weapon(attacker, _, _);
   if( weapon2 == WEAPON_CSW)
   {
      SetHamParamFloat(4, damage * get_pcvar_float(damage_weapon));
      return HAM_HANDLED;
   }

   return HAM_IGNORED;
}
public Event_CurWeapon(id)
{
   if ( !g_Weapon[id] || !is_user_alive(id) )
   return PLUGIN_CONTINUE;

   new Gun = read_data(2)

   if( Gun == WEAPON_CSW)
   {
      entity_set_string(id, EV_SZ_viewmodel, WEAPON_V_MDL)
   }

   return PLUGIN_CONTINUE;
}

Предоставям примерен код в който има много неща, но както и да е. Важното е, че в този код има спийд на въпросното оръжиe и самото оръжиe стреля и презарежда в пъти по бързо от стандартното. По принцип ще е възможно ли да се направи същото за всяко едно оръжия чрез един Item или не понеже всяко оръжие си има различна бързина на стреляне?

А относно заглавието ще извинявате. Не бих могъл да го наименувам по добре за момента.

[OciXCrom]

viewtopic.php?f=110&t=5009

[Marinovv]

Приятел пускам отново коментар, но тук с цел да не спамя в онази тема. Няма да лъжа не бачка твоя плъгин. Всичко уж върви няма Errors, а спийда е еднакъв за всички оръжия. И с просто око може да се види, че разлика с този Item няма върху спийда на оръжията. На AWP и Knife се вижда толкова ясно, че няма промяна с този Item, че и слепите ще го видят.

Не вярвам да има други плъгини да му пречат точно на този Item да работи, защото примерно в твоя шоп има Item - Fast Speed, който пък от своя страна си върви перфектно.

Не разбирам и ще се радвам да помогнеш. Може да предоставиш и видео с колко се увеличава спийда на оръжията, което ще помогне не само на мен, а и на други потребители.

П.С> защо в gametracker.com не отчита, че ползвам Item-ът ти? Уж съм го сложил правилно. Моля те виж отново плъгинът ти.
Поздрави!

Added in 2 hours 33 minutes 26 seconds:
Добре де. На HLDS Windows върви този твой плъгин OCixCrom, а на ReHLDS на лунукс не. Как така.. странното е, че компилацията всичко си е окей и няма грешки дори при стартиране на сървърът, но при ReHLDS не баца. Има в го в шоп магазина и може да се купи, но не баца.

И най - странното е, че в gametracker.com не показва, че ползвам този плъгин в сървърът. И така сега излиза, че хем го имам, хем го нямам този плъгин.

Много моля помогнете. Какво става? Рових уж махах Reaimdetector и всички други допълнителни защити, за ReHLDS , но уви пак същото. Има нещо ме съмнява блокира плъгина.. или е несъвместим с нещо.

[OciXCrom]

Gametracker се обнявява през 24 часа. Ако работи на HLDS, значи проблемът е в ReHLDS и наистина ми е писнало да се оправям с плъгини несъвместими за ReHLDS. Някой ако иска нека да го преработи за ReHLDS, аз няма да се занимавам с това, да вземат и да си оправят проблемите.

// Едит: току що го тествах под ReHLDS и си работи, на Windows обаче. Опитай да обновиш ReHLDS и добавките до последната им версия.

[Marinovv]

Наистина на ReHLDS на Windows си работи без грешка. На Linux Debian обаче не работи. Наистина моля, който желае да фиксира плъгина и за Linux сървърите.

П.С> всичко ми е обновено, но проблемът продължава. Дори не отчита, че ползвам плъгинът ти в GameTrackers, а в действителност го ползвам постоянно и в игра, когато се закупи не работи.

[OciXCrom]

Плъгинът си е направен и за Windows и за Linux. Ако имат проблем в ReAPI, аз няма как да го оправя. Опитай така:

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <customshop>
#include <fakemeta>
#include <hamsandwich>
#include <reapi>

#define PLUGIN_VERSION "1.0"

additem ITEM_ATTACKRATE;
new Float:g_fMultiplier;
new bool:g_bHasItem[33];

public plugin_init()
{
	register_plugin("CSHOP: Primary Attack Rate", PLUGIN_VERSION, "OciXCrom");

	for(new szWeapon[20], i = CSW_P228; i <= CSW_P90; i++)
	{
		if(get_weaponname(i, szWeapon, charsmax(szWeapon)))
		{
			RegisterHam(Ham_Weapon_Reload, szWeapon, "OnReload", 1);
			RegisterHam(Ham_Weapon_PrimaryAttack, szWeapon, "OnPrimaryAttack", 1);
		}
	}

	g_fMultiplier = cshop_get_float(ITEM_ATTACKRATE, "Multiplier");
}

public plugin_precache()
{
	ITEM_ATTACKRATE = cshop_register_item("attackrate", "Faster Attack Rate", 6000);
	cshop_set_float(ITEM_ATTACKRATE, "Multiplier", 1.5);
}

public client_putinserver(id)
	g_bHasItem[id] = false;

public cshop_item_selected(id, iItem)
{
	if(iItem == ITEM_ATTACKRATE)
		g_bHasItem[id] = true;
}

public cshop_item_removed(id, iItem)
{
	if(iItem == ITEM_ATTACKRATE)
		g_bHasItem[id] = false;
}

public OnReload(iEnt)
{
	if(get_member(iEnt, m_Weapon_fInReload))
	{
		static id
		id = get_member(iEnt, m_pPlayer);

		if(g_bHasItem[id])
			set_member(id, m_flNextAttack, (get_member(id, m_flNextAttack) / g_fMultiplier));
	}
}

public OnPrimaryAttack(iEnt)
{
	if(!pev_valid(iEnt))
		return;

	if(g_bHasItem[get_member(iEnt, m_pPlayer)])
		set_member(iEnt, m_Weapon_flNextPrimaryAttack, Float:get_member(iEnt, m_Weapon_flNextPrimaryAttack) / g_fMultiplier);
}

[Marinovv]

Сега вече на Reapi работи идеално. Много ама адски много благодаря. Бях изгубил надежда.

Ще е добре, ако споделиш и Reapi версията. Може да локвате.