Заявка за добавяне на команда смяна на име NickProtection(OciXCrom) плъгин

[M36]

Здравите просто на плъгина не е добавена опция за смяна на име на играч които вече се е ригистрирал един път ,ще е хубаво ако може да се добави опция която да може да си регистрира другия ник.
Благодаря предварително!

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cromchat>
#include <nvault>

#define MSG_DELAY 15.0
#define MSG_TASK 300533
#define PLUGIN_VERSION "1.0"

new g_iVault

public plugin_init()
{
	register_plugin("Nick Protection", PLUGIN_VERSION, "OciXCrom")
	register_cvar("CRXNickProtection", PLUGIN_VERSION, FCVAR_SERVER|FCVAR_SPONLY|FCVAR_UNLOGGED)
	register_clcmd("say /nick", "Cmd_Nick")
	register_clcmd("say_team /nick", "Cmd_Nick")
	g_iVault = nvault_open("NickProtection")
	CC_SetPrefix("&x04[Nick Protection]")
}

public plugin_end()
	nvault_close(g_iVault)

public client_authorized(id)
{
	new szAuth[35]
	get_user_authid(id, szAuth, charsmax(szAuth))
		
	if(!is_valid_steam(szAuth))
		return
		
	new szData[35], szName[32]
	get_user_name_lower(id, szName, charsmax(szName))

	if(nvault_get(g_iVault, szName, szData, charsmax(szData)))
	{
		if(!equal(szAuth, szData))
			server_cmd("kick #%i ^"This Nick is protected by SteamID^"", get_user_userid(id))
	}
	else set_task(MSG_DELAY, "Inform_User", id + MSG_TASK)
}

public Inform_User(id)
{
	id -= MSG_TASK
	
	if(is_user_connected(id))
		CC_SendMessage(id, "Napishi &x03/nick &x01za da si zashtitish nicka po SteamID!")
}

public Cmd_Nick(id)
{
	new szAuth[35]
	get_user_authid(id, szAuth, charsmax(szAuth))
	
	if(!is_valid_steam(szAuth))
	{
		CC_SendMessage(id, "Trqbva da imash SteamID za da mojesh da polzvash sistemata!")
		return PLUGIN_HANDLED
	}
	
	new szData[35], szName[32]
	get_user_name_lower(id, szName, charsmax(szName))

	if(nvault_get(g_iVault, szName, szData, charsmax(szData)))
		CC_SendMessage(id, "Tozi nick veche e zashtiten sus SteamID &x04%s", szData)
	else if(nvault_get(g_iVault, szAuth, szData, charsmax(szData)))
		CC_SendMessage(id, "Veche si zashtitil edin nick sus SteamID-to si: &x03%s", szData)
	else
	{
		nvault_set(g_iVault, szAuth, szName)
		nvault_set(g_iVault, szName, szAuth)
		CC_LogMessage(id, _, "Nickut &x03%s &x01e uspeshno zashtiten sus SteamID &x04%s", szName, szAuth)
		remove_task(id + MSG_TASK)
	}

	return PLUGIN_HANDLED
}

get_user_name_lower(const id, szName[], const iLen)
{
	get_user_name(id, szName, iLen)
	strtolower(szName)
}

bool:is_valid_steam(const szAuth[])
{
	if(!equali(szAuth, "STEAM_", 6) || equal(szAuth, "STEAM_ID_LAN") || equal(szAuth, "STEAM_ID_PENDING"))
		return false
	
	return true
}

[OciXCrom]

Качи плъгина?

[M36]

Качи плъгина?

готово.

[OciXCrom]

Не е тествано. Командата е /changenick.

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cromchat>
#include <nvault>

#define MSG_DELAY 15.0
#define MSG_TASK 300533
#define PLUGIN_VERSION "1.1"

new g_szAuth[33][35], g_iVault

public plugin_init()
{
	register_plugin("Nick Protection", PLUGIN_VERSION, "OciXCrom")
	register_cvar("CRXNickProtection", PLUGIN_VERSION, FCVAR_SERVER|FCVAR_SPONLY|FCVAR_UNLOGGED)
	register_clcmd("say /nick", "Cmd_Nick")
	register_clcmd("say_team /nick", "Cmd_Nick")
	register_clcmd("say /changenick", "Cmd_ChangeNick")
	register_clcmd("say_team /changenick", "Cmd_ChangeNick")
	g_iVault = nvault_open("NickProtection")
	CC_SetPrefix("&x04[Nick Protection]")
}

