Request Plugin Cyrillic Name

[glmmlg]

Hellow everyone , i need one plugin to block cyrillic characters from name, If someone connect to server with cyrillic name to change automaticaly on other name ex: Player Tnx.

[OciXCrom]

Requires AMXX 1.9. You can change the replacement name in the beginning of the code - the NEW_NAME variable.

Код за потвърждение: Избери целия код

#include <amxmodx>

#if !defined get_char_bytes
	#error This plugin requires at AMXX 1.9
#endif

new const NAME_FIELD[] = "name"
new const NEW_NAME[] = "cyrillic name not allowed"

public plugin_init()
{
	register_plugin("Block Non-ASCII Names", "1.0", "OciXCrom")
}

public client_putinserver(id)
{
	new szName[MAX_NAME_LENGTH]
	get_user_name(id, szName, charsmax(szName))

	for(new i; i < sizeof(szName); i++)
	{
		if(get_char_bytes(szName[i]) > 1)
		{
			set_user_info(id, NAME_FIELD, NEW_NAME)
			break
		}
	}
}

[glmmlg]

and for amxmodx 1.8.2 ?

[DaRk_StyLe]

and for amxmodx 1.8.2 ?

► Покажи скъсения текст

Код за потвърждение: Избери целия код

#include < amxmodx >

const Check_Name_TaskID = 123;
new const Default_Name[] = "Player"; // Names that contain non-ASCII character(s) will be changed to this.

public plugin_init()
{
	register_plugin( "Block Non-ASCII Names", "1.0", "DaRk_StyLe" );
}

public client_putinserver( id )
{
	remove_task( id + Check_Name_TaskID );
	set_task( 1.0, "Check_Name", id + Check_Name_TaskID );
}

public client_infochanged( id )
{
	new Old_Name[ 32 ];
	get_user_name( id, Old_Name, charsmax( Old_Name ) );
	
	new New_Name[ 32 ];
	get_user_info( id, "name", New_Name, charsmax( New_Name ) );
	
	if( !equali( Old_Name, New_Name ) )
	{
		remove_task( id + Check_Name_TaskID );
		set_task( 1.0, "Check_Name", id + Check_Name_TaskID );
	}
}

public Check_Name( id )
{
	id -= Check_Name_TaskID;
	
	if( is_user_connected( id ) )
	{
		new Name[ 32 ];
		get_user_name( id, Name, charsmax( Name ) );
		
		for( new i = 0; i < charsmax( Name ); i++ )
		{
			if( retrieve_char_bytes( Name[ i ] ) > 1 )
			{
				set_user_info( id, "name", Default_Name );
				break;
			}
		}
	}
}

retrieve_char_bytes( const name )
{
	new c = name;
	
	if( c & ( 1 << 7 ) )
	{
		if( c & ( 1 << 5 ) )
		{
			if( c & ( 1 << 4 ) )
			{
				return 4;
			}
			
			return 3;
		}
		
		return 2;
	}
	
	return 1;
}

[glmmlg]

Awesome , tnx work