cl_filterstuffcmd 0 Plugin Kick

[Infamous2018]

Hello, since i am running FPS Max 101 Plugin but there are Users who get more when they overwrite fps + filterstuff = 1

Any Way that anyone can create an Plugin what accept only cl_filterstuffcmd 0 ? And when anyone add to "1" that he get kicked with message:

"cl_filterstuffcmd need to be "0""

Thx?!

[Huehue]

There you go..

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <fakemeta>

#define VERSION "1.0-Huehue"

public plugin_init()
{
	register_plugin("Steam Filterstuffcmd Var Check", VERSION, "AMXX-BG PawnTeam")
	
	register_forward(FM_PlayerPreThink, "Fwd_FM_PlayerPreThink", ._post = 0)
}

public Fwd_FM_PlayerPreThink(id)
{
	if (is_user_connected(id))
	{
		if (!(pev(id, pev_flags) & FL_ONGROUND))
			CheckFilter(id)
	}
	return FMRES_IGNORED
}

public CheckFilter(id)
{
	if (is_user_alive(id) && !is_user_bot(id) && !is_user_hltv(id) && !CheckFlood(id))
	{
		if (is_user_steam(id))
			query_client_cvar(id, "cl_filterstuffcmd", "qcv_callback")
	}
}

public qcv_callback(id, const cvar[], const value[])
{
	if (!equal(value, "0"))
		server_cmd("kick #%d ^"cl_filterstuffcmd 1 Detected^"", get_user_userid(id))
		
	return PLUGIN_HANDLED
}

stock CheckFlood(id) 
{	
	static Float:g_flLastCmd[MAX_PLAYERS + 1]
	new Float:flGametime = get_gametime()
	
	if (g_flLastCmd[id] < flGametime) 
	{
		g_flLastCmd[id] = flGametime + 0.2
		return false
	}    
	return true
}

stock bool:is_user_steam(id)
{
	static dp_pointer
	
	if (dp_pointer || (dp_pointer = get_cvar_pointer("dp_r_id_provider")))
	{
		server_cmd("dp_clientinfo %d", id)
		server_exec()
		return (get_pcvar_num(dp_pointer) == 2) ? true : false
	}
	return false
}

[Infamous2018]

Thx but i dont need this FPS 100 ... I need only the filterstuff thing.... SO can u edit it pls?!

[Huehue]

Try it now.