VIP плъгин

[MF1]

Здравейте ! Имах вип плъгин който имаше грешки и крашваше сървъра.
та ако може някой да ми направи 1 ако може без грешки
Плъгина да включва в началото на всеки рунд :
-100 ARMOR
- 1xHE 1xFLASH 1xSMOKE
- на всеки 5ти рунд да излиза меню което да дава избор между
1. АК 47
2. М4A
3. AWP + Deagle

Ако може да е флаг ''p''

[TheRedShoko]

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cstrike>
#include <hamsandwich>
#include <fakemeta_util>

#define ADMIN_FLAG "p"

new g_iRound;

public plugin_init()
{
    register_plugin("VIP Extras on Spawn", "1.0", "AMXX-BG.info");
    
    RegisterHam(Ham_Spawn, "player", "FwPlayerSpawnPost", 1);
    
    register_logevent("LogEventRoundStart", 2, "1=Round_Start");
}

public LogEventRoundStart()
{
    g_iRound++;
}

public FwPlayerSpawnPost(id)
{
    if (!is_user_alive(id) || ~get_user_flags(id) & read_flags(ADMIN_FLAG))
    {
        return;
    }
    
    set_pev(id, pev_armorvalue, 100.0);
    set_pev(id, pev_armortype, CS_ARMOR_VESTHELM);
    
    fm_give_item(id, "weapon_hegrenade");
    fm_give_item(id, "weapon_smokegrenade");
    fm_give_item(id, "weapon_flashbang");
    
    if (g_iRound % 5 == 0)
    {
        ShowWeaponsMenu(id);
    }
}

ShowWeaponsMenu(id)
{
    new iMenu = menu_create("Choose you free weapons", "WeaponsMenuHandler");
    
    menu_additem(iMenu, "AK47");
    menu_additem(iMenu, "M4A1");
    menu_additem(iMenu, "AWP + Deagle");
    
    menu_display(id, iMenu);
}

public WeaponsMenuHandler(id, iMenu, Item)
{
    if (Item == MENU_EXIT || !is_user_alive(id) || ~get_user_flags(id) & read_flags(ADMIN_FLAG) || g_iRound % 5 != 0)
    {
        menu_cancel(id);
        return;
    }
    
    switch (Item)
    {
        case 0:
        {
            fm_give_item(id, "weapon_ak47");
            cs_set_user_bpammo(id, CSW_AK47, 90);
        }
        case 1:
        {
            fm_give_item(id, "weapon_m4a1");
            cs_set_user_bpammo(id, CSW_M4A1, 90);
        }
        case 2:
        {
            fm_give_item(id, "weapon_awp");
            cs_set_user_bpammo(id, CSW_AWP, 30);
            
            fm_give_item(id, "weapon_deagle");
            cs_set_user_bpammo(id, CSW_DEAGLE, 35);
        }
    }
    
    menu_destroy(iMenu);
} 

[MF1]

плъгина работи идеално, но съм пропуснал да кажа нещо,
ако може да се настрой да заменя оръжието което е налично, а не да са по 2, благодаря ви !

[TheRedShoko]

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cstrike>
#include <hamsandwich>
#include <fakemeta_util>

#define ADMIN_FLAG "p"

new g_iPrimaryWeapons[] = 
{ 
    CSW_SCOUT, 
    CSW_XM1014, 
    CSW_MAC10,
    CSW_AUG, 
    CSW_UMP45, 
    CSW_SG550, 
    CSW_GALIL, 
    CSW_FAMAS, 
    CSW_AWP, 
    CSW_MP5NAVY,
    CSW_M249,
    CSW_M3,
    CSW_M4A1,
    CSW_TMP,
    CSW_G3SG1,
    CSW_SG552,
    CSW_AK47,
    CSW_P90
};

new g_iRound;

public plugin_init()
{
    RegisterHam(Ham_Spawn, "player", "FwPlayerSpawnPost", 1);
    
    register_logevent("LogEventRoundStart", 2, "1=Round_Start");
}

public LogEventRoundStart()
{
    g_iRound++;
}

public FwPlayerSpawnPost(id)
{
    if (!is_user_alive(id) || ~get_user_flags(id) & read_flags(ADMIN_FLAG))
    {
        return;
    }
    
    set_pev(id, pev_armorvalue, 100.0);
    set_pev(id, pev_armortype, CS_ARMOR_VESTHELM);
    
    fm_give_item(id, "weapon_hegrenade");
    fm_give_item(id, "weapon_smokegrenade");
    fm_give_item(id, "weapon_flashbang");
    
    if (g_iRound % 5 == 0)
    {
        ShowWeaponsMenu(id);
    }
}

ShowWeaponsMenu(id)
{
    new iMenu = menu_create("Choose you free weapons", "WeaponsMenuHandler");
    
    menu_additem(iMenu, "AK47");
    menu_additem(iMenu, "M4A1");
    menu_additem(iMenu, "AWP + Deagle");
    
    menu_display(id, iMenu);
}

public WeaponsMenuHandler(id, iMenu, Item)
{
    if (Item == MENU_EXIT || !is_user_alive(id) || ~get_user_flags(id) & read_flags(ADMIN_FLAG) || g_iRound % 5 != 0)
    {
        menu_cancel(id);
        return;
    }

    for (new i = 0; i < sizeof(g_iPrimaryWeapons); i++)
    {
        fm_strip_user_gun(id, g_iPrimaryWeapons[i]);
    }
    
    switch (Item)
    {
        case 0:
        {
            fm_give_item(id, "weapon_ak47");
            cs_set_user_bpammo(id, CSW_AK47, 90);
        }
        case 1:
        {
            fm_give_item(id, "weapon_m4a1");
            cs_set_user_bpammo(id, CSW_M4A1, 90);
        }
        case 2:
        {
            fm_give_item(id, "weapon_awp");
            cs_set_user_bpammo(id, CSW_AWP, 30);
            
            fm_give_item(id, "weapon_deagle");
            cs_set_user_bpammo(id, CSW_DEAGLE, 35);
        }
    }
    
    menu_destroy(iMenu);
}  

Пробвай.

[MF1]

Има проблеми, изивнявай че те разхождам, вместо M4A ми дава друго, при първо земане също не ми дава нищо, може ли да го тестваш и да го едитнеш ?
някой път дава/не дава оръжия