Заявка за радио команди плъгин

В този раздел можете да подавате всякакви заявки за намиране, изработка или преработка на плъгини/модове.
Аватар
p20lite
Извън линия
Потребител
Потребител
Мнения: 14
Регистриран на: 07 Дек 2018, 18:55
Се отблагодари: 1 път

Заявка за радио команди плъгин

Мнение от p20lite » 08 Дек 2018, 21:14

Добър вечер на всички! Много ще съм благодарен ако някой направи заявката ми. Значи ако може се редактират оригиналните радио команди и на мястото на тях да се напишат други ще бъде много добре. Когато играч натисне "x" да му излязат следните команди ако може цветни.
1. Vurvete walk
2. Bombata e na B
3. Bombata e na A
4. Daite mi orujie
5. Idvat ot (qrd)
6. Idvat ot (st)
7. Zalagam bombata!
8. Obezvrejdam bombata!
9. Ima snaiperist v bazata im!

Това е. Ако може да се направи пак както оригиналните "Nick" (RADIO) Vurvete walk | След ползването на радиото да може да се ползва след 10-15 секунди отново
Цветове: "Nick"-според отбора (РАДИО)-жълт Vurvete walk-зелен. Ако е възможно да се блокират изцяло другите копчета за радиото и да се използва само това "х". Оригиналните команди имат и звук когато ги ползваш тук не знам дали може да се сложи един вид "известие" когато някой натиска дадена команда от радиото, ако е възможно ще се радвам да ми кажете как да сложа някакъв звук или ако не е сложно и имате време да го направите с звук! Извинявам се ако съм пропуснал нещо надявам се да съм обеснил правилно всичко!

П.С Ако е възможно да се сложи и звук ето този много ми допадна: https://www.youtube.com/watch?v=umYZyPRE0g4

Аватар
OciXCrom
Извън линия
Администратор
Администратор
Мнения: 7206
Регистриран на: 06 Окт 2016, 19:20
Местоположение: /resetscore
Се отблагодари: 117 пъти
Получена благодарност: 1295 пъти
Обратна връзка:

Заявка за радио команди плъгин

Мнение от OciXCrom » 09 Дек 2018, 17:19

Сложи звука в cstrike/sound.

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cromchat>

new const g_szCommands[][] =
{
	"Vurvete walk",
	"Bombata e na B",
	"Bombata e na A",
	"Daite mi orujie",
	"Idvat ot (qrd)",
	"Idvat ot (st)",
	"Zalagam bombata!",
	"Obezvrejdam bombata!",
	"Ima snaiperist v bazata im!"
}

new const g_szSound[] = "radiocmd_signal.wav"

new g_iMenu
new g_pUseTime
new Float:g_fLastUse[33]

public plugin_init()
{
	register_plugin("Radio Commands", "1.0", "OciXCrom")

	register_clcmd("radio1", "BlockCommand")
	register_clcmd("radio2", "CustomRadio")
	register_clcmd("radio3", "BlockCommand")

	g_pUseTime = register_cvar("radiocmd_use_time", "15.0")

	g_iMenu = menu_create("Radio Komandi", "Menu_Handler")

	for(new i; i < sizeof(g_szCommands); i++)
		menu_additem(g_iMenu, g_szCommands[i])
}

public plugin_precache()
	precache_sound(g_szSound)

public client_putinserver(id)
	g_fLastUse[id] = 0.0

public BlockCommand(id)
	return PLUGIN_HANDLED

public CustomRadio(id)
{
	if(!is_user_alive(id))
		return PLUGIN_HANDLED

	new Float:fCurrentTime = get_gametime()
	new Float:fUseTime = get_pcvar_float(g_pUseTime)
	new Float:fRemaining = fCurrentTime - g_fLastUse[id]

	if(g_fLastUse[id] && (fRemaining < fUseTime))
	{
		client_print(id, print_center, "Mojesh da polzvash radio komandite sled %.1f sekundi.", fRemaining)
		return PLUGIN_HANDLED
	}

	menu_display(id, g_iMenu)
	return PLUGIN_HANDLED
}

public Menu_Handler(id, iMenu, iItem)
{
	if(!is_user_alive(id))
		return PLUGIN_HANDLED

	new szMessage[128], szName[32], szTeam[10]
	get_user_name(id, szName, charsmax(szName))
	get_user_team(id, szTeam, charsmax(szTeam))
	formatex(szMessage, charsmax(szMessage), "&x03%s &x01(RADIO) &x04%s", szName, g_szCommands[iItem])

	new iPlayers[32], iPnum
	get_players(iPlayers, iPnum, "e", szTeam)

	for(new iPlayer, i; i < iPnum; i++)
	{
		iPlayer = iPlayers[i]
		
		CC_SendMessage(iPlayer, szMessage)
		client_cmd(iPlayer, "spk ^"%s^"", g_szSound)
	}

	g_fLastUse[id] = get_gametime()
	return PLUGIN_HANDLED
}
Прикачени файлове
radiocmd_signal.wav
(65.39 KiB) Свалено 232 пъти
radiocmd_signal.wav
(65.39 KiB) Свалено 232 пъти

Аватар
p20lite
Извън линия
Потребител
Потребител
Мнения: 14
Регистриран на: 07 Дек 2018, 18:55
Се отблагодари: 1 път

Заявка за радио команди плъгин

Мнение от p20lite » 09 Дек 2018, 17:33

Всичко е супер и работи! Благодаря много! Само звука прави някакви проблеми и не се чува. Сложих го в strike/sound както ми каза дори опитах в папката sound да направя папка с име radiocmd_signal.wav и вътре да сложа звука но и така не се получи

В конзолата ми изписва това:
Warning: Unable to open sound/radiocmd_signal.wav for transfer

Аватар
stambeto2006
Извън линия
Модератор
Модератор
Мнения: 505
Регистриран на: 06 Окт 2016, 15:44
Се отблагодари: 53 пъти
Получена благодарност: 45 пъти
Обратна връзка:

Заявка за радио команди плъгин

Мнение от stambeto2006 » 09 Дек 2018, 18:38

p20lite написа: 09 Дек 2018, 17:33 Всичко е супер и работи! Благодаря много! Само звука прави някакви проблеми и не се чува. Сложих го в strike/sound както ми каза дори опитах в папката sound да направя папка с име radiocmd_signal.wav и вътре да сложа звука но и така не се получи

В конзолата ми изписва това:
Warning: Unable to open sound/radiocmd_signal.wav for transfer
Нормално да ти го дава това, качил ли си файла в сървъра ти за бързо теглене?

Аватар
p20lite
Извън линия
Потребител
Потребител
Мнения: 14
Регистриран на: 07 Дек 2018, 18:55
Се отблагодари: 1 път

Заявка за радио команди плъгин

Мнение от p20lite » 09 Дек 2018, 18:48

Ами ползвам програмата HFS мисля че всичко е качено

П.С сега видях че звука не излиза че е в папката sound като гледам през HFS а реално го сложих в папката не знам как да оправя проблема.. Пробвах на ново да кача папката strike и не помогна***(Вече не ми излиза този проблем Warning: Unable to open sound/radiocmd_signal.wav for transfer но пак не се чува "известието" на командите.. спирах и плъгини да пробвам да не е нещо от тях но пак нищо

Аватар
OciXCrom
Извън линия
Администратор
Администратор
Мнения: 7206
Регистриран на: 06 Окт 2016, 19:20
Местоположение: /resetscore
Се отблагодари: 117 пъти
Получена благодарност: 1295 пъти
Обратна връзка:

Заявка за радио команди плъгин

Мнение от OciXCrom » 09 Дек 2018, 20:53

Грешката казва, че звукът не е добавен в сървъра или в downloadurl. Няма проблем в самия плъгин.

Аватар
p20lite
Извън линия
Потребител
Потребител
Мнения: 14
Регистриран на: 07 Дек 2018, 18:55
Се отблагодари: 1 път

Заявка за радио команди плъгин

Мнение от p20lite » 09 Дек 2018, 20:56

OciXCrom написа: 09 Дек 2018, 20:53 Грешката казва, че звукът не е добавен в сървъра или в downloadurl. Няма проблем в самия плъгин.
Плъгина работи прекрасно за което пак ти благодаря! Нещо аз не правя както трябва но не е проблем и да няма звук. Може да заключите

Заключено
  • Подобни теми
    Отговори
    Преглеждания
     Последно мнение

Обратно към “Заявки за плъгини”

Кой е на линия

Потребители разглеждащи този форум: Bing [Bot] и 21 госта