public plugin_end()
{
	nvault_close(g_iVault)
}

public client_authorized(id)
{
	get_user_authid(id, g_szAuth[id], charsmax(g_szAuth[]))

	if(!is_valid_steam(g_szAuth[id]))
	{
		return
	}

	new szData[35], szName[32]
	get_user_name_lower(id, szName, charsmax(szName))

	if(nvault_get(g_iVault, szName, szData, charsmax(szData)))
	{
		if(!equal(g_szAuth[id], szData))
		{
			server_cmd("kick #%i ^"This Nick is protected by SteamID^"", get_user_userid(id))
		}
	}
	else
	{
		set_task(MSG_DELAY, "Inform_User", id + MSG_TASK)
	}
}

public Inform_User(id)
{
	id -= MSG_TASK

	if(is_user_connected(id))
	{
		CC_SendMessage(id, "Napishi &x03/nick &x01za da si zashtitish nicka po SteamID!")
	}
}

public Cmd_Nick(id)
{
	if(!is_valid_steam(g_szAuth[id]))
	{
		CC_SendMessage(id, "Trqbva da imash SteamID za da mojesh da polzvash sistemata!")
		return PLUGIN_HANDLED
	}

	new szData[35], szName[32]
	get_user_name_lower(id, szName, charsmax(szName))

	if(nvault_get(g_iVault, szName, szData, charsmax(szData)))
	{
		CC_SendMessage(id, "Tozi nick veche e zashtiten sus SteamID &x04%s", szData)
	}
	else if(nvault_get(g_iVault, g_szAuth[id], szData, charsmax(szData)))
	{
		CC_SendMessage(id, "Veche si zashtitil edin nick sus SteamID-to si: &x03%s", szData)
	}
	else
	{
		nvault_set(g_iVault, g_szAuth[id], szName)
		nvault_set(g_iVault, szName, g_szAuth[id])
		CC_LogMessage(id, _, "Nickut &x03%s &x01e uspeshno zashtiten sus SteamID &x04%s", szName, g_szAuth[id])
		remove_task(id + MSG_TASK)
	}

	return PLUGIN_HANDLED
}

public Cmd_ChangeNick(id)
{
	if(!is_valid_steam(g_szAuth[id]))
	{
		CC_SendMessage(id, "Trqbva da imash SteamID za da mojesh da polzvash sistemata!")
		return PLUGIN_HANDLED
	}

	new szData[35], szName[32], szTemp[32]
	get_user_name_lower(id, szName, charsmax(szName))

	if(!nvault_get(g_iVault, g_szAuth[id], szData, charsmax(szData)))
	{
		CC_SendMessage(id, "Nqma zashtiten nick na tova SteamID. Polzvai &x04/nick &x01za da si zashtitish nicka.", szData)
		return PLUGIN_HANDLED
	}

	if(nvault_get(g_iVault, szName, szTemp, charsmax(szTemp)))
	{
		CC_SendMessage(id, "Tozi nick veche e zashtiten ot SteamID &x04%s", szTemp)
		return PLUGIN_HANDLED
	}

	if(equal(szName, szData))
	{
		CC_SendMessage(id, "Nickut e ednakuv s tozi koito veche si zashtitil!")
		return PLUGIN_HANDLED
	}

	nvault_remove(g_iVault, szData)
	nvault_remove(g_iVault, g_szAuth[id])
	nvault_set(g_iVault, szName, g_szAuth[id])
	nvault_set(g_iVault, g_szAuth[id], szName)

	CC_SendMessage(id, "Uspeshno promeni nicka &x03%s &x01na &x03%s &x01za SteamID &x04%s", szData, szName, g_szAuth[id])
	return PLUGIN_HANDLED
}

get_user_name_lower(const id, szName[], const iLen)
{
	get_user_name(id, szName, iLen)
	strtolower(szName)
}

bool:is_valid_steam(const szAuth[])
{
	if(!equali(szAuth, "STEAM_", 6) || equal(szAuth, "STEAM_ID_LAN") || equal(szAuth, "STEAM_ID_PENDING"))
	{
		return false
	}

	return true
}

[M36]

мерси оци плъгина работи перфектно мерси може да