Заявка за плъгин ВИП.

[sjw]

1.Ако е възможно плъгина да има опцията като се цъкне 'таб' Да изписва на играча с права ВИП.
2.Ако е възможно също така да се добави скин на вип и на админите.
1.Книфе скин също така.

[mi0]

Кажи какви скинове искаш и имената и директориите им.

[sjw]

Няма значение
какви то намерите само да пише админ на тях нямам претенциий

но ,май е само за терористит
https:///// Блокиран текст/линк [НЕЖЕЛАН САЙТ] ///=7&t=124662
https:///// Блокиран текст/линк [НЕЖЕЛАН САЙТ] ///=7&t=124662

[OciXCrom]

Ъ, ъ, тук правим/търсим плъгини, моделите ти ще си ги намериш и настроиш.

1. vipgen

2.

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cstrike>
#include <hamsandwich>

new const SKIN_FLAG = ADMIN_RESERVATION
new const SKIN_CT[] = "CustomAdmCT"
new const SKIN_T[] = "CustomAdmT"

new bool:g_bHasCustomSkin[33]

public plugin_init()
{
	register_plugin("Simple VIP Model", "1.0", "OciXCrom")
	RegisterHam(Ham_Spawn, "player", "OnPlayerSpawn", 1)
}

public plugin_precache()
{	
	precache_player_model(SKIN_CT)
	precache_player_model(SKIN_T)
}

public client_putinserver(id)
	g_bHasCustomSkin[id] = false

public OnPlayerSpawn(id)
{
	if(is_user_alive(id))
	{
		if(get_user_flags(id) & SKIN_FLAG)
		{
			switch(cs_get_user_team(id))
			{
				case CS_TEAM_CT: set_model(id, SKIN_CT)
				case CS_TEAM_T: set_model(id, SKIN_T)
			}
		}
		else if(g_bHasCustomSkin[id])
		{
			g_bHasCustomSkin[id] = false
			cs_reset_user_model(id)
		}
	}
}

set_model(const id, const szModel[])
{
	cs_set_user_model(id, szModel)
	g_bHasCustomSkin[id] = true
}

stock precache_player_model(const name[], &id = 0)
{
    new model[128]
    formatex(model, charsmax(model), "models/player/%s/%sT.mdl", name, name)

    if(file_exists(model))
        id = precache_generic(model)

    static const extension[] = "T.mdl"
    #pragma unused extension

    copy(model[strlen(model) - charsmax(extension)], charsmax(model), ".mdl")
    return precache_model(model)
}

1.

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <fakemeta>

#define V_MODEL "models/v_ime_na_skina.mdl"
#define ADMIN_FLAG ADMIN_SLAY

public plugin_init()
{
	register_plugin("Knife VIP Skin", "1.0", "OciXCrom")
	register_event("CurWeapon", "OnSelectKnife", "be", "1=1", "2=29")
}

public plugin_precache()
{
	#if defined V_MODEL
	precache_model(V_MODEL)
	#endif
	
	#if defined P_MODEL
	precache_model(P_MODEL)
	#endif
}

public OnSelectKnife(id)
{
	if(!(get_user_flags(id) & ADMIN_FLAG))
		return
		
	#if defined V_MODEL
	set_pev(id, pev_viewmodel2, V_MODEL)
	#endif
	
	#if defined P_MODEL
	set_pev(id, pev_weaponmodel2, P_MODEL)
	#endif
}

Настройките са в началото на кодовете.