Заявка за плъгин при конбинация скок с нож и натиснеш десен бутон да ти дава тласък напред

[M36]

Добър ден ще се радвам ако някой може да ми помогне с такъв плъгин ,когато вървиш с ножа и при скок когато натиснеш десния бутон на мишката да ти дава тласък.
Благодаря предварително!

[mBFF-TheFucKBG]

Обясни малко повечко.Като някои класове в ZP ли ?

[JackEyedJones]

Обясни малко повечко.Като някои класове в ZP ли ?

Има предвид способността на зомбитата Leap за отскачане при скок, но иска да го прави по-опростено - с десния бутон само.

[M36]

забравих да спомена, плъгинът ми трябва да е за респаунд сървър.

[<VeCo>]

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

new Float:playerUseCooldown[MAX_PLAYERS+1]
new Float:cvalLeapCooldown_f, cvalLeapPower,Float:cvalLeapHeight_f
public plugin_init()
{
	register_plugin("Leap, my knife, leap!","1.0", "<VeCo>");
	
	bind_pcvar_float(register_cvar("leap_cooldown","3.0"), cvalLeapCooldown_f)
	bind_pcvar_num(register_cvar("leap_power","400"), cvalLeapPower)
	bind_pcvar_float(register_cvar("leap_height","200.0"), cvalLeapHeight_f)
	
	RegisterHam(Ham_Weapon_SecondaryAttack,"weapon_knife", "@Ham_Weapon_Knife_SecondaryAttack", 1)
}

@Ham_Weapon_Knife_SecondaryAttack(ent)
{
	new id = get_ent_data_entity(ent, "CBasePlayerItem","m_pPlayer")
	
	if(pev(id,pev_flags) & FL_ONGROUND) return
	
	new Float:currentGameTime = get_gametime()
	if((currentGameTime - playerUseCooldown[id]) < cvalLeapCooldown_f) return
	
	new Float:velocity[3]
	pev(id,pev_velocity, velocity)
	if(velocity[0] == 0.0 && velocity[1] == 0.0) return
	
	playerUseCooldown[id] = currentGameTime
	
	velocity_by_aim(id,cvalLeapPower, velocity)
	
	velocity[2] = cvalLeapHeight_f
	
	set_pev(id,pev_velocity, velocity)
}

[M36]

Мерси много всичко е 6+