Заявка за премахнаване на двата пистолета от VIP и добавяне на пари при убийство

[smtng]

Какви ли не методи четох, пробвах какво ли не и не мога да премахна USP, GLOCK и искам ако може да се добави когато се направи нормално убийство да дава 300 $, и убийство с хс да дава 600 $. Благодаря предварително.

vipstuff.sma

(1.07 KiB) Свалено 134 пъти

vipstuff.sma

(1.07 KiB) Свалено 134 пъти

[mi0]

Тествай

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cstrike>
#include <fun>
#include <hamsandwich>

#define PLUGIN_VERSION "1.0"

#define EXTRA_MONEY
#define VIP_FLAG ADMIN_LEVEL_E
#define MOTD_FILE "vip.txt"

#if defined EXTRA_MONEY
	#include <reapi>
#else
	#include <fakemeta>
	const XTRA_OFS_PLAYER = 5
	const XTRA_OFS_WEAPON = 4
	const m_rgpPlayerItems_Slot2 = 369
	const m_iId = 43
	const m_pNext = 42
#endif

public plugin_init()
{
	register_plugin("Generated VIP Plugin", PLUGIN_VERSION, "AMXX-BG.info")
	register_cvar("amxxbg_vip", PLUGIN_VERSION, FCVAR_SERVER|FCVAR_SPONLY|FCVAR_UNLOGGED)
	#if defined EXTRA_MONEY
	RegisterHam(Ham_Killed, "player", "OnPlayerKilled", 1)
	#endif
	RegisterHam(Ham_Spawn, "player", "OnPlayerSpawn", 1)
	
	register_clcmd("say /vip", "ShowMotd")
	register_clcmd("say_team /vip", "ShowMotd")
}

public ShowMotd(id)
{
    show_motd(id, MOTD_FILE)
    return PLUGIN_HANDLED
}

#if defined EXTRA_MONEY
public OnPlayerKilled(iVictim, iAttacker)
{
	if (get_member(iVictim, m_bHeadshotKilled))
	{
		rg_add_account(iAttacker, 300)
	}
}
#endif

public OnPlayerSpawn(id)
{
	if(!is_user_alive(id) || !is_user_vip(id))
	{
		return
	}

	// removing pistols
	#if defined EXTRA_MONEY
	rg_remove_items_by_slot(id, PISTOL_SLOT)
	#else
	new iWeapon
	while (((iWeapon = (get_pdata_cbase(id , m_rgpPlayerItems_Slot2, XTRA_OFS_WEAPON) > 0)) ? get_pdata_int(iWeapon, m_iId, XTRA_OFS_WEAPON) : 0))
	{
		ham_strip_user_pistol(id, iWeapon)
	}
	#endif
		
	set_user_health(id, 104)
	cs_set_user_armor(id, 102, CS_ARMOR_VESTHELM)
	give_item(id, "weapon_deagle")
	cs_set_user_bpammo(id, CSW_DEAGLE, 35)
	give_item(id, "weapon_hegrenade")
	give_item(id, "weapon_flashbang")
	cs_set_user_bpammo(id, CSW_FLASHBANG, 2)
	give_item(id, "weapon_smokegrenade")
	
	if(cs_get_user_team(id) == CS_TEAM_CT)
	{
	    give_item(id, "item_thighpack")
	}
}

bool:is_user_vip(id)
{
	return bool:(get_user_flags(id) & VIP_FLAG)
}

#if !defined EXTRA_MONEY
ham_strip_user_pistol(id, iCswId)
{
	new iWeapon = get_pdata_cbase(id, m_rgpPlayerItems_Slot2, XTRA_OFS_PLAYER)

	while(iWeapon > 0)
	{
		if(get_pdata_int(iWeapon, m_iId, XTRA_OFS_WEAPON) == iCswId && ExecuteHamB(Ham_RemovePlayerItem, id, iWeapon))
		{
			user_has_weapon(id, iCswId, 0)
			ExecuteHamB(Ham_Item_Kill, iWeapon)
		}
		iWeapon = get_pdata_cbase(iWeapon, m_pNext, XTRA_OFS_WEAPON)
	}
}
#endif

Допълнителните пари от HeadShot използват ReAPI, въпреки това ако нямаш ReAPI можеш да ги спреш, като сложиш // пред

Код за потвърждение: Избери целия код

#define EXTRA_MONEY

[smtng]

Всичко е точно благодаря много дори след като добави нещата сървъра спря да крашва благодаря.