Respawn команда

[chillblaze]

Плугин , който да респаунва играча с написване на командата /respawn и /res
Без значение дали играча е жив или мъртъв.
Да запомня играчите по ип или никнейм с право на респаун - 1 път на карта.
п.с. Благодаря на JustInCase и OciXCrom

[JustInCase]

Тествай. Провери и дали може след смяна на картата пак да се използва командата защото не съм добавил такава проверка.


EDIT :
Тествал съм го вече. Всичко работи!

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <amxmisc>
#include <hamsandwich>

#define PLUGIN "Respawn Command"
#define VERSION "1.0"
#define AUTHOR "JustInCase"

new const szLimit = 1
new szUses[33]

new szChatCommands[][] = {
    "say /respawn", "say_team /respawn",
    "say /res", "say_team /res"
}


public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	for ( new i = 0; i < sizeof szChatCommands; i++)
	register_clcmd( szChatCommands[i], "RespawnF" )
	
}
public RespawnF(id)
{
	if(szUses[id]++ >= szLimit)
	{
		client_print(id, print_center, "You can use this command once per map")
		return PLUGIN_HANDLED
	}
	else ExecuteHamB(Ham_CS_RoundRespawn, id)
	return PLUGIN_HANDLED
}

[OciXCrom]

• Не си добавил запазване до края на картата.
• Ако не рестартираш стойността на szUses когато играч влезне в сървъра, тя ще се прехвърли на напълно друг играч, който ще получи id-то на предишния.
• szLimit, szUses - "sz" се ползва за стрингове, в случая ползваш числа (интежер) и правилно е да се пишат iLimit, iUses.

Поправен код:

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <amxmisc>
#include <hamsandwich>

#define PLUGIN "Respawn Command"
#define VERSION "1.0"
#define AUTHOR "AMXX-BG.info"

new const g_iLimit = 1
new g_iUses[33]

new Trie:g_tUses
new g_szIP[33][16]

new g_szChatCommands[][] = {
    "say /respawn", "say_team /respawn",
    "say /res", "say_team /res"
}

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
   
    for(new i; i < sizeof(g_szChatCommands); i++)
        register_clcmd(g_szChatCommands[i], "RespawnF")
        
    g_tUses = TrieCreate()
}

public plugin_end()
    TrieDestroy(g_tUses)

public RespawnF(id)
{
    if(g_iUses[id]++ >= g_iLimit)
        client_print(id, print_center, "You can use this command once per map")
    else
        ExecuteHamB(Ham_CS_RoundRespawn, id)
        
    return PLUGIN_HANDLED
}

public client_putinserver(id)
{
    g_iUses[id] = 0
    get_user_ip(id, g_szIP[id], charsmax(g_szIP[]))
    TrieGetCell(g_tUses, g_szIP[id], g_iUses[id])
}

public client_disconnect(id)
    TrieSetCell(g_tUses, g_szIP[id], g_iUses[id]) 

[chillblaze]

Мерси. Ще го тествам днес по някое време.

п.с. Перфектен