Hook само в Build Time [ Base Builder ]

В този раздел можете да подавате всякакви заявки за намиране, изработка или преработка на плъгини/модове.
Аватар
dyanaka
Извън линия
Потребител
Потребител
Мнения: 20
Регистриран на: 29 Окт 2016, 05:19
Местоположение: Варна
Обратна връзка:

Hook само в Build Time [ Base Builder ]

Мнение от dyanaka » 05 Ное 2016, 01:44

Този плъгин го гледах в няколко сръбски сървъра и е доста удобно за строене. Вече 2ри час ровя из нета и не можах да намеря нищо.
Ако някой е виждал/може да направи/може да намери ще бъде прекрасно, но трябва да е само за BUILD TIME без prepare time само и единствено когато строят и после да изчезва, а админи с флаг rcon да го имат постоянно
Благодарско предварително

Richma
Извън линия
Потребител
Потребител
Мнения: 63
Регистриран на: 27 Окт 2016, 22:55

Re: Hook само в Build Time [ Base Builder ]

Мнение от Richma » 05 Ное 2016, 03:16

Нищо не обясни.. Админите с rcon го разбрахме, но останалите който да го ползват да бъдат всички играчи или пак вип/админ с даден флаг?

Аватар
dyanaka
Извън линия
Потребител
Потребител
Мнения: 20
Регистриран на: 29 Окт 2016, 05:19
Местоположение: Варна
Обратна връзка:

Re: Hook само в Build Time [ Base Builder ]

Мнение от dyanaka » 05 Ное 2016, 16:24

Richma написа:Нищо не обясни.. Админите с rcon го разбрахме, но останалите който да го ползват да бъдат всички играчи или пак вип/админ с даден флаг?
Еми не съм дал флаг значи всички да могат да го ползват

Аватар
JustInCase
Извън линия
Потребител
Потребител
Мнения: 582
Регистриран на: 14 Окт 2016, 23:31
Се отблагодари: 4 пъти
Получена благодарност: 15 пъти

Re: Hook само в Build Time [ Base Builder ]

Мнение от JustInCase » 05 Ное 2016, 17:42

Ще се пробвам да го направя но ми трябва .sma на Base Builder плъгина ти.
MANSION - HNS : 45.144.155.99:27026
ONLINE

Аватар
spartaque
Извън линия
Потребител
Потребител
Мнения: 1
Регистриран на: 24 Окт 2016, 18:06

Re: Hook само в Build Time [ Base Builder ]

Мнение от spartaque » 05 Ное 2016, 23:02

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <engine>


/* Tirant Zombie Base Builder or Veco Zombie Base Builder */
 
#define USE_TIRANT_ZBB
//#define USE_VECO_ZBB
 
#if defined USE_TIRANT_ZBB
    #include <basebuilder>
    #define IsBuildPhase() bb_is_build_phase()
#endif
 
#if defined USE_VECO_ZBB
    #include <vzbb_mod>
    #define IsBuildPhase() user_can_build()
#endif
 
new bool:g_bHook[ 33 ];
 
new gHookOrigins[ 33 ][ 3 ];
 
new g_iHook;
 
new const g_szPrefix[ ] = "Your Prefix Here";
 
public plugin_init( )
{
    register_plugin( "[ ZBB Addon ] Hook", "1.0", "One Above All" );
   
    register_clcmd( "+hook", "hook_on" );
    register_clcmd( "-hook", "hook_off" );
}
public plugin_precache( )
{  
    g_iHook = precache_model( "sprites/zbb/hook.spr" );
}
public hook_on( id )
{
    if ( !(get_user_flags( id ) & ADMIN_RCON) && !IsBuildPhase( ) )
    {
        ColorMessage( id, "Only^3 Admins^1 can use hook after build phase." );
        return PLUGIN_HANDLED;
    }
    if ( get_user_team( id ) != 2 )
    {
        ColorMessage( id, "Only^3 Counter-Terrorists^1 can use hook!" );
        return PLUGIN_HANDLED;
    }
    if ( IsBuildPhase() || get_user_flags( id ) & ADMIN_RCON && !IsBuildPhase())
    {
        get_user_origin( id, gHookOrigins[ id ], 3 );
        g_bHook[ id ] = true;
        set_task( 0.1, "hook_task", id, "", 0, "ab" );
        hook_task( id );
    }
    return PLUGIN_HANDLED;
}
public hook_off( id )
{
    remove_hook( id );
    return PLUGIN_HANDLED;
}
public hook_task( id )
{
    if( !is_user_connected( id ) || !is_user_alive( id ) )
        remove_hook( id );
   
    remove_beam( id );
    draw_hook( id );
    new iOrigin[ 3 ], Float:fVelocity[ 3 ];
   
    get_user_origin( id, iOrigin );
    new iDistance = get_distance( gHookOrigins[ id ], iOrigin);
    if ( iDistance > 25 )
    {
        fVelocity[ 0 ] = ( gHookOrigins[ id ][ 0 ] - iOrigin[ 0 ] ) * ( 2.0 * 300 / iDistance );
        fVelocity[ 1 ] = ( gHookOrigins[ id ][ 1 ] - iOrigin[ 1 ] ) * ( 2.0 * 300 / iDistance );
        fVelocity[ 2 ] = ( gHookOrigins[ id ][ 2 ] - iOrigin[ 2 ] ) * ( 2.0 * 300 / iDistance );
        entity_set_vector( id, EV_VEC_velocity, fVelocity );
    }
    else
    {
        entity_set_vector( id, EV_VEC_velocity, Float:{0.0,0.0,0.0} );
        remove_hook( id );
    }
}
public draw_hook( id )
{
    message_begin( MSG_BROADCAST, SVC_TEMPENTITY );
    write_byte( 1 );                // TE_BEAMENTPOINT
    write_short( id );          // Entity index
    write_coord( gHookOrigins[ id ][ 0 ] );     // Origin
    write_coord( gHookOrigins[ id ][ 1 ] );     // Origin
    write_coord( gHookOrigins[ id ][ 2 ] );     // Origin
    write_short( g_iHook );             // Sprite index
    write_byte( 0 );                // Start frame
    write_byte( 0 );                // Framerate
    write_byte( 100 );          // Life
    write_byte( 10 );           // Width
    write_byte( 0 );                // Noise
    write_byte( random_num(0, 255) );       // Red
    write_byte( random_num(0, 255) );       // Green
    write_byte( random_num(0, 255) );       // Blue
    write_byte( 250 );          // Brightness
    write_byte( 1 );                // Speed
    message_end( );
}
public remove_hook( id )
{
    if( task_exists( id ) )
        remove_task( id );
       
    remove_beam(id);
    g_bHook[ id ] = false;
}
public remove_beam(id)
{
    message_begin( MSG_BROADCAST, SVC_TEMPENTITY );
    write_byte( 99 );
    write_short( id );
    message_end( );
}
stock ColorMessage( const id, const input[ ], any:... )
{
    new iCount = 1, iPlayers[ 32 ];
    static szMessage[ 191 ];
    new iLen = formatex( szMessage, 190, "^4[%s]^1 ", g_szPrefix );
    vformat( szMessage[ iLen ], 190-iLen, input, 3 );
    if ( id ) iPlayers[ 0 ] = id;
    else get_players( iPlayers , iCount , "ch" );
   
    for ( new i = 0; i < iCount; i++ )
    {
        if ( is_user_connected( iPlayers[ i ] ) )
        {
            message_begin( MSG_ONE_UNRELIABLE, get_user_msgid( "SayText" ), _, iPlayers[ i ] );
            write_byte( iPlayers[ i ] );
            write_string( szMessage );
            message_end( );
        }
    }
}
<gamedir>/cstrike/sprites/zbb/hook.spr

Аватар
dyanaka
Извън линия
Потребител
Потребител
Мнения: 20
Регистриран на: 29 Окт 2016, 05:19
Местоположение: Варна
Обратна връзка:

Re: Hook само в Build Time [ Base Builder ]

Мнение от dyanaka » 06 Ное 2016, 01:40

Работи перфектно, благодаря ти много за положения труд за търсене или писане на плъгина!
Може да заключвате!

Заключено
  • Подобни теми
    Отговори
    Преглеждания
     Последно мнение

Обратно към “Заявки за плъгини”

Кой е на линия

Потребители разглеждащи този форум: 0 регистрирани и 26 госта