Заявка за вип модел

[KaniBaLL]

искам модела да е Банан
Със флаг : b
Ако може да се направи.И ако е възможно да се смени името му на Bananas VIP

[OciXCrom]

Да не би да трябва ние да намерим и модела и да му сменим името защото ти не знаеш как се променя име на файл?!

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cstrike>
#include <hamsandwich>

new const SKIN_FLAG = ADMIN_RESERVATION
new const SKIN_CT[] = "CustomAdmCT"
new const SKIN_T[] = "CustomAdmT"

new bool:g_bHasCustomSkin[33]

public plugin_init()
{
	register_plugin("Simple VIP Model", "1.0", "OciXCrom")
	RegisterHam(Ham_Spawn, "player", "OnPlayerSpawn", 1)
}

public plugin_precache()
{	
	precache_player_model(SKIN_CT)
	precache_player_model(SKIN_T)
}

public client_putinserver(id)
	g_bHasCustomSkin[id] = false

public OnPlayerSpawn(id)
{
	if(is_user_alive(id))
	{
		if(get_user_flags(id) & SKIN_FLAG)
		{
			switch(cs_get_user_team(id))
			{
				case CS_TEAM_CT: set_model(id, SKIN_CT)
				case CS_TEAM_T: set_model(id, SKIN_T)
			}
		}
		else if(g_bHasCustomSkin[id])
		{
			g_bHasCustomSkin[id] = false
			cs_reset_user_model(id)
		}
	}
}

set_model(const id, const szModel[])
{
	cs_set_user_model(id, szModel)
	g_bHasCustomSkin[id] = true
}

stock precache_player_model(const name[], &id = 0)
{
    new model[128]
    formatex(model, charsmax(model), "models/player/%s/%sT.mdl", name, name)

    if(file_exists(model))
        id = precache_generic(model)

    static const extension[] = "T.mdl"
    #pragma unused extension

    copy(model[strlen(model) - charsmax(extension)], charsmax(model), ".mdl")
    return precache_model(model)
}

Настрой си флага и моделите в първите редове